modresizeform.bas

计算机网络与通信的知识

Attribute VB_Name = "modResizeForm"
'================================================================
'||                                                            ||
'||      调整窗体，使窗体内各控件随之自动调整（通用）          ||
'||                                                            ||
'================================================================
Option Explicit
Private FormOldWidth As Long   '保存窗体的原始宽度
Private FormOldHeight As Long  '保存窗体的原始高度

'在 Form_Load事件中 调用本函数
Public Sub ResizeInit(FormName As Form)
   Dim Obj As Control
   FormOldWidth = FormName.ScaleWidth
   FormOldHeight = FormName.ScaleHeight
   On Error Resume Next
   For Each Obj In FormName
     Obj.Tag = Obj.Left & " " & Obj.Top & " " _
           & Obj.Width & " " & Obj.Height & " "
   Next Obj
   On Error GoTo 0
End Sub

'按比例改变窗体内各控件的大小，在调用ReSizeForm前先调用ReSizeInit函数
Public Sub ResizeForm(FormName As Form)
   Dim Pos(4) As Double
   Dim i As Long, TempPos As Long, StartPos As Long
   Dim Obj As Control
   Dim ScaleX As Double, ScaleY As Double

   ScaleX = FormName.ScaleWidth / FormOldWidth  '保存窗体宽度缩放比例
   ScaleY = FormName.ScaleHeight / FormOldHeight '保存窗体高度缩放比例
   On Error Resume Next
   For Each Obj In FormName
     StartPos = 1
     For i = 0 To 4
     '读取控件的原始位置与大小
       TempPos = InStr(StartPos, Obj.Tag, " ", vbTextCompare)
       If TempPos > 0 Then
         Pos(i) = Val(Mid(Obj.Tag, StartPos, TempPos - StartPos))
         StartPos = TempPos + 1
       Else
         Pos(i) = 0
       End If
       '根据控件的原始位置及窗体改变大小的比例对控件重新定位与改变大小
       Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, _
               Pos(2) * ScaleX, Pos(3) * ScaleY
     Next i
   Next Obj
   On Error GoTo 0
End Sub