form04.frm

一个关于基于MO编程的参考资料希望对大家的交流和学习有帮助

VERSION 5.00
Object = "{9BD6A640-CE75-11D1-AF04-204C4F4F5020}#2.0#0"; "mo20.ocx"
Begin VB.Form Form04 
   Caption         =   "form1"
   ClientHeight    =   6360
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   8400
   LinkTopic       =   "Form1"
   ScaleHeight     =   6360
   ScaleWidth      =   8400
   StartUpPosition =   3  '窗口缺省
   Begin VB.CommandButton Command1 
      Caption         =   "Command1"
      Height          =   495
      Left            =   3600
      TabIndex        =   1
      Top             =   5760
      Width           =   1215
   End
   Begin MapObjects2.Map Map1 
      Height          =   5655
      Left            =   0
      TabIndex        =   0
      Top             =   0
      Width           =   8415
      _Version        =   131072
      _ExtentX        =   14843
      _ExtentY        =   9975
      _StockProps     =   225
      BackColor       =   16777215
      BorderStyle     =   1
      Contents        =   "form04.frx":0000
   End
End
Attribute VB_Name = "Form04"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'Xuewei,2003/6/27
'求点到线的距离；

Option Explicit

Dim moLine As MapObjects2.Line
Dim moPoints As New MapObjects2.Points
Dim moPoint As MapObjects2.Point

Private Sub Command1_Click()
  Dim oPoint As New MapObjects2.Point
  Set oPoint = Map1.ToMapPoint(3800, 600)
  moPoints.Add oPoint
  Set oPoint = Map1.ToMapPoint(900, 3100)
  moPoints.Add oPoint
  Set moLine = New MapObjects2.Line
  moLine.Parts.Add moPoints
  Map1.Refresh
End Sub

Private Sub Form_Load()
  DrawLayer
  Command1.Caption = "显示线段"
  Me.Caption = "计算点到线段的距离"
End Sub

Private Sub Map1_AfterTrackingLayerDraw(ByVal hDC As stdole.OLE_HANDLE)
  Dim oLnSym As New MapObjects2.Symbol
  Dim oPtSym As New MapObjects2.Symbol
  
  If Not moLine Is Nothing Then
    oLnSym.SymbolType = moLineSymbol
    oLnSym.Color = moRed
    oLnSym.Size = 3
    Map1.DrawShape moLine, oLnSym
  End If
  
  If Not moPoint Is Nothing Then
    oPtSym.SymbolType = moPointSymbol
    oPtSym.Color = moBlue
    oPtSym.Style = moCircleMarker
    Map1.DrawShape moPoint, oPtSym
  End If
  
End Sub

Private Sub Map1_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
  Dim fDist As Double
  
  If moLine Is Nothing Then
    MsgBox "先单击“显示线段”"
    Exit Sub
  Else
    Set moPoint = Map1.ToMapPoint(x, y)
    fDist = moPoint.DistanceToSegment(moPoints(0), moPoints(1))
    Map1.TrackingLayer.Refresh True
    MsgBox "距离＝" & Format(fDist, "fixed")
  End If
End Sub

Sub DrawLayer()
  Dim dc As New DataConnection
  Dim layer As MapLayer
  dc.Database = App.Path + "\..\" + "Mexico"
  If Not dc.Connect Then
    MsgBox "在指定的文件夹下没找到图层数据文件！"
    End
  End If
  
  Set layer = New MapLayer
  Set layer.GeoDataset = dc.FindGeoDataset("States")
  layer.Symbol.Color = moLimeGreen
  Map1.Layers.Add layer
End Sub