📄 renamesort.asp

📁 商务网站,信息分类,可以搜索加上ACCESS数据库
💻 ASP
字号:
<%Option Explicit%>
<!--#include file="functions.asp"-->
<!--#include file="adoconn.asp"-->

<%
dim objRS, sql
dim sortid,parentid,sortname,comment,oldname

if Request.ServerVariables("REQUEST_METHOD") = "POST" then
    sortid = Request.Form("sortid")
    parentid = Request.Form("parentid")
    sortname = Server.HTMLEncode(Trim(Request.Form("sortname")))
    oldname  = Server.HTMLEncode(Request.Form("oldname"))
    comment  = Server.HTMLEncode(Trim(Request.Form("comment")))
    
    sortname = Replace(sortname,"'","’")

    if sortid = "" or (not IsNumeric(sortid)) or parentid = "" or (not IsNumeric(parentid)) or Trim(oldname) = "" then
        Response.Write("<script language=""JavaScript"">alert(""意外参数错误！"");history.go(-1)</script>")
    elseif Trim(sortname) = "" then
        Response.Write("<script language=""JavaScript"">alert(""请输入类名称！"");history.go(-1)</script>")
    else
objConn.BeginTrans
        sql = "select * from sort where id = " & sortid
        Set objRS = Server.CreateObject("ADODB.RecordSet")
        objRS.Open sql, objConn, 3, 3
        if objRS.EOF then
objConn.RollbackTrans
            objConn.Close()
            Set objRS = nothing
            Set objConn = nothing
            Response.Write("<script language=""JavaScript"">alert(""参数错误！"");history.go(-1)</script>")
            Response.End
        else
            objRS("sortname") = sortname
            if not (IsNull(comment) or comment = "") then objRS("description") = comment
            objRS.Update()
            objRS.Close()
'///////////////////////////////////////////// 处理路径表 /////////////////////////////////
            if Clng(parentid) = -1 then
                sql = "select * from pathform where (thispath = '" & sortid & "') or (thispath like '" & sortid & chr(44) & "%')"
            else
                sql = "select * from pathform where (thispath like '%" & chr(44) & sortid & "') or (thispath like '%" & chr(44) & sortid & chr(44) & "%')"
            end if
'Response.Write("sql: " & sql & "<br>")
            objRS.Open sql, objConn, 3, 3
            do while not objRS.EOF
                objRS("pathname").value = replacepath(objRS("thispath"), sortid, objRS("pathname").value, sortname)
                objRS.Update()
                objRS.MoveNext()
            loop
            objRS.Close()
'//////////////////////////////////////////// 处理快捷表 //////////////////////////////////
            sql = "select * from shortcut where sortid = " & sortid
            objRS.Open sql, objConn, 3, 3
            if not objRS.EOF then
                objRS("sortname") = sortname
                if not (IsNull(comment) or comment = "") then objRS("description") = comment
                objRS.Update()
            end if
            objRS.Close()
objConn.CommitTrans
            objConn.Close()
            Set objRS = nothing
            Set objConn = nothing
            if Clng(parentid) = -1 then
                Response.Write("<script language=""JavaScript"">location.replace(""admsort1.asp"")</script>")
            else
                Response.Write("<script language=""JavaScript"">location.replace(""admclass.asp?sortid=" & parentid & """)</script>")
            end if
            Response.End
        end if
    end if
else
    sortid = Request.QueryString("sortid")
    parentid = Request.QueryString("parentid")
    sortname = Request.QueryString("sortname")
    comment  = Request.QueryString("comment")%>

<body bgcolor="#FFFFFF" topmargin="100">
<table width="300" border="1" align="center" style="border: 1 solid #C0C0C0" cellpadding="0" cellspacing="0" bordercolorlight="#CCCC99" bordercolordark="#FFFFFF">
  <form action="renameclass.asp" method="POST" id=form1 name=form1>
<input type="hidden" name="sortid" value="<%=sortid%>">
<input type="hidden" name="parentid" value="<%=parentid%>">
<input type="hidden" name="oldname" value="<%=sortname%>">
  <tr bgcolor="#cccc99"> 
    <td> <font color="#000000">编辑类目</font> </td>
  </tr>
  <tr>
    <td align="center">&nbsp;<br>
        类名:&nbsp;<input type="text" name="sortname" value="<%=sortname%>" size="30" style="background-color: #ffffff;"><br>
        说明:&nbsp;<input type="text" name="comment" value="<%=comment%>" size="30" style="background-color: #ffffff;">
    </td>
  </tr>
  <tr>
    <td align="right">
        <input type="submit" value="确定更改" id=submit1 name=submit1>&nbsp;&nbsp;<input type="button" value=" 返 回 " onclick="history.go(-1);" id=button1 name=button1>&nbsp;<br>&nbsp;
    </td>
  </tr>
</table>
</body>
<%
end if

objConn.Close()
Set objConn = nothing
Set objRS = nothing
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -