dpmta.m4

xgrafix 是PTSG模拟程序中的图形截面库 改版本是最新版本

dnl ######################################################################
dnl
dnl Determine the locations of dpmta includes and libraries
dnl
dnl Version: $Id: dpmta.m4,v 1.7 2002/07/11 15:43:53 cary Exp $
dnl
dnl ######################################################################

dnl ######################################################################
dnl
dnl Allow the user to specify an overall dpmta directory.  If specified,
dnl we look for include and lib under this.
dnl
dnl ######################################################################

AC_ARG_WITH(dpmta-dir,[  --with-dpmta-dir=<location of dpmta installation> ],DPMTA_DIR="$withval",DPMTA_DIR="")

dnl ######################################################################
dnl
dnl Find dpmta includes - looking in include location if present,
dnl otherwise in dir/include if present, otherwise in default locations,
dnl first parallel, then serial.
dnl
dnl ######################################################################

AC_ARG_WITH(dpmta-incdir,[  --with-dpmta-incdir=<location of dpmta includes> ],
DPMTA_INCDIR="$withval",DPMTA_INCDIR="")
if test -n "$DPMTA_INCDIR"; then
  DPMTA_INCPATH=$DPMTA_INCDIR
elif test -n "$DPMTA_DIR"; then
  DPMTA_INCPATH=$DPMTA_DIR/src
else
  DPMTA_INCPATH=$PWD/../dpmta/src:$HOME/dpmta/src:/usr/local/dpmta/src:/loc/dpmta/src:/local/dpmta/src:/usr/common/usg/dpmta/1.4.2/serial/src:$HOME/dpmta/src
fi
AC_PATH_PROGS(DPMTA_H, dpmta.h, "", $DPMTA_INCPATH)
if test -z "$DPMTA_H"; then
  AC_MSG_WARN(dpmta.h not found in $DPMTA_INCPATH.  Set with --with-dpmta-incdir=)
  DPMTA_INC=" "
  ac_cv_have_dpmta=no
else
  DPMTA_INCDIR=`dirname $DPMTA_H`
  AC_SUBST(DPMTA_INCDIR)
  DPMTA_INC=-I$DPMTA_INCDIR
  AC_SUBST(DPMTA_INC)
  DPMTA_DIR=`dirname $DPMTA_INCDIR`
  ac_cv_have_dpmta=yes
fi

dnl ######################################################################
dnl
dnl Find dpmta libraries
dnl
dnl ######################################################################

AC_ARG_WITH(dpmta-libdir,[  --with-dpmta-libdir=<location of dpmta library> ],
DPMTA_LIBDIR="$withval",DPMTA_LIBDIR="")
if test $ac_cv_have_dpmta = yes; then
  if test -n "$DPMTA_LIBDIR"; then
    DPMTA_LIBPATH=$DPMTA_LIBDIR
  else
    DPMTA_LIBPATH=$DPMTA_DIR/src
  fi
  AC_PATH_PROGS(LIBDPMTA_A, libspmta.a, "", $DPMTA_LIBPATH)
  if test -z "$LIBDPMTA_A"; then
    AC_MSG_WARN(libspmta.a not found.  Set with --with-dpmta-libdir=)
    ac_cv_have_dpmta=no
    DPMTA_LIB=" "
  else
    DPMTA_LIBDIR=`dirname $LIBDPMTA_A`
    AC_SUBST(DPMTA_LIBDIR)
    DPMTA_LIB="-L$DPMTA_LIBDIR -lspmta"
  fi
  AC_SUBST(DPMTA_LIB)
fi

dnl ######################################################################
dnl
dnl Define for whether dpmta found
dnl
dnl ######################################################################

if test $ac_cv_have_dpmta = yes; then
  AC_DEFINE(HAVE_DPMTA)
fi