d12_hal.asm

利用sunplus16位单片机实现USB接口的全套技术资料

// =========================================
// 文件名称：D12_HAL.asm
// 功能描述：PDIUSBD12物理层
// 维护记录：modified by liuxue v1.0 2007-03-15
// =========================================
.include D12_CONFIG.inc

.public _D12_Initial
.public _D12_InitWrite
.public _D12_InitRead
.public _D12_Read 
.public _D12_Write

.code
// =========================================
// 函数：void D12_Initial(void)
// 描述：初始化PDIUSBD12的I/O和中断，复位PDIUSBD12
// 参数：无
// 返回：无
// =========================================
_D12_Initial:
	push r1 to [SP]
	
	r1 = [P_USB_D_Dir]
	r1 &= ~D12_DATA_MASK
	r1 |= 0x0003
	[P_USB_D_Dir] = r1
	r1 = [P_USB_D_Attrib]
	r1 &= ~D12_DATA_MASK
	r1 |= 0x0003
	[P_USB_D_Attrib] = r1
	r1 = [P_USB_D_Buffer]
	r1 |= D12_DATA_MASK
	[P_USB_D_Buffer] = r1
	
	r1 = [P_USB_C_Dir]
	r1 |= D12_CS_MASK | D12_ALE_MASK |D12_WR_MASK | D12_RD_MASK | D12_RESET_MASK
	r1 &= ~D12_INT_MASK
	[P_USB_C_Dir] = r1
	r1 = [P_USB_C_Attrib]
	r1 |= D12_CS_MASK | D12_ALE_MASK | D12_WR_MASK | D12_RD_MASK | D12_RESET_MASK
	r1 &= ~D12_INT_MASK
	[P_USB_C_Attrib] = r1

	r1 = [P_USB_C_Buffer]
	r1 |= D12_WR_MASK | D12_RD_MASK | D12_INT_MASK
	r1 &= ~D12_CS_MASK
	r1 &= ~D12_RESET_MASK
	[P_USB_C_Buffer] = r1
	call _D12_Delay					// 等待总线复位，5898307cycle = 120ms

	r1 = [P_USB_C_Buffer]
	r1 |= D12_RESET_MASK
	[P_USB_C_Buffer] = r1
	
	r1 = [P_INT_Ctrl_New]
.IF D12_INT_BIT == 2
	r1 |= C_IRQ3_EXT1				// 使能外部中断1，调用D12中断服务程序
.ELSE
	r1 |= C_IRQ3_EXT2				// 使能外部中断2，调用D12中断服务程序
.ENDIF	
	[P_INT_Ctrl_New] = r1

	IRQ ON
	pop r1 from [SP]
	retf

// =========================================
// 函数：void D12_InitWrite(void)
// 描述：初始化写PDIUSBD12
// 参数：无
// 返回：无
// =========================================
_D12_InitWrite:
	push r1 to [SP]
	
	r1 = [P_USB_D_Dir]
	r1 |= D12_DATA_MASK
	[P_USB_D_Dir] = r1
	r1 = [P_USB_D_Attrib]
	r1 |= D12_DATA_MASK
	[P_USB_D_Attrib]  = r1
	r1 = [P_USB_D_Buffer]
	r1 |= D12_DATA_MASK
	r1 = [P_USB_D_Buffer]
	
	r1 = [P_USB_C_Buffer]
	r1 |= D12_WR_MASK | D12_RD_MASK | D12_INT_MASK
	r1 &= ~D12_CS_MASK
	[P_USB_C_Buffer] = r1
	
	pop r1 from [SP]
	retf

// =========================================
// 函数：void D12_InitRead()
// 描述：初始化读PDIUSBD12
// 参数：无
// 返回：无
// =========================================
_D12_InitRead:
	push r1 to [SP]
	
	r1 = [P_USB_D_Dir]
	r1 |= D12_DATA_MASK
	[P_USB_D_Dir] = r1
	r1 = [P_USB_D_Attrib]
	r1 |= D12_DATA_MASK
	[P_USB_D_Attrib]  = r1
	r1 = [P_USB_D_Buffer]
	r1 |= D12_DATA_MASK
	r1 = [P_USB_D_Buffer]
	
	r1 = [P_USB_C_Buffer]
	r1 |= D12_WR_MASK | D12_RD_MASK | D12_INT_MASK
	r1 &= ~D12_CS_MASK
	[P_USB_C_Buffer] = r1
	
	pop r1 from [SP]
	retf

// =========================================
// 函数：void D12_Read()
// 描述：从PDIUSBD12读数据
// 参数：无
// 返回：r1
// =========================================
_D12_Read:
	push r2,r3 to [SP]
	
	r3 = [P_USB_C_Buffer]
	r3 &= ~D12_CS_MASK
	r3 &= ~D12_RD_MASK
	r3 |= D12_WR_MASK
	[P_USB_C_Buffer] = r3
	nop
	
	r1 = [P_USB_D_Data]
.IF D12_DATA_BYTE == 1	
	r1 = r1 lsr 4
	r1 = r1 lsr 4
.ENDIF	
	r2 = [P_USB_C_Buffer]
	r2 &= ~D12_CS_MASK
	r2 |= D12_RD_MASK
	[P_USB_C_Buffer] = r2

	pop r2,r3 from [SP]
	retf

// =========================================
// 函数：void D12_Write(unsigned int D_or_C_Addr, unsigned int Data_or_Command)
// 描述：向PDIUSBD12写数据或命令
// 参数：D_or_C_Addr: 地址参数；Data_or_Command：命令或数据参数
// 返回：无
// =========================================
_D12_Write:
	push bp to [SP]
	bp = SP + 1
	push r1,r2 to [SP]
	r1 = [bp+3]
	r2 = [bp+4]
	call D12_Write
	pop r1,r2 from [SP]
	pop bp from [SP]
	retf
D12_Write:
	push r1,r3 to [SP]
.IF D12_DATA_BYTE == 1	
	r1 = r1 lsl 4
	r1 = r1 lsl 4
	r2 = r2 lsl 4
	r2 = r2 lsl 4
.ENDIF
	r3 = [P_USB_D_Buffer]
	r3 &= ~D12_DATA_MASK
	r1 |= r3
	[P_USB_D_Buffer] = r1

	r1 = [P_USB_C_Buffer]
	r1 &= ~D12_CS_MASK
	r1 |= D12_ALE_MASK
	[P_USB_C_Buffer] = r1
	
	r1 = [P_USB_C_Buffer]		// 地址锁存
	r1 &= ~D12_ALE_MASK
	[P_USB_C_Buffer] = r1
	
	r1 = [P_USB_D_Buffer]
	r1 &= ~D12_DATA_MASK
	r2 |= r1
	[P_USB_D_Buffer] = r2
	
	r1 = [P_USB_C_Buffer]
	r1 &= ~D12_CS_MASK
	r1 &= ~D12_WR_MASK
	r1 |= D12_RD_MASK
	[P_USB_C_Buffer] = r1
	
	r1= [P_USB_C_Buffer]
	r1 |= D12_WR_MASK
	[P_IOB_Buffer] = r1
	
	pop r1,r3 from [SP]
	retf

// =========================================
// 函数：void D12_Delay(void)
// 描述：延时函数
// 参数：无
// 返回：无
// =========================================
_D12_Delay:
	push r1, r2 to [SP]
	r2 = 0x000f
?Loop1:
	r1 = 0xffff
?Loop2:
	r1 -= 1
	jnz	?Loop2
	r1 = 0x01
	[P_Watchdog_Clear] = r1
	r2 -= 1
	jnz ?Loop1
	pop r1, r2 from [SP]
	retf