formmanagemain.asp

印刷物の発注、在庫管理、出庫処理を一元管理

<%
'/************************************
'/*嵼屔堦棗儊僀儞僋儔僗
'/************************************
Class FormManageMain
	Dim l_CutilObject
	Dim l_CommonObject
	Dim l_PgCtrlObject
	Dim l_DBObject
	Dim l_Page
	Dim l_RsPageCount
	Dim l_RsRecordCount
	Dim l_FormManageMdlObject
	Dim l_Basp

	'/********************************************
	'/* 弶婜張棟
	'/********************************************
	Public Function Init()
		Set l_CutilObject = New CharUtil
		Set l_CommonObject = New Common
		Set l_PgCtrlObject = New PageControl
		Set l_FormManageMdlObject = New FormManageMdl
		Set l_Basp = Server.CreateObject("basp21")

		Call l_CommonObject.SearchSession
		'DB僐僱僋僔儑儞庢摼
		Set l_DBObject = New DbAccess
		Call l_DBObject.ProcConnection(DSN,USERID,PASSWD)

		'僙僢僔儑儞傛傝儐乕僓乕忣曬庢摼
		l_FormManageMdlObject.l_SystemId = Session("User").Item("SYSTEM_ID")
		l_FormManageMdlObject.l_CompanyId = Session("User").Item("COMPANY_ID")
		l_FormManageMdlObject.l_UserName = Session("User").Item("NAME")

		'尰嵼偺儁乕僕悢愝掕(僷儔儊乕僞偵儁乕僕偑側偗傟偽1傪愝掕)
		l_Page = Request.QueryString("page")
		If l_Page = "" Then
			l_Page = 1
		End If
	End Function

	'/********************************************
	'/* 嵼屔堦棗儗僐乕僪拪弌
	'/* return丗Scripting.Dictionary 昞帵儕僗僩
	'/********************************************
	Public Function GetList()
		Dim l_FormManageObject
		Dim l_RecordSet
		Dim l_retList,l_retRec,l_cnt
		Dim l_Result
		l_Result = True

		'擖椡抣愝掕
		Call l_CommonObject.SetSearchInfoSession("WareStockList")

		'僙僢僔儑儞忣曬懚嵼僠僃僢僋
		If IsObject(Session("WareStockList")) Then
			l_FormManageMdlObject.l_SListCd = Replace(l_CutilObject.html_chg(l_Basp,Session("WareStockList").Item("list_cd")),"""","&quot;")
			l_FormManageMdlObject.l_SListEda = Replace(l_CutilObject.html_chg(l_Basp,Session("WareStockList").Item("list_eda")),"""","&quot;")
			l_FormManageMdlObject.l_SListName = Session("WareStockList").Item("list_name")
			l_FormManageMdlObject.l_STemplate = Session("WareStockList").Item("template")
			l_FormManageMdlObject.l_SCategory = Session("WareStockList").Item("category")
			l_FormManageMdlObject.l_SSection = Session("WareStockList").Item("section")
			l_FormManageMdlObject.l_SStockStatus1 = Session("WareStockList").Item("stock_status1")
			l_FormManageMdlObject.l_SStockStatus2 = Session("WareStockList").Item("stock_status2")
			l_FormManageMdlObject.l_SStockStatus3 = Session("WareStockList").Item("stock_status3")
			l_FormManageMdlObject.l_SortKey = Session("WareStockList").Item("sortkey")
			l_FormManageMdlObject.l_SortDesc = Session("WareStockList").Item("sortdesc")

			'擖椡僠僃僢僋
			l_Result = CheckInput(l_FormManageMdlObject)
		Else
			'敪拲揰愗傟
			l_FormManageMdlObject.l_SStockStatus2 = STSTS_ODR_POINT
			'嬞媫敪拲揰愗傟
			l_FormManageMdlObject.l_SStockStatus3 = STSTS_URGODR_POINT
			l_FormManageMdlObject.l_SortKey = SORT_KEY1
			l_FormManageMdlObject.l_SortDesc = FLG_ON
		End If

		Set l_retList = CreateObject("Scripting.Dictionary")

		If l_Result Then
			'DB傛傝忣曬庢摼
			Set l_FormManageObject = New FormManageMaster
			Set l_RecordSet = l_FormManageObject.SearchStockBase(l_DBObject,l_FormManageMdlObject,Session("WareStockList"))
			'儗僐乕僪曇廤
			l_cnt = 0
			Do Until l_RecordSet.eof
				Set l_retRec = EditRec(l_RecordSet)
				l_retList.add CStr(l_cnt), l_retRec
				l_cnt = l_cnt + 1
				l_RecordSet.MoveNext
			Loop

			'儁乕僕惂屼梡偺僒僀僘丄審悢傪愝掕
			l_RsPageCount = Fix(l_retList.Count / 20 + 0.99)		'儁乕僕僒僀僘愝掕
			l_RsRecordCount = l_retList.Count	'儗僐乕僪審悢愝掕
		End If

		Set GetList = l_retList
	End Function

	'/********************************************
	'/* 儗僐乕僪曇廤
	'/* param丗l_rs 	侾儗僐乕僪
	'/* return丗曇廤寢壥
	'/********************************************
	Public Function EditRec(l_rs)
		Dim l_rec
		Set l_rec = New FormManageMdl

		l_rec.l_ListCd = l_rs.Fields.Item("LIST_CD")
		l_rec.l_ListEda = l_rs.Fields.Item("LIST_EDA")
		l_rec.l_ListName = l_rs.Fields.Item("LIST_NAME")
		l_rec.l_StockNum = l_rs.Fields.Item("STOCK_NUM")
		l_rec.l_OrderPoint = l_rs.Fields.Item("ORDER_POINT")
		l_rec.l_ListUnit = l_rs.Fields.Item("LIST_UNIT")
		l_rec.l_SectionName = l_rs.Fields.Item("SECTION_NAME")
		l_rec.l_Class = l_rs.Fields.Item("CLASS1")
		l_rec.l_StockStatus = l_rs.Fields.Item("STOCK_STATUS")
		l_rec.l_SecretFlg = l_rs.Fields.Item("SECRET_FLG")
		l_rec.l_DspListNo = l_rec.l_ListCd & "-" & l_rec.l_ListEda
		'l_rec.l_DspListUnit = l_CommonObject.GetCodeName(l_DBObject,CD_LIST_UNIT,l_rec.l_ListUnit)
		l_rec.l_DspListUnit = l_rs.Fields.Item("LIST_UNIT_NAME")
		'l_rec.l_DspClass = l_CommonObject.GetCodeName(l_DBObject,CD_CLASS1,l_rec.l_Class)
		l_rec.l_DspClass = l_rs.Fields.Item("CODE_NAME")
		'l_rec.l_DspStockStatus = l_CommonObject.GetCodeName(l_DBObject,CD_STOCK_STATUS,l_rec.l_StockStatus)
		l_rec.l_DspStockStatus = l_rs.Fields.Item("STOCK_STATUS_NAME")

		Set EditRec = l_rec
	End Function

	'/********************************************
	'/* 僜乕僩帪偺俫俿俵俴儕儞僋庢摼
	'/* param丗String l_sortkey 僜乕僩僉乕
	'/* return丗String 俫俿俵俴暥帤楍
	'/********************************************
	Public Function GetSortParmHtml(l_sortkey,l_oldSortDesc)
		Dim l_retStr
		Dim l_newSortDesc

		'僜乕僩弴偺愝掕(徃弴佁崀弴愗傝懼偊)
		If l_oldSortDesc = FLG_ON Then
			l_newSortDesc = FLG_OFF		'崀弴仺徃弴
		Else 
			l_newSortDesc =  FLG_ON		'徃弴仺崀弴
		End If

		'僷儔儊乕僞亖僜乕僩僉乕丄専嶕忦審
		l_retStr = "sessave=" & "2"  &_
			"&sortkey=" & l_sortkey &_
			"&sortdesc=" & l_newSortDesc 
		GetSortParmHtml = l_retStr
	End Function

	'/*************************************
	'/ 堦棗僿僢僟
	'/ return:html
	'/*************************************
	Public Function ListHeadDsp
		Dim l_html
		Dim l_CRLF
		Dim l_sortdsp

		l_CRLF = Chr(13) & Chr(10)

		'僜乕僩弴丂徃弴丗(仾)丂崀弴丗(伀)
		If l_FormManageMdlObject.l_SortDesc = FLG_ON Then
			l_sortdsp = "(伀)"
		Else
			l_sortdsp = "(仾)"
		End If

		l_html = "<tr align=""center""> " & l_CRLF &_
				 "<td class=""txt_m"" width=""95"" height=""20"" bgcolor=""#666666"">" &_
				 "<a href=""stock_list.asp?" & GetSortParmHtml("2",l_FormManageMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">挔昜斣崋"

		'挔昜斣崋偱僜乕僩偺応崌
		If l_FormManageMdlObject.l_SortKey = "2" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a></td>" & l_CRLF &_
				 "<td class=""txt_m"" height=""20"" bgcolor=""#666666"">" &_
				 "<a href=""stock_list.asp?" & GetSortParmHtml("3",l_FormManageMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">挔昜柤"

		'挔昜柤偱僜乕僩偺応崌
		If l_FormManageMdlObject.l_SortKey = "3" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a></td>" & l_CRLF &_
				 "<td class=""txt_m"" height=""20"" width=""120"" bgcolor=""#666666"">" &_
				 "<a href=""stock_list.asp?" & GetSortParmHtml("4",l_FormManageMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">嵼屔悢"

		'嵼屔悢偱僜乕僩偺応崌
		If l_FormManageMdlObject.l_SortKey = "4" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a>"
		l_html = l_html & "<font color=""#FFFFFF"">/</font>" &_
				"<a href=""stock_list.asp?" & GetSortParmHtml("5",l_FormManageMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">敪拲揰"

		'敪拲揰偱僜乕僩偺応崌
		If l_FormManageMdlObject.l_SortKey = "5" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a></td>" & l_CRLF &_
				 "<td class=""txt_m"" height=""20"" width=""120"" bgcolor=""#666666"">" &_
				 "<font color=""#FFFFFF"">挔昜忣曬</font></td>" & l_CRLF &_
        		 "</tr>" & l_CRLF 

		ListHeadDsp = l_html

	End Function

	'/********************************************
	'/* 僋儘乕僘
	'/********************************************
	Public Function Close
		Call l_DBObject.CloseRecodeset
		Call l_DBObject.CloseConnection
	End Function

	'/********************************************
	'/* 擖椡僠僃僢僋
	'/* param:専嶕忦審曐帩僋儔僗
	'/* return:boolean
	'/********************************************
	Public Function CheckInput(Mdl)
		Dim l_Index
		Dim l_CharUtil
		Dim l_CheckUtil

		CheckInput = True

		Set l_CharUtil = New CharUtil
		Set l_CheckUtil = New CheckUtil

		l_Index = 0

		'挔昜斣崋僠僃僢僋
		If Mdl.l_SListCd <> "" Then
			If Not l_CheckUtil.IsNumericAlpha(Mdl.l_SListCd) Then
				l_ErrArray(l_Index) = IG11001E
				l_Index = l_Index + 1
				CheckInput = False
			End If
		End If

		'挔昜巬斣僠僃僢僋
		If Mdl.l_SListEda <> "" Then
			If l_CheckUtil.number_chk(l_Basp,Mdl.l_SListEda) = 0 Then
				l_ErrArray(l_Index) = IG11021E
				l_Index = l_Index + 1
				CheckInput = False
			End If
		End If

		'挔昜斣崋丄巬斣憡娭僠僃僢僋丂2006/02/28
		If Mdl.l_SListEda <> "" And _
			(Mdl.l_SListCd = "" Or _
			IsNull(Mdl.l_SListCd)) Then
			l_ErrArray(l_Index) = IG11022E
			l_Index = l_Index + 1
			CheckInput = false
		End If

		'挔昜柤慡妏曄姺
		If Mdl.l_SListName <> "" Then
			Mdl.l_SListName = l_CharUtil.chg_HantoZen(Mdl.l_SListName)
		End If
	End Function
End Class

'/************************************
'/*専嶕忦審曐帩僋儔僗
'/************************************
Class FormManageMdl
	Dim l_SystemId
	Dim l_CompanyId
	Dim l_UserName
	Dim l_SortKey
	Dim l_SortDesc

	'専嶕忦審擖椡棑崁栚
	Dim l_SListCd
	Dim l_SListEda
	Dim l_SListName
	Dim l_STemplate
	Dim l_SCategory
	Dim l_SSection
	Dim l_SStockStatus1
	Dim l_SStockStatus2
	Dim l_SStockStatus3

	'昞帵崁栚
	Dim l_ListCd
	Dim l_ListEda
	Dim l_ListName
	Dim l_StockNum
	Dim l_OrderPoint
	Dim l_ListUnit
	Dim l_SectionName
	Dim l_Class
	Dim l_StockStatus
	Dim l_SecretFlg

	Dim l_DspListNo
	Dim l_DspListUnit
	Dim l_DspClass
	Dim l_DspStockStatus
End Class
%>