newsort.asp

商务网站,信息分类,可以搜索加上ACCESS数据库

<%Option Explicit%>
<!--#include file=ismaster.asp-->
<!--#include file=adoconn.asp-->
<%
dim sortid,sortname,comment
dim objRS,sql
dim thispath,pathname
dim IsErr
dim id

sortid = Request.QueryString("sortid")
sortname = Trim(Request.QueryString("sortname"))
comment  = Trim(Request.QueryString("comment"))
IsErr = FALSE

objConn.BeginTrans
if sortid = "" or (not IsNumeric(sortid)) or Trim(sortname) = "" then
    objConn.RollbackTrans
    IsErr = TRUE
else
    sortname = Replace(sortname,"'","’")
    sortname = Replace(sortname,chr(255),"")
    comment  = Replace(comment,"'","’")
    comment  = Replace(comment,chr(255),"")

    Set objRS = Server.CreateObject("ADODB.RecordSet")
'Response.Write("sql: " & sql & "<br>")
    sql = "select * from sort where parentid = " & sortid & " and sortname = '" & sortname & "'"
    objRS.Open sql, objConn, 3, 3

    if not objRS.EOF then                               '同一目录下类名不能重复
        objConn.RollbackTrans
        
        objConn.Close()
        Set objConn = nothing
        Set objRS = nothing
        Response.Write("<script language=""JavaScript"">alert(""同一目录下类名不能重复！"");history.go(-1)</script>")
        Response.End
    else

        objRS.AddNew
            objRS("parentID") = sortid
            objRS("sortname") = sortname
            objRS("description") = comment
            objRS("thisdate") = now()
        objRS.Update
        objRS.Close()
        sql = "select id from sort where parentid = " & sortid & " and sortname = '" & sortname & "'"
        objRS.Open sql, objConn, 3, 1
        id = objRS("id")                                '取新建类的ID
        objRS.Close()
        if Clng(sortid) = -1 then
            sql = "pathform"
            objRS.Open sql, objConn, 3, 3
            objRS.AddNew
                objRS("thispath") = id
                objRS("pathname") = sortname
            objRS.Update()
        else
            sql = "select * from pathform where thispath like '%" & sortid & "'"
            objRS.Open sql, objConn, 3, 3
            thispath = objRS("thispath")
            pathname = objRS("pathname")
            objRS.AddNew()
                objRS("thispath") = thispath & chr(44) & id
                objRS("pathname") = pathname & chr(255) & sortname
            objRS.Update()
        end if
        objRS.Close()
        if Clng(sortid) <> -1 then
            sql = "select * from sort where id = " & sortid
            objRS.Open sql, objConn, 3, 3
                objRS("totalchild").value = objRS("totalchild").value + 1
            objRS.Update()
        end if
        objConn.CommitTrans
    end if
end if

objConn.Close()
Set objRS = nothing
Set objConn = nothing
if IsErr then
    Response.Write("<script language=""JavaScript"">alert(""参数错误！"");history.go(-1)</script>")
else
    if Clng(sortid) = -1 then
        Response.Write("<script language=""JavaScript"">location.replace(""admsort1.asp"")</script>")
    else
        Response.Write("<script language=""JavaScript"">location.replace(""admclass.asp?sortid=" & sortid & """)</script>")
    end if
end if
%>