crc32.pas

CRC校验算法 CRC校验算法 CRC校验算法 CRC校验算法

/////////////////////////////////////////////////////
//  Unit crc32: Basic functions for crc32 calculations
//
//  Usage:
//  *  procedure CalcCRC(var CRC32:Cardinal;
//                    Buffer: Pointer; Length: Integer);
//              to calculate the CRC32 of data in buffer.
//              Length is the buffer size, MAKE SURE YOU
//              PROVIDE THE BUFFER SIZE, the program doesn't
//              check it is correct.
//              To start a new calculation call InitCRC()
//              and pass a variable to initialize it to 0.
//              To continue a calculation pass the last
//              result as parameter.
//
//     Define CRC_STREAM_SUPPORT when compiling unit
//     to activate StreamCRC32 functions.
//     This will require Classes unit. It is deactivated
//     so that the program is smaller when Classes
//     aren't needed.
//
//  *  function StreamCRC32(const Stream: TStream;
//          var CRC: Cardinal; [InitCRC: boolean;]
//          [Progress: TProgress]): Integer;
//        This will calculate the CRC of the Stream starting
//        at 0 and reading to the end of the stream. You may
//        set InitCRC to false to continue from another
//        stream. TProgress is a procedure(Percentage: byte);
//        Progress will be called each time the buffer is
//        empty, so you may wish to lower buffersize for
//        precise reports.
//
//     DEFINE CRC_FILE_IO_SUPPORT to add File IO functions.
//     No additional units are required.

//  *  function FileCRC32(const Filename: string;
//               [Progress: TProgress]): cardinal;
//        returns the CRC32 of the file. No exceptions are
//        handled, no error codes passed. Use progress as
//        described in StreamCRC32
//
//  *  The variable MaxCRCBufferSize defines the maximum
//     memory to allocate when reading streams or files.
//     By default this is 1 MegaByte. This is not safe
//     when many units access it.
//
//  Andrew Koupparis, 2003
//  http://www34.brinkster.com/dizzyk/
///////////////////////////////////////////////////////

unit crc32;

//Remove dot (.) to activate
{.$DEFINE CALCULATE_CRC_TABLE} //calculate on init
{.$DEFINE CRC_STREAM_SUPPORT}  //streams support
{$DEFINE CRC_FILE_IO_SUPPORT}  //file support

//General:
//Polynomials in binary are represented with highest
//power in the right-most (least significant) digit
//
//Addition/substraction is xor
//multiply by x is shr 1
//
//CRC32 uses 1+x+x^2+x^4+x^5+x^7+x^8+x^10+x^11+x^12+x^16+x^22+x^23+x^26+x^32

interface
// Streams Support:
{$IFDEF CRC_STREAM_SUPPORT}
uses Classes;

type TProgress = procedure (Percentage: Byte);

function StreamCRC32(const Stream: TStream; var CRC: Cardinal): Integer; overload;
function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                     const InitCRC:boolean): Integer; overload;
function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                     const Progress: TProgress): Integer; overload;
function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                     const InitCRC:boolean;
                     const Progress: TProgress): Integer; overload;
//These functions return 0 if successfull, -1 if not


var MaxCRCBufferSize: Integer = $FFFFF; //1 MegaByte
{$ENDIF} //CRC_STREAM_SUPPORT

{$IFDEF CRC_FILE_IO_SUPPORT}  //file support
  {$IFNDEF CRC_STREAM_SUPPORT} //BufferSize, Progress not defined
    var MaxCRCBufferSize: Integer = $FFFFF; //1 MegaByte
    type TProgress = procedure (Percentage: Byte);
  {$ENDIF} //CRC_STREAM_SUPPORT
function FileCRC32(const Filename: string): cardinal; overload;
function FileCRC32(const Filename: string;
                   const Progress: TProgress): cardinal; overload;
{$ENDIF} //CRC_FILE_IO_SUPPORT

// Basic functions:
procedure CalcCRC(var CRC32:Cardinal; Buffer: Pointer; Length: Integer);
procedure InitCRC(out CRC32:Cardinal); //we start with zero, but anyway...

//Error control
var CRCError: Boolean; //True if last stream/file operation failed

implementation

{$IFDEF CALCULATE_CRC_TABLE}
//We hold all possible values here
var CRCArray: array[0..255] of Cardinal;

//Table procedures

procedure CalculateCRCs; //Calculate all possible values
const
 //p is polynomial x^32 mod 1+x+x^2+...+x^26+x^32
 p: array[0..13] of integer =(0,1,2,4,5,7,8,10,11,12,16,22,23,26);
var i,q: byte;
    c,s: Cardinal;
begin
 //s is x^32 mod p
 s:=0;
 for i:=0 to 13 do s:=s xor (1 shl (31-p[i])); //writing digits to s
 for q:=0 to 255 do begin //calculate all possible CRCs
  c:=0; //c is CRC
  for i:=0 to 7 do begin  //q is the byte, we check every bit
   if (c and 1)=0 then c:=c shr 1 else  //multiply by x, mod p
                        c:=(c shr 1) xor s;
   if (q and (1 shl i))>0 then c:=c xor s; //if bit is 1, xor s
  end;
  CRCArray[q]:=c;
 end;
end;

{$ELSE}

//We hold all possible values here
const CRCArray: array[0..255] of Cardinal =

($00000000, $77073096, $EE0E612C, $990951BA, $076DC419, $706AF48F,
 $E963A535, $9E6495A3, $0EDB8832, $79DCB8A4, $E0D5E91E, $97D2D988,
 $09B64C2B, $7EB17CBD, $E7B82D07, $90BF1D91, $1DB71064, $6AB020F2,
 $F3B97148, $84BE41DE, $1ADAD47D, $6DDDE4EB, $F4D4B551, $83D385C7,
 $136C9856, $646BA8C0, $FD62F97A, $8A65C9EC, $14015C4F, $63066CD9,
 $FA0F3D63, $8D080DF5, $3B6E20C8, $4C69105E, $D56041E4, $A2677172,
 $3C03E4D1, $4B04D447, $D20D85FD, $A50AB56B, $35B5A8FA, $42B2986C,
 $DBBBC9D6, $ACBCF940, $32D86CE3, $45DF5C75, $DCD60DCF, $ABD13D59,
 $26D930AC, $51DE003A, $C8D75180, $BFD06116, $21B4F4B5, $56B3C423,
 $CFBA9599, $B8BDA50F, $2802B89E, $5F058808, $C60CD9B2, $B10BE924,
 $2F6F7C87, $58684C11, $C1611DAB, $B6662D3D, $76DC4190, $01DB7106,
 $98D220BC, $EFD5102A, $71B18589, $06B6B51F, $9FBFE4A5, $E8B8D433,
 $7807C9A2, $0F00F934, $9609A88E, $E10E9818, $7F6A0DBB, $086D3D2D,
 $91646C97, $E6635C01, $6B6B51F4, $1C6C6162, $856530D8, $F262004E,
 $6C0695ED, $1B01A57B, $8208F4C1, $F50FC457, $65B0D9C6, $12B7E950,
 $8BBEB8EA, $FCB9887C, $62DD1DDF, $15DA2D49, $8CD37CF3, $FBD44C65,
 $4DB26158, $3AB551CE, $A3BC0074, $D4BB30E2, $4ADFA541, $3DD895D7,
 $A4D1C46D, $D3D6F4FB, $4369E96A, $346ED9FC, $AD678846, $DA60B8D0,
 $44042D73, $33031DE5, $AA0A4C5F, $DD0D7CC9, $5005713C, $270241AA,
 $BE0B1010, $C90C2086, $5768B525, $206F85B3, $B966D409, $CE61E49F,
 $5EDEF90E, $29D9C998, $B0D09822, $C7D7A8B4, $59B33D17, $2EB40D81,
 $B7BD5C3B, $C0BA6CAD, $EDB88320, $9ABFB3B6, $03B6E20C, $74B1D29A,
 $EAD54739, $9DD277AF, $04DB2615, $73DC1683, $E3630B12, $94643B84,
 $0D6D6A3E, $7A6A5AA8, $E40ECF0B, $9309FF9D, $0A00AE27, $7D079EB1,
 $F00F9344, $8708A3D2, $1E01F268, $6906C2FE, $F762575D, $806567CB,
 $196C3671, $6E6B06E7, $FED41B76, $89D32BE0, $10DA7A5A, $67DD4ACC,
 $F9B9DF6F, $8EBEEFF9, $17B7BE43, $60B08ED5, $D6D6A3E8, $A1D1937E,
 $38D8C2C4, $4FDFF252, $D1BB67F1, $A6BC5767, $3FB506DD, $48B2364B,
 $D80D2BDA, $AF0A1B4C, $36034AF6, $41047A60, $DF60EFC3, $A867DF55,
 $316E8EEF, $4669BE79, $CB61B38C, $BC66831A, $256FD2A0, $5268E236,
 $CC0C7795, $BB0B4703, $220216B9, $5505262F, $C5BA3BBE, $B2BD0B28,
 $2BB45A92, $5CB36A04, $C2D7FFA7, $B5D0CF31, $2CD99E8B, $5BDEAE1D,
 $9B64C2B0, $EC63F226, $756AA39C, $026D930A, $9C0906A9, $EB0E363F,
 $72076785, $05005713, $95BF4A82, $E2B87A14, $7BB12BAE, $0CB61B38,
 $92D28E9B, $E5D5BE0D, $7CDCEFB7, $0BDBDF21, $86D3D2D4, $F1D4E242,
 $68DDB3F8, $1FDA836E, $81BE16CD, $F6B9265B, $6FB077E1, $18B74777,
 $88085AE6, $FF0F6A70, $66063BCA, $11010B5C, $8F659EFF, $F862AE69,
 $616BFFD3, $166CCF45, $A00AE278, $D70DD2EE, $4E048354, $3903B3C2,
 $A7672661, $D06016F7, $4969474D, $3E6E77DB, $AED16A4A, $D9D65ADC,
 $40DF0B66, $37D83BF0, $A9BCAE53, $DEBB9EC5, $47B2CF7F, $30B5FFE9,
 $BDBDF21C, $CABAC28A, $53B39330, $24B4A3A6, $BAD03605, $CDD70693,
 $54DE5729, $23D967BF, $B3667A2E, $C4614AB8, $5D681B02, $2A6F2B94,
 $B40BBE37, $C30C8EA1, $5A05DF1B, $2D02EF8D);

{$ENDIF} //CALCULATE_CRC_TABLE

//Calculation procedures

procedure InitCRC(out CRC32:Cardinal); //we start with zero
begin
CRC32:=0;
end;

procedure CalcCRC(var CRC32:Cardinal; Buffer: Pointer; Length: Integer);
var i:integer; //ubiquitous counter :)
    p:^Byte;
begin
if Length=0 then Exit;
p:=Buffer;
//Initialization to $FFFFFFFF. If this is an update, then we
//invert the finalization. So, no init/update/finish required.
CRC32:=not CRC32;
//OK, let's scan the buffer:
//we do:
//the right 8-bits of crc xor current_byte to get the index
//shift right by 8bits, xor the array value.
for i:=0 to Length-1 do begin
 CRC32:= (CRC32 shr 8) xor CRCArray[(CRC32 xor p^) and $ff];
 PChar(p):=PChar(p)+1;
 end;
//If we aren't finished, this will be undone with the next operation
CRC32:=not CRC32;
end;

{$IFDEF CRC_STREAM_SUPPORT}

function StreamCRC32(const Stream: TStream; var CRC: Cardinal): Integer;
begin
Result:=StreamCRC32(Stream,CRC,True,nil);
end;

function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                     const Progress: TProgress): Integer;
begin
Result:=StreamCRC32(Stream,CRC,True,Progress);
end;

function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                     const InitCRC:boolean): Integer;
begin
Result:=StreamCRC32(Stream,CRC,InitCRC,nil);
end;

function StreamCRC32(const Stream: TStream; var CRC: Cardinal;
                   const InitCRC:boolean; const Progress: TProgress): Integer;
var Buffer: PChar;
    Count: Integer;
    Size: Integer;
    TotalSize: Integer;
begin
Result:=-1; CRCError:=True; //Failure, unless changed latter
Size:=Stream.Size; TotalSize:=Size;
if Size=0 then Exit;
if MaxCRCBufferSize<Size then Size:=MaxCRCBufferSize;
GetMem(Buffer,Size);
Stream.Position:=0; //Read from start
if InitCRC then CRC:=0;
try
 if Assigned(Progress) then Progress(0);
 repeat
  Count:=Stream.Read(Buffer^,Size);
  CalcCRC(CRC,Buffer,Count);
  if Assigned(Progress) then Progress(Round((Stream.Position/TotalSize)*100));
 until Count<Size;
 Result:=0; CRCError:=False; //Succeded!
finally
 FreeMem(Buffer);
end;
end;

{$ENDIF} //CRC_STREAM_SUPPORT

{$IFDEF CRC_FILE_IO_SUPPORT}  //file support

function FileCRC32(const Filename: string): cardinal;
begin
Result:=FileCRC32(Filename,nil);
end;

function FileCRC32(const Filename: string;
                   const Progress: TProgress): cardinal;
var F: File of byte;
    buffer: PChar;
    length: integer;
    totalsize:integer;
    bsize: integer; //buffersize
    old_mode:byte;
begin
 CRCError:=False;
 AssignFile(F,Filename);
 old_mode:=FileMode;
 FileMode:=0; //Open-read
 Reset(F);
 FileMode:=old_mode;
 BSize:=FileSize(F); TotalSize:=BSize;
 if BSize=0 then begin CRCError:=True; Result:=0; CloseFile(F); Exit; end;
 if BSize>MaxCRCBufferSize then BSize:=MaxCRCBufferSize;
 GetMem(buffer,BSize);
 try
  Result:=0;
  if Assigned(Progress) then Progress(0);
  repeat
   BlockRead(F,buffer^,BSize,length);
   CalcCRC(Result,buffer,length);
   if Assigned(Progress) then Progress(Round((FilePos(F)/TotalSize)*100));
  until (length<BSize);
 finally
  CloseFile(F);
  FreeMem(buffer);
 end;
end;

{$ENDIF} //CRC_FILE_IO_SUPPORT

initialization
{$IFDEF CALCULATE_CRC_TABLE}
CalculateCRCs;
{$ENDIF}
end.