setvalid.asp

java的一个网上商店的源码,后台是Access数据库.功能还可以.界面比较简单,但是基本的功能都有.

<% option explicit %>
<!-- #include file="_ccwlib/_lib.asp" -->
<%
'-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
'	功能：用户管理--确认用户
'	Author: 顾志亮
'	@Language=VBscript
'	Create: 2002-10-14
'	Modify: 2003-7-8
'-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-

Dim sql,rs,i,msg
Dim uid  '---管理员ID
Dim id,idgroup

call DB_Connect(strconn)

'---验证身份----
uid=session("admID")
call IsValidUser(uid,sAdmin_Level+sUser_Level,1,"../error.htm",oConn)

'--发送确认信--
sub sendconfirm(id,byref oConn)
	dim fromwho , towho , ccwho , subject , mailbody 
	dim username , pwd
	dim sqlt , rst
	sqlt="select usr_name,usr_pwd,usr_email from userinfo where usr_id=" & id 
	set rst=oConn.execute(sqlt)
	if not rst.eof then 
		username=rst("usr_name")
		pwd=rst("usr_pwd")
		towho=rst("usr_email")
	end if
	rst.close
	set rst=nothing
	fromwho=WebSiteSendEmail
	ccwho=""
	subject="User Account for Nokia E-order System"
	mailbody="你已经通过管理员的确认!" & "<br>"
	mailbody=mailbody & "你的用户名:" & username & "<br>"
	mailbody=mailbody & "你的密码:" & pwd & "<br>"
	mailbody=mailbody & "<a href='" & WebDomain & "'>现在登录系统</a>" & "<br>"
	call sendmail(fromwho,towho,ccwho,subject,mailbody,0,0)
end sub
'--读取表单数据--
id = getFormElem("id")
if id="" then 
	response.redirect "confirm.asp"
	response.end
end if
'response.write id&"<br>"
idgroup = split(id,", ")

oConn.begintrans
	for i=0 to ubound(idgroup)
		'response.write idgroup(i)
		sql="update userinfo set usr_ispass='Y',usr_isvalid='Y' where usr_id=" & cint(idgroup(i))
		oConn.execute(sql)
		call sendconfirm(cint(idgroup(i)),oConn)
	next
oConn.committrans


call DB_DisConnect

response.redirect "confirm.asp"

%>