frmparaedit.frm

基于化工行业造气岗位的自动化监控系统

VERSION 5.00
Begin VB.Form frmParaEdit 
   BorderStyle     =   1  'Fixed Single
   Caption         =   "寻优微机参数下载"
   ClientHeight    =   1365
   ClientLeft      =   3570
   ClientTop       =   6585
   ClientWidth     =   3825
   Icon            =   "frmParaEdit.frx":0000
   LinkTopic       =   "寻优微机参数修改"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   1365
   ScaleWidth      =   3825
   Begin VB.CommandButton cmdLock 
      Height          =   375
      Left            =   120
      Style           =   1  'Graphical
      TabIndex        =   5
      ToolTipText     =   "当前状态：锁定"
      Top             =   960
      Visible         =   0   'False
      Width           =   615
   End
   Begin VB.CommandButton cmdParaView 
      Caption         =   "参数浏览&V"
      Height          =   375
      Left            =   1200
      TabIndex        =   6
      Top             =   960
      Width           =   1215
   End
   Begin VB.CommandButton cmdDownload 
      Caption         =   "下载&1"
      Height          =   285
      Index           =   0
      Left            =   1440
      TabIndex        =   4
      Top             =   360
      Width           =   1215
   End
   Begin VB.CommandButton cmdClose 
      Caption         =   "关闭&C"
      Height          =   375
      Left            =   2520
      TabIndex        =   3
      Top             =   960
      Width           =   1215
   End
   Begin VB.TextBox txtPara 
      Alignment       =   2  'Center
      BeginProperty DataFormat 
         Type            =   1
         Format          =   "0"
         HaveTrueFalseNull=   0
         FirstDayOfWeek  =   0
         FirstWeekOfYear =   0
         LCID            =   2052
         SubFormatType   =   1
      EndProperty
      Height          =   285
      Index           =   0
      Left            =   600
      TabIndex        =   2
      Text            =   "0"
      Top             =   360
      Width           =   615
   End
   Begin VB.Label lblID 
      Alignment       =   1  'Right Justify
      Caption         =   "1#炉"
      Height          =   255
      Index           =   0
      Left            =   0
      TabIndex        =   1
      Top             =   360
      Width           =   495
   End
   Begin VB.Label lblName 
      Alignment       =   2  'Center
      Caption         =   "吹风"
      Height          =   255
      Index           =   0
      Left            =   600
      TabIndex        =   0
      Top             =   120
      Width           =   615
   End
End
Attribute VB_Name = "frmParaEdit"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False

Private Sub cmdClose_Click()
    Unload Me
End Sub

Private Sub cmdDownload_Click(Index As Integer)
    Dim bytData(12) As Byte
    Dim CheckSum As Long
    Dim i As Long
    On Error Resume Next
    bytData(0) = 255
     
    bytData(1) = CheckRange(Val(txtPara(Index + 5 * StoveNumber).Text), 5, 0)    '排队
    CheckSum = CheckSum + bytData(1)
    
    bytData(2) = 1                                                               '命令
    CheckSum = CheckSum + bytData(2)
    
    bytData(3) = 0                                                                  '预留
    CheckSum = CheckSum + bytData(3)
    
    bytData(4) = CheckRange(Val(txtPara(Index).Text), 55, 30)                      '吹风
    CheckSum = CheckSum + bytData(4)
    
    bytData(5) = CheckRange(Val(txtPara(Index + 8 * StoveNumber).Text), 40, 0)     '回收
    CheckSum = CheckSum + bytData(5)

    bytData(6) = CheckRange(Val(txtPara(Index + 1 * StoveNumber).Text), 50, 23)    '上吹
    CheckSum = CheckSum + bytData(6)
    
    bytData(7) = CheckRange(Val(txtPara(Index + 9 * StoveNumber).Text), 100, 0)     '给料
    CheckSum = CheckSum + bytData(7)
    
    bytData(8) = CheckRange(Val(txtPara(Index + 7 * StoveNumber).Text), 2, 0)       '循环时间
    bytData(8) = bytData(8) + CheckRange(Val(txtPara(Index + 10 * StoveNumber).Text), 3, 0) * 16
    CheckSum = CheckSum + bytData(8)
    
    bytData(9) = CLng(Val(txtPara(Index + 4 * StoveNumber).Text) / 3)             '下温设定
    CheckSum = CheckSum + bytData(9)
    
    bytData(10) = CLng(Val(txtPara(Index + 3 * StoveNumber).Text) / 3)           '上温设定
    CheckSum = CheckSum + bytData(10)
    
    bytData(11) = CheckRange(Val(txtPara(Index + 6 * StoveNumber).Text), 4, 0)                      '上加氮
    bytData(11) = bytData(11) + CheckRange(Val(txtPara(Index + 11 * StoveNumber).Text), 4, 0) * 16  '下加氮
    CheckSum = CheckSum + bytData(11)
    
    bytData(12) = CheckSum Mod 256
    
        stoveMsg Trim(Stove(Index).ip), bytData
        With frmMessage
            .lblMsg = "参数正在下载中，请稍候……"
            .Show
        End With
        
        TimeDelay 600
        ParaEdit(Index) = True
End Sub

Private Sub cmdLock_Click()
    If blnLock = False Then
        If MsgBox("你确认要锁定参数吗？", vbQuestion + vbYesNo, ErrorTitle) = vbYes Then
            blnLock = True
            cmdLock.Picture = cmdLock.DownPicture
        End If
    Else
        'frmLogin.Show
    End If
End Sub

Private Sub cmdParaView_Click()
    frmParaView.Show
End Sub

Private Sub Form_Load()
    Dim RetVal As Long
    Dim i As Long, j As Long
    On Error Resume Next
    RetVal = SetParent(Me.hWnd, frmMain.hWnd)
    lblID(0).Caption = StoveStart & "#炉"
    Me.Caption = "寻优微机参数下载"
    For i = 1 To StoveNumber - 1
        Load lblID(i)
        With lblID(i)
            .Top = lblID(0).Top + i * (lblID(0).Height + 30)
            .Caption = i + StoveStart & "#炉"
            .Visible = True
        End With
    Next
    For i = 1 To paraNumber - 1
        Load lblName(i)
        With lblName(i)
            .Left = lblName(0).Left + i * lblName(0).Width
            .Caption = ReadInIFiles("Parameter", "Name" & CStr(i), "参数" & CStr(i), iniPaths + "system.ini")
            .Visible = True
        End With
    Next
    
    For i = 0 To paraNumber - 1
        For j = 0 To StoveNumber - 1
            If j <> 0 Or i <> 0 Then
                Load txtPara(i * StoveNumber + j)
            End If
            With txtPara(i * StoveNumber + j)
                .Top = txtPara(0).Top + j * txtPara(0).Height
                .Left = txtPara(0).Left + i * txtPara(0).Width
                .Visible = True
                If Stove(j).runstate = 1 Then
                    .ForeColor = RGB(0, 0, 255)
                Else
                    .ForeColor = RGB(255, 0, 0)
                End If
                If j Mod 2 = 1 Then
                    .BackColor = &H8000000F
                End If
            End With
            
        Next
    Next
    
    For i = 0 To StoveNumber - 1
        txtPara(i).Text = Stove(i).CF_Control
        txtPara(i + 1 * StoveNumber).Text = Stove(i).SC_Control
        txtPara(i + 2 * StoveNumber).Text = Stove(i).XC_Control
        txtPara(i + 2 * StoveNumber).Locked = True
'        If ReadInIFiles("Stove" & i + 1, "GiveDown", "False", iniPaths + "Stove.ini") Then
            txtPara(i + 3 * StoveNumber).Text = Stove(i).SXWD_Control
            txtPara(i + 3 * StoveNumber).Locked = False
'        Else
'            txtPara(i + 3 * StoveNumber).Text = 0
'            txtPara(i + 3 * StoveNumber).Locked = True
'        End If
        txtPara(i + 4 * StoveNumber).Text = Stove(i).XXWD_Control
        txtPara(i + 5 * StoveNumber).Text = Stove(i).Queue_Control
        txtPara(i + 6 * StoveNumber).Text = Stove(i).SJN_Control
        txtPara(i + 7 * StoveNumber).Text = Stove(i).CycleTime
        txtPara(i + 8 * StoveNumber).Text = Stove(i).HS_Control
        If paraNumber > 9 Then txtPara(i + 9 * StoveNumber).Text = Stove(i).GL_Control
        If paraNumber > 10 Then txtPara(i + 10 * StoveNumber).Text = Stove(i).GL_Count
        If paraNumber > 11 Then txtPara(i + 11 * StoveNumber).Text = Stove(i).XJN_Control
    Next
    cmdDownload(0).Left = txtPara(paraNumber * StoveNumber - 1).Left + txtPara(paraNumber * StoveNumber - 1).Width + 40
    If Stove(0).runstate = 1 And Not blnLock Then
        cmdDownload(0).Enabled = True
    Else
        cmdDownload(0).Enabled = False
    End If
    For i = 0 To StoveNumber - 1
        If i <> 0 Then Load cmdDownload(i)
        With cmdDownload(i)
            .Left = cmdDownload(0).Left
            .Caption = "下载-" & i + StoveStart
            .Top = txtPara(i).Top
            If Stove(i).runstate = 1 And Not blnLock Then
                cmdDownload(i).Enabled = True
            Else
                cmdDownload(i).Enabled = False
            End If
            .Visible = True
        End With
    Next
    
    CmdClose.Top = txtPara(paraNumber * StoveNumber - 1).Top + txtPara(paraNumber * StoveNumber - 1).Height + 200
    CmdClose.Left = cmdDownload(0).Left
    cmdParaView.Top = CmdClose.Top
    cmdParaView.Left = 800
    cmdLock.Top = CmdClose.Top
    Me.Height = CmdClose.Top + CmdClose.Height + 420
    Me.Width = CmdClose.Left + CmdClose.Width + 120
    Me.Show
End Sub

Private Sub txtPara_DblClick(Index As Integer)
    If txtPara(Index).Locked Then Exit Sub
    Set ControlLink = txtPara(Index)
    frmDataIn.txtNumber = txtPara(Index).Text
    frmDataIn.Show
End Sub