functions1.asp

商务网站,信息分类,可以搜索加上ACCESS数据库

<%
'==============================  getPath(pthid,pnam)  ==============================
'功能：返回带超链接的路径
'参数：pthid 用逗号分隔的ID号字符串
'      pnam用chr(255)分隔的字符串
'===================================================================================
function GetPath(pthid,pnam,isadm)
    dim i
    
    if right(pthid,1) <> "," then pthid = pthid & ","
    pthid = split(pthid,",")
    pnam  = split(pnam,chr(255))
    thispath = ""
    for i = 0 to UBound(pthid) - 2
        if isadm = TRUE then
            thispath = thispath & ">><a href=""admshop.asp?sortid=" & pthid(i) & """>" & pnam(i) & "</a>"
        else
            thispath = thispath & ">><a href=""info.asp?sortid=" & pthid(i) & """>" & pnam(i) & "</a>"
        end if
    next
    GetPath = thispath & ">>" & pnam(i)
end function
'===================================  getEndID(idlist)  ===========================
'功能：返回以逗号分隔的ID字符串列表的最后一个ID,若参数中没有逗号则返回该参数
'参数：idlist 用逗号分隔的ID字符串列表
'      idlist 用逗号分隔的数字表
'==================================================================================
function getEndID(idlist)
    dim pos
    for pos = len(idlist) to 1 step -1
        if mid(idlist,pos,1) = chr(44) then exit for
    next
    if pos < 1 then
        getEndID = idlist
    else
        getEndID = right(idlist,len(idlist) - pos)
    end if
end function
%>