autoexec.bat

wicebootloader design in platform builder

@REM
@REM Copyright (c) Microsoft Corporation.  All rights reserved.
@REM
@REM
@REM Use of this source code is subject to the terms of the Microsoft end-user
@REM license agreement (EULA) under which you licensed this SOFTWARE PRODUCT.
@REM If you did not accept the terms of the EULA, you are not authorized to use
@REM this source code. For a copy of the EULA, please see the LICENSE.RTF on your
@REM install media.
@REM
@echo off
verify off
PROMPT $p$g

REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
REM !!                                               !!
REM !! MAKE SURE YOU SET THE RIGHT IRQ & IOBASE      !!
REM !! FOR YOUR NETCARD BELOW.                       !!
REM !!                                               !!
REM !! NET_IRQ can be specified in either hex or     !!
REM !! decimal digits (ie either as IRQ=E or IRQ=14).!!
REM !! A value of 0 for both NET_IRQ & NET_IOBASE    !!
REM !! requests that the first network card found on !!
REM !! the PCI bus should be used.                   !!
REM !!                                               !!
REM !! NET_IOBASE must be specified in Hex digits.   !!
REM !! A value of 0 for NET_IOBASE means to auto     !!
REM !! searchfor the PCI net card using the          !!
REM !! specified IRQ value.                          !!
REM !!                                               !!
REM !! NET_IP can be set to specify a static IP      !!
REM !! address or left blank to use DHCP to obtain   !!
REM !! an IP address.  Format of set should be:      !!
REM !!      set NET_IP=10.0.0.1                      !!
REM !!                                               !!
REM !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

set NET_IRQ=0
set NET_IOBASE=0
set NET_IP=192.168.1.6


if "%CONFIG%" == "CEPC_LOCAL"  goto CEPC_LOCAL
if "%CONFIG%" == "CEPC_1024"   goto CEPC_1024
if "%CONFIG%" == "CEPC_800"    goto CEPC_800
if "%CONFIG%" == "CEPC_640"    goto CEPC_640
if "%CONFIG%" == "CEPC_SERIAL" goto CEPC_SERIAL
if "%CONFIG%" == "VESATEST"    goto VESATEST
if "%CONFIG%" == "CLEAN"       goto CLEAN


:CEPC_LOCAL
REM #################################################################
REM     Launch LOADCEPC using a local NK.BIN image.

loadcepc/v /e:300:5 /l:800x600x16 c: nk.bin
goto END


:CEPC_1024
REM #################################################################
REM     Set RES=/L:1024x768x8 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:1024x768x8
goto WITHRES


:CEPC_800
REM #################################################################
REM     Set RES=/L:800x600x16 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:800x600x16
goto WITHRES


:CEPC_640
REM #################################################################
REM     Set RES=/L:640x480x32 for use with FLAT display driver.
REM
REM     Format
REM             /L:DXxDYxBPP[:PXxPY] in DECIMAL!!!!
REM

set RES=/L:640x480x32
goto WITHRES


:CEPC_SERIAL
REM #################################################################
REM     Launch LOADCEPC on SBoot for a serial port download.

loadcepc /v sboot.bin
goto END


:VESATEST
REM #################################################################
REM     Launch VESATEST program.  VESATEST will display the
REM     VESA BIOS Version number and list all of the available
REM     video modes that are supported by the FLAT driver.
REM
REM	Note: VESATEST.EXE is an internal tool that is provided AS-IS
REM	with no testing or support, hence use at your own risk. We do
REM	not provide any redistribution rights either.

vesatest
goto END


:WITHRES
REM #################################################################
REM     Here we actually Launch LOADCEPC using the RES, NET_IOBASE,
REM     and NET_IRQ env vars we just set above based on menu
REM     selections.

loadcepc /v /e:%NET_IOBASE%:%NET_IRQ%:%NET_IP% %RES% eboot.bin
goto END
loadcepc/v /e:300:5 /l:800x600x16 c: nk.bin

:CLEAN

:END