cwarnings.cls

一个客户系统,VB+SQL,其中有客户类型分类

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CWarnings"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Private mCol As Collection

'往集合中加入一个“提醒信息”对象
Public Sub Add(objWarn As CWarning)
  mCol.Add objWarn, "A" & objWarn.ID
  '在加入对象是，最好同时加入其“KEY”属性
  '“KEY”属性不可以是数字型，因此在前面随便加
  '一个字母，此处加了一个“A”
End Sub

Public Property Get Item(vntIndexKey As Variant) As CWarning
  Set Item = mCol(vntIndexKey)
End Property

Public Property Get Count() As Long
  Count = mCol.Count
End Property

Public Sub Remove(vntIndexKey As Variant)
  mCol.Remove vntIndexKey
End Sub

Public Property Get NewEnum() As IUnknown
  '本属性允许用 For...Each 语法枚举该集合。
  Set NewEnum = mCol.[_NewEnum]
End Property

'清除集合中的全部元素
Public Sub Clear()
  '注意！在清除时必须倒序清除，否则要出错！
  Dim i As Long
  For i = mCol.Count To 1 Step -1
    mCol.Remove i
  Next i
End Sub

Private Sub Class_Initialize()
  Set mCol = New Collection
End Sub

Private Sub Class_Terminate()
  Set mCol = Nothing
End Sub

'按条件查找提醒信息，以集合类的方式返回
Public Function Find(Optional ByVal lngID As Long = 0, _
                    Optional ByVal lngTypeId As Long = 0) As CWarnings
                      
  '构造查询SQL
  Dim strSQL As String
  strSQL = "Select Warning.*,WarnType.WTypeName from Warning left outer join WarnType "
  strSQL = strSQL & " ON Warning.TypeID=WarnType.WTypeID Where "
  
  If lngID <> 0 Then strSQL = strSQL & "Warning.WarnId=" & lngID & " and "
  If lngTypeId <> 0 Then strSQL = strSQL & "Warning.TypeID=" & lngTypeId & " and "
  strSQL = strSQL & "Warning.WarnId>0"
  
  On Error Resume Next
  '将查询结果加入集合类
  Dim rs As Recordset
  Set rs = g_Conn.Execute(strSQL)
  Dim i As Long
  Dim objWarn As CWarning
  For i = 1 To rs.RecordCount
    Set objWarn = New CWarning
    With objWarn
      .ID = rs("WarnId").Value
      .ClientID = rs("ClientId").Value
      .Msg = Trim(rs("Msg").Value)
      .ShowDate = rs("ShowDate").Value
      .TypeID = rs("TypeId").Value
      .TypeName = rs("WTypeName").Value
    End With
    Me.Add objWarn
    Set objWarn = Nothing
    rs.MoveNext
  Next i
  
  Set rs = Nothing
  Set Find = Me
End Function

'按条件查找提醒信息，以集合类的方式返回
Public Function FindByDate(Optional ByVal intYear As Integer = 0, _
                           Optional ByVal intMonth As Integer = 0, _
                           Optional ByVal intDay As Integer = 0, _
                           Optional ByVal IncludeBirthdayWarn As Boolean = True) As CWarnings
                      
  If intYear < 0 Then intYear = 0
  If intMonth < 0 Then intMonth = 0
  If intDay < 0 Then intDay = 0
  
  '构造查询SQL
  Dim strSQL As String
  strSQL = "Select Warning.*,WarnType.WTypeName from Warning left outer join WarnType "
  strSQL = strSQL & " ON Warning.TypeID=WarnType.WTypeID Where "
  
  '非生日提醒
  If intYear + intMonth + intDay <> 0 Then
    strSQL = strSQL & "("
  End If
  
  If intYear <> 0 Then strSQL = strSQL & "Year(ShowDate)=" & intYear & " and "
  If intMonth <> 0 Then strSQL = strSQL & "Month(ShowDate)=" & intMonth & " and "
  If intDay <> 0 Then strSQL = strSQL & "Day(ShowDate)=" & intDay & " and "
  
  If intYear + intMonth + intDay <> 0 Then
    strSQL = strSQL & " Warning.TypeID > 0 "
    strSQL = strSQL & ") "
  End If
  
  '生日提醒
  If intYear + intMonth + intDay <> 0 And IncludeBirthdayWarn Then
    strSQL = strSQL & " OR ("
  End If
  
  If intMonth <> 0 Then strSQL = strSQL & "Month(ShowDate)=" & intMonth & " and "
  If intDay <> 0 Then strSQL = strSQL & "Day(ShowDate)=" & intDay & " and "
  
  If intYear + intMonth + intDay <> 0 And IncludeBirthdayWarn Then
    strSQL = strSQL & " Warning.TypeID = 1 "
    strSQL = strSQL & ") "
  End If
  
  
  strSQL = strSQL & " AND Warning.WarnId > 0"
  
  On Error Resume Next
  '将查询结果加入集合类
  Dim rs As Recordset
  Set rs = g_Conn.Execute(strSQL)
  Dim i As Long
  Dim objWarn As CWarning
  For i = 1 To rs.RecordCount
    Set objWarn = New CWarning
    With objWarn
      .ID = rs("WarnId").Value
      .ClientID = rs("ClientId").Value
      .Msg = Trim(rs("Msg").Value)
      .ShowDate = rs("ShowDate").Value
      .TypeID = rs("TypeId").Value
      .TypeName = rs("WTypeName").Value
    End With
    Me.Add objWarn
    Set objWarn = Nothing
    rs.MoveNext
  Next i
  
  Set rs = Nothing
  Set FindByDate = Me
End Function