cclienttypes.cls

一个客户系统,VB+SQL,其中有客户类型分类

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CTypes"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Private mCol As Collection

'往集合中加入一个“客户类型”对象
Public Sub Add(objType As CType)
  mCol.Add objType, "A" & objType.ID
  '在加入对象是，最好同时加入其“KEY”属性
  '“KEY”属性不可以是数字型，因此在前面随便加
  '一个字母，此处加了一个“A”
End Sub

Public Property Get Item(vntIndexKey As Variant) As CType
  Set Item = mCol(vntIndexKey)
End Property

Public Property Get Count() As Long
  Count = mCol.Count
End Property

Public Sub Remove(vntIndexKey As Variant)
  mCol.Remove vntIndexKey
End Sub

Public Property Get NewEnum() As IUnknown
  '本属性允许用 For...Each 语法枚举该集合。
  Set NewEnum = mCol.[_NewEnum]
End Property

'清除集合中的全部元素
Public Sub Clear()
  '注意！在清除时必须倒序清除，否则要出错！
  Dim i As Long
  For i = mCol.Count To 1 Step -1
    mCol.Remove i
  Next i
End Sub

Private Sub Class_Initialize()
  Set mCol = New Collection
End Sub

Private Sub Class_Terminate()
  Set mCol = Nothing
End Sub

'按条件查找客户类型，以集合类的方式返回
Public Function Find(Optional lngID As Long = 0, _
                     Optional lngSuperID As Long = -1) As CTypes
  '按输入的参数查询，并返回一个集合类
  Dim strSQL As String
  
  '构造SQL语句
  strSQL = "Select * from ClientType where "
  If lngID <> 0 Then strSQL = strSQL & "TypeID=" & lngID & " and "
  If lngSuperID <> -1 Then
'    If lngSuperID = 0 Then '如果传入0，则表示没有上级客户类型
'      strSQL = strSQL & "SuperID is null and "
'    Else
      strSQL = strSQL & "SuperID=" & lngSuperID & " and "
'    End If
  End If
  strSQL = strSQL & "TypeID>0"
  
  '清空当前集合
  Me.Clear
  
  Dim rs As Recordset
  Set rs = g_Conn.Execute(strSQL)
  
  '往集合中添加查询结果
  Dim i As Long
  Dim objType As CType
  For i = 1 To rs.RecordCount
    Set objType = New CType
    With objType
      .ID = rs("TypeID").Value
      .TypeName = Trim(rs("TypeName").Value)
      .SuperID = IIf(IsNull(rs("SuperID").Value), 0, rs("SuperID").Value)
    End With
    Me.Add objType
    Set objType = Nothing
    rs.MoveNext
  Next i
  
  Set rs = Nothing
  Set Find = Me
End Function