recvcontextm.nc

tinios的 源码

/*									tab:4
 *
 *
 * "Copyright (c) 2000-2002 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and
 * its documentation for any purpose, without fee, and without written
 * agreement is hereby granted, provided that the above copyright
 * notice, the following two paragraphs and the author appear in all
 * copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY
 * PARTY FOR DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL
 * DAMAGES ARISING OUT OF THE USE OF THIS SOFTWARE AND ITS
 * DOCUMENTATION, EVEN IF THE UNIVERSITY OF CALIFORNIA HAS BEEN
 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
 * MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE
 * PROVIDED HEREUNDER IS ON AN "AS IS" BASIS, AND THE UNIVERSITY OF
 * CALIFORNIA HAS NO OBLIGATION TO PROVIDE MAINTENANCE, SUPPORT,
 * UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 */
/*									tab:4
 *									
 *  IMPORTANT: READ BEFORE DOWNLOADING, COPYING, INSTALLING OR USING.
 *  By downloading, copying, installing or using the software you
 *  agree to this license.  If you do not agree to this license, do
 *  not download, install, copy or use the software.
 *
 *  Intel Open Source License 
 *
 *  Copyright (c) 2002 Intel Corporation 
 *  All rights reserved. 
 *  Redistribution and use in source and binary forms, with or without
 *  modification, are permitted provided that the following conditions are
 *  met:
 * 
 *	Redistributions of source code must retain the above copyright
 *  notice, this list of conditions and the following disclaimer.
 *	Redistributions in binary form must reproduce the above copyright
 *  notice, this list of conditions and the following disclaimer in the
 *  documentation and/or other materials provided with the distribution.
 *      Neither the name of the Intel Corporation nor the names of its
 *  contributors may be used to endorse or promote products derived from
 *  this software without specific prior written permission.
 *  
 *  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 *  ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 *  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
 *  PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE INTEL OR ITS
 *  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
 *  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
 *  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
 *  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
 *  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
 *  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 *  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * 
 */

/*
 * Authors:   Neil Patel
 * History:   Apr 11, 2003         Inception.
 *
 */

/**
 * @author Neil Patel
 */


includes AM;
includes Bombilla;

module RecvContextM {
  provides interface StdControl;
  uses {
    interface ReceiveMsg as ReceivePacket;
    interface Receive as ReceiveAdHoc;
    interface BombillaStacks as Stacks;
    interface BombillaContextSynch as Synch;
    interface BombillaContextComm as Comm;
    interface BombillaVirus as Virus;
    interface BombillaAnalysis as Analysis;
  }
}

implementation {
  BombillaContext recvContext;
  BombillaDataBuffer recvBuffer;

  command result_t StdControl.init() {
    int pc = 0;
    
    recvContext.which = BOMB_CAPSULE_RECV;
    recvContext.state = BOMB_STATE_HALT;
    recvContext.rootCapsule.capsule.type = recvContext.which;
    recvContext.rootCapsule.capsule.type |= BOMB_OPTION_FORWARD;
      
    call Virus.registerCapsule(recvContext.rootCapsule.capsule.type, 
                               &recvContext.rootCapsule.capsule);
    
    recvContext.rootCapsule.capsule.code[pc++] = OPbhead;
    recvContext.rootCapsule.capsule.code[pc++] = OPpushc | 7;
    recvContext.rootCapsule.capsule.code[pc++] = OPland;
    recvContext.rootCapsule.capsule.code[pc++] = OPputled;
    recvContext.rootCapsule.capsule.code[pc++] = OPhalt;
    recvContext.rootCapsule.capsule.options = 0;
    recvContext.rootCapsule.capsule.version = 0;

    call Analysis.analyzeCapsuleVars(&recvContext.rootCapsule);
    call Comm.registerCapsule(&recvContext.rootCapsule);
    
    return SUCCESS;
  }

  command result_t StdControl.start() {
    return SUCCESS;
  }

  command result_t StdControl.stop() {
    return SUCCESS;
  }

  event result_t Comm.analyzeLockSets(BombillaCapsuleBuffer* capsules[]) {
    return SUCCESS;
  }
  
  void alertReceiveContext(TOS_MsgPtr msg) {
    if (!msg->crc) {return;}
    if (recvContext.state != BOMB_STATE_HALT) {
      dbg(DBG_USR1, "VM (%i): Received packet, receive context busy, drop.\n", recvContext.which);
    }
    else {
      int i;
      BombillaPacket* packet = (BombillaPacket*)(msg->data);
      BombillaDataBuffer* buffer = (BombillaDataBuffer*)&(packet->payload);
      dbg(DBG_USR1, "VM (%i): Received packet, enqueuing receive context to run.\n", recvContext.which);
      dbg(DBG_USR1, "VM (%i): Copying %i bytes of header over:\n  ", recvContext.which, sizeof(recvContext.header));
      for (i = 0; i < sizeof(recvContext.header); i++) {
        dbg_clear(DBG_USR1, "%02hhx", packet->header[i]);
      }
      dbg_clear(DBG_USR1, "\n->");
      nmemcpy(&(recvContext.header), packet->header, sizeof(recvContext.header));
      for (i = 0; i < sizeof(recvContext.header); i++) {
        dbg_clear(DBG_USR1, "%02hhx", ((uint8_t*)recvContext.header)[i]);
      }
      dbg_clear(DBG_USR1, "\n");
      nmemcpy(&recvBuffer, buffer, sizeof(BombillaDataBuffer));
      call Synch.initializeContext(&recvContext);
      call Stacks.pushBuffer(&recvContext, &recvBuffer);
      call Synch.resumeContext(&recvContext, &recvContext);
    }
  }

  event TOS_MsgPtr ReceivePacket.receive(TOS_MsgPtr msg) {
    alertReceiveContext(msg);
    return msg;
  }
  
  event TOS_MsgPtr ReceiveAdHoc.receive(TOS_MsgPtr msg, void* payload, uint16_t payloadLen) {
    alertReceiveContext(msg);
    return msg;
  }

  event result_t Synch.makeRunnable(BombillaContext* context) {
    return SUCCESS;
  }

  event result_t Virus.capsuleInstalled(BombillaCapsule* capsule) {
    call Synch.initializeContext(&recvContext);
    if (capsule->type == (BOMB_CAPSULE_RECV | BOMB_OPTION_FORWARD)) {
      dbg(DBG_USR1, "VM: Installing recvContext Capsule. \n");
      recvContext.rootCapsule.capsule = *capsule;
      call Analysis.analyzeCapsuleVars(&recvContext.rootCapsule);
      recvBuffer.type = BOMB_DATA_NONE;
      recvBuffer.size = 0;
      call Comm.reboot();
    }
    return SUCCESS;
  }

  event result_t Virus.enableExecution() {
    return SUCCESS;
  }

  event result_t Virus.disableExecution() {
    return SUCCESS;
  }

  event result_t Virus.capsuleHeard(uint8_t type) {
    return SUCCESS;
  }

  event void Virus.capsuleForce(uint8_t type) {
    return;
  }
}