configure.in

从 IEEE 1394总线接收传输流

AC_INIT(mpeg2ts1394dec, 0.3.1)
AC_CONFIG_SRCDIR(mpeg2demux.c)
AM_INIT_AUTOMAKE

AC_PROG_RANLIB
AC_PROG_CC
AM_PROG_CC_C_O

dnl check for libmpeg2
PKG_CHECK_MODULES(LIBMPEG2, libmpeg2 >= 0.4.0)

dnl check for libraw1394
AC_CHECK_LIB(raw1394, raw1394_phy_packet_write,,AC_MSG_ERROR(need libraw1394 0.10.0 or later))
AC_CHECK_HEADER(libraw1394/raw1394.h, ,AC_MSG_ERROR(need libraw1394 headers (development package)))
dnl in future the two lines above should be removed and RAW1394_CFLAGS and RAW1394_LIBS should be used
PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0, AC_MSG_NOTICE(new libraw1394 (>= 1.1.0) found), [AC_MSG_NOTICE(old libraw1394 (<= 1.1.0) found); oldlibraw1394=true])

AC_CANONICAL_HOST

AC_ARG_ENABLE([fix-window], AC_HELP_STRING([--enable-fix-window], [use fix video window]))
AM_CONDITIONAL(FIX_WINDOW, test x"$enable_fix_window" = x"yes")
if test x"$enable_fix_window" = x"yes"; then
    AC_DEFINE([VIDEO_FIX_WINDOW],,[use a fix window for TV output])
    AC_ARG_ENABLE([xv-workaround], AC_HELP_STRING([--disable-xv-workaround], [do not use the Xv workaround]))
    if test x"$enable_xv_workaround" != x"no"; then
        AC_DEFINE([XV_BUG_WORKAROUND],,[use Xv workaround])
    fi
fi


dnl this is needed for mpeg2 video decoder:
dnl CC-specific flags
AC_SUBST([OPT_CFLAGS])
if test x"$CC" = x"checkergcc"; then
    enable_sdl=no
elif test x"$GCC" = x"yes"; then

    dnl GCC-specific flags

    dnl -Wall
    dnl -Werror moved to the end to not disturb the configure script
    TRY_CFLAGS="$OPT_CFLAGS -Wall"
    AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"])

    dnl -O3
    changequote(<<,>>)
    TRY_CFLAGS=`echo "$OPT_CFLAGS $CFLAGS"|sed "s/-O[0-9]*//g"`
    changequote([,])
    TRY_CFLAGS="$TRY_CFLAGS -O3"
    AC_TRY_CFLAGS([$TRY_CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"; CFLAGS=""])

    AC_ARG_ENABLE([debug],
	[  --enable-debug          debug mode configuration])
    if test x"$enable_debug" = x"yes"; then
	AC_DEFINE([DEBUG],,[debug mode configuration])
    else
	dnl -fomit-frame-pointer
	TRY_CFLAGS="$OPT_CFLAGS -fomit-frame-pointer"
	AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"])
    fi

    dnl -fno-common
    TRY_CFLAGS="$OPT_CFLAGS -fno-common"
    AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"])

    dnl arch-specific flags
    case "$host" in
    i?86-* | k?-* | x86_64-*)
	AC_DEFINE([ARCH_X86],,[x86 architecture])
	case "$host" in
	i386-*) TRY_CFLAGS="$OPT_CFLAGS -mcpu=i386";;
	i486-*) TRY_CFLAGS="$OPT_CFLAGS -mcpu=i486";;
	i586-*) TRY_CFLAGS="$OPT_CFLAGS -mcpu=pentium";;
	i686-*) TRY_CFLAGS="$OPT_CFLAGS -mcpu=pentiumpro";;
	k6-*)   TRY_CFLAGS="$OPT_CFLAGS -mcpu=k6";;
	esac
	AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"]);;
    ppc-* | powerpc-*)
	AC_CHECK_HEADER([altivec.h],
	    [TRY_CFLAGS="$ARCH_OPT_CFLAGS -maltivec"],
	    [TRY_CFLAGS="$ARCH_OPT_CFLAGS -faltivec"])
	AC_TRY_CFLAGS([$OPT_CFLAGS $TRY_CFLAGS $CFLAGS],
	    [ARCH_OPT_CFLAGS="$TRY_CFLAGS"
	    AC_DEFINE([ARCH_PPC],,[ppc architecture])]);;
    sparc-* | sparc64-*)
	AC_DEFINE([ARCH_SPARC],,[sparc architecture])
	TRY_CFLAGS="$OPT_CFLAGS -mcpu=ultrasparc -mvis"
	AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"]);;
    alpha*)
	AC_DEFINE([ARCH_ALPHA],,[alpha architecture]);;
    esac
elif test x"$CC" = x"tendracc"; then
    dnl TenDRA portability checking compiler
    TENDRA=yes
    OPT_CFLAGS="-Xp -Yansi -f`pwd`/include/tendra.h -DELIDE_CODE"
    no_x=yes
    enable_sdl=no
elif test x"$CC" = x"icc" -a x"`$CC -V 2>&1 | grep Intel`" != x""; then
    dnl Intel C++ compiler
    OPT_CFLAGS="-g -O3 -unroll -ip"; CFLAGS=""
else
    dnl non-gcc flags - we probably need exact configuration triplets here.
    case "$host" in
    sparc-sun-solaris*)
	TRY_CFLAGS="$OPT_CFLAGS -xCC -fast -xO5"
	AC_TRY_CFLAGS([$TRY_CFLAGS $CFLAGS],[OPT_CFLAGS="$TRY_CFLAGS"]);;
    esac
fi

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_ALWAYS_INLINE
AC_C_RESTRICT
AC_C_BUILTIN_EXPECT
AC_C_BIGENDIAN
AC_C_VOLATILE
AC_TYPE_SIZE_T

builtin([include],[video/libvo/configure.incl])

AC_C_ATTRIBUTE_ALIGNED

AM_CONDITIONAL(OLDLIBRAW1394, test x$oldlibraw1394 = xtrue)

AM_CONFIG_HEADER(config.h)
dnl the line above should be replaced with the line below after upgrading to automake 1.7
dnl AC_CONFIG_HEADERS(config.h)
AC_CONFIG_FILES(Makefile audio/Makefile video/Makefile video/libvo/Makefile)
AC_OUTPUT