postlistmain.asp

印刷物の発注、在庫管理、出庫処理を一元管理

<%
'/************************************
'/*晹栧堦棗儊僀儞僋儔僗
'/************************************
Class PostListMain
	Dim l_CommonObject
	Dim l_PgCtrlObject
	Dim l_DBObject
	Dim l_Page
	Dim l_RsPageCount
	Dim l_RsRecordCount
	Dim l_PostMdlObject
	Dim l_CharUtil
	Dim l_basp

	'/********************************************
	'/* 弶婜張棟
	'/********************************************
	Public Function Init()
		Set l_CommonObject = New Common
		Set l_PgCtrlObject = New PageControl
		Set l_PostMdlObject = New PostListMdl
		Set l_CharUtil = New CharUtil
		Set l_basp = Server.CreateObject("basp21")

		Call l_CommonObject.SearchSession()

		'DB僐僱僋僔儑儞庢摼
		Set l_DBObject = New DbAccess
		Call l_DBObject.ProcConnection(DSN,USERID,PASSWD)

		'僙僢僔儑儞傛傝儐乕僓乕忣曬庢摼
		l_PostMdlObject.l_SystemId = Session("User").Item("SYSTEM_ID")
		l_PostMdlObject.l_CompanyId = Session("User").Item("COMPANY_ID")
		l_PostMdlObject.l_UserName = Session("User").Item("NAME")

		'尰嵼偺儁乕僕悢愝掕(僷儔儊乕僞偵儁乕僕偑側偗傟偽1傪愝掕)
		l_Page = Request.QueryString("page")
		If l_Page = "" Then
			l_Page = 1
		End If
	End Function

	'/********************************************
	'/* 晹栧堦棗儗僐乕僪拪弌
	'/* return丗Scripting.Dictionary 昞帵儕僗僩(FormListMdl宆偺攝楍)
	'/********************************************
	Public Function GetList()
		Dim l_PostSectionMasterObject
		Dim l_RecordSet
		Dim l_retList,l_retRec,l_cnt
		Dim l_Result

		l_Result = True

		'擖椡抣愝掕
		Call l_CommonObject.SetSearchInfoSession("PostList")

		'僙僢僔儑儞忣曬懚嵼僠僃僢僋
		If IsObject(Session("PostList")) Then
			If Session("PostList").Item("section_id") <> "" Then
				l_PostMdlObject.l_SectionId = Replace(l_CharUtil.html_chg(l_basp,Session("PostList").Item("section_id")),"""","&quot;")
			End If
			l_PostMdlObject.l_SectionName = Session("PostList").Item("section_name")
			l_PostMdlObject.l_CostBurdenKind = Session("PostList").Item("cost_burden_kind")
			If l_PostMdlObject.l_CostBurdenKind = "" Then
				l_PostMdlObject.l_CostBurdenKind = "0"
			End If
			l_PostMdlObject.l_SortKey = Session("PostList").Item("sortkey")
			l_PostMdlObject.l_SortDesc = Session("PostList").Item("sortdesc")

			'擖椡僠僃僢僋
			l_Result = CheckInput(l_PostMdlObject)
		Else
			l_PostMdlObject.l_CostBurdenKind = "1"
			l_PostMdlObject.l_SortKey = SORT_KEY1
			l_PostMdlObject.l_SortDesc = FLG_ON
		End If

		Set l_retList = CreateObject("Scripting.Dictionary")
		'擖椡僄儔乕僠僃僢僋
		If l_Result Then
			'DB傛傝忣曬庢摼
			Set l_PostSectionMasterObject = New PostSecsionMaster
			Set l_RecordSet = l_PostSectionMasterObject.SearchSectionBase(l_DBObject,l_PostMdlObject,Session("PostList"))
			'儗僐乕僪曇廤
			l_cnt = 0

			Do Until l_RecordSet.eof
				Set l_retRec = EditRec(l_RecordSet)
				l_retList.add CStr(l_cnt), l_retRec
				l_cnt = l_cnt + 1
				l_RecordSet.MoveNext
			Loop

			'儁乕僕惂屼梡偺僒僀僘丄審悢傪愝掕
			l_RsPageCount = Fix(l_retList.Count / 20 + 0.95)		'儁乕僕僒僀僘愝掕
			l_RsRecordCount = l_retList.Count	'儗僐乕僪審悢愝掕
		End If
		Set GetList = l_retList
	End Function

	Public Function EditRec(l_rs)
		Dim l_rec
		Set l_rec = New PostListMdl

		l_rec.l_DspSectionId = l_rs.Fields.Item("SECTION_ID")
		l_rec.l_DspSectionName = l_rs.Fields.Item("SECTION_NAME")

		If l_rs.Fields.Item("COST_BURDEN_KIND") = "1" Then
			l_rec.l_DspCostBurdenKind = "旓梡晧扴晹栧"
		Else
			l_rec.l_DspCostBurdenKind = "偦偺懠晹栧"
		End If

		Set EditRec = l_rec
	End Function

	'/********************************************
	'/* 僜乕僩帪偺俫俿俵俴儕儞僋庢摼
	'/* param丗String l_sortkey 僜乕僩僉乕
	'/* return丗String 俫俿俵俴暥帤楍
	'/********************************************
	Public Function GetSortParmHtml(l_sortkey,l_oldSortDesc)
		Dim l_retStr
		Dim l_newSortDesc

		'僜乕僩弴偺愝掕(徃弴佁崀弴愗傝懼偊)
		If l_oldSortDesc = FLG_ON Then
			l_newSortDesc = FLG_OFF		'崀弴仺徃弴
		Else 
			l_newSortDesc =  FLG_ON		'徃弴仺崀弴
		End If

		'僷儔儊乕僞亖僜乕僩僉乕丄専嶕忦審
		l_retStr = "sessave=" & "2"  &_
			"&sortkey=" & l_sortkey &_
			"&sortdesc=" & l_newSortDesc 
		GetSortParmHtml = l_retStr
	End Function

	'/********************************************
	'/* 僋儘乕僘
	'/********************************************
	Public Function Close
		Call l_DBObject.CloseRecodeset
		Call l_DBObject.CloseConnection
	End Function

	'/********************************************
	'/* 擖椡僠僃僢僋
	'/********************************************
	Public Function CheckInput(Mdl)
		Dim l_Index
		Dim l_CheckUtil

		CheckInput = True

		Set l_CheckUtil = New CheckUtil

		l_Index = 0

		'晹栧僐乕僪僠僃僢僋
		If Mdl.l_SectionId <> "" Then
			If Not l_CheckUtil.IsNumericAlpha(Mdl.l_SectionId) Then
				l_errarray(l_Index) = IG11053E
				l_Index = l_Index + 1
				CheckInput = False
			End If
		End If

		'晹栧柤僠僃僢僋
		If Mdl.l_SectionName <> "" Then
			Mdl.l_SectionName = l_CharUtil.chg_HantoZen(Mdl.l_SectionName)
		End If
	End Function

	'/*************************************
	'/ 堦棗僿僢僟
	'/ return:html
	'/*************************************
	Public Function ListHeadDsp
		Dim l_html
		Dim l_CRLF
		Dim l_sortdsp

		l_CRLF = Chr(13) & Chr(10)

		'僜乕僩弴丂徃弴丗(仾)丂崀弴丗(伀)
		If l_PostMdlObject.l_SortDesc = FLG_ON Then
			l_sortdsp = "(伀)"
		Else
			l_sortdsp = "(仾)"
		End If

		l_html = "<tr align=""center""> " & l_CRLF &_
				 "<td class=""txt_m"" height=""20"" bgcolor=""#999966"" width=""100"">" &_
				 "<a href=""post_list.asp?" & GetSortParmHtml("2",l_PostMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">晹栧僐乕僪"

		'晹栧僐乕僪偱僜乕僩偺応崌
		If l_PostMdlObject.l_SortKey = "2" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a></td>" & l_CRLF &_
				 "<td class=""txt_m"" height=""20"" bgcolor=""#999966"">" &_
				 "<a href=""post_list.asp?" & GetSortParmHtml("3",l_PostMdlObject.l_SortDesc) & """>" &_
				 "<font color=""#FFFFFF"">晹栧柤"

		'晹栧柤偱僜乕僩偺応崌
		If l_PostMdlObject.l_SortKey = "3" Then
			l_html = l_html & l_sortdsp
		End If

		l_html = l_html & "</font></a></td>" & l_CRLF &_
				 "</tr>" & l_CRLF

		ListHeadDsp = l_html
	End Function
End Class

'/************************************
'/*専嶕忦審曐帩僋儔僗
'/************************************
Class PostListMdl
	Dim l_SystemId
	Dim l_CompanyId
	Dim l_UserName
	Dim l_SortKey
	Dim l_SortDesc

	'専嶕忦審擖椡棑崁栚
	Dim l_SectionId
	Dim l_SectionName
	Dim l_CostBurdenKind

	Dim l_DspSectionId
	Dim l_DspSectionName
	Dim l_DspCostBurdenKind
End Class
%>