txbase.m4

xgrafix 是PTSG模拟程序中的图形截面库 改版本是最新版本

dnl ######################################################################
dnl
dnl File:	txbase.m4
dnl
dnl Purpose:	Determine the locations of txbase includes and libraries
dnl
dnl Version: 	$Id: txbase.m4,v 1.5 2005/04/20 23:20:05 rmtrines Exp $
dnl
dnl Tech-X configure system
dnl
dnl ######################################################################

dnl ######################################################################
dnl
dnl Allow the user to specify an overall txbase directory.  If specified,
dnl we look for include and lib under this.
dnl
dnl ######################################################################

AC_ARG_WITH(txbase-dir,[  --with-txbase-dir=<location of txbase installation> ],TXBASE_DIR="$withval",TXBASE_DIR="")

dnl ######################################################################
dnl
dnl Find txbase includes - looking in include location if present,
dnl otherwise in dir/include if present, otherwise in default locations,
dnl first parallel, then serial.
dnl
dnl ######################################################################

AC_ARG_WITH(txbase-incdir,[  --with-txbase-incdir=<location of txbase includes> ],
TXBASE_INCDIR="$withval",TXBASE_INCDIR="")
if test -n "$TXBASE_INCDIR"; then
  TXBASE_INCPATH=$TXBASE_INCDIR
elif test -n "$TXBASE_DIR"; then
  TXBASE_INCPATH=$TXBASE_DIR/include
else
  TXBASE_INCPATH=$HOME/$UNIXFLAVOR/optsolve++/include:$HOME/optsolve++/include:/usr/local/optsolve++/include:/loc/optsolve++/include:/local/optsolve++/include:$HOME/$UNIXFLAVOR/txmath/include:$HOME/txmath/include:/usr/local/txmath/include:/loc/txmath/include:/local/txmath/include
fi
AC_PATH_PROGS(TXBASE_H, txc_math.h, "", $TXBASE_INCPATH)
if test -z "$TXBASE_H"; then
  AC_MSG_WARN(txc_math.h not found in $TXBASE_INCPATH.  Set location with --with-txbase-incdir=)
  TXBASE_INC=""
else
  TXBASE_INCDIR=`dirname $TXBASE_H`
  AC_SUBST(TXBASE_INCDIR)
  TXBASE_INC=-I$TXBASE_INCDIR
  AC_SUBST(TXBASE_INC)
  TXBASE_DIR=`dirname $TXBASE_INCDIR`
fi

dnl ######################################################################
dnl
dnl Find txbase libraries
dnl
dnl ######################################################################

AC_ARG_WITH(txbase-libdir,[  --with-txbase-libdir=<location of txbase library> ], TXBASE_LIBDIR="$withval",TXBASE_LIBDIR="")
if test -n "$TXBASE_INCDIR"; then
  if test -n "$TXBASE_LIBDIR"; then
    TXBASE_LIBPATH=$TXBASE_LIBDIR
  else
    TXBASE_LIBPATH=$TXBASE_DIR/lib/$COMPDIR:$TXBASE_DIR/lib
  fi
  AC_PATH_PROGS(LIBTXBASE_A, libtxbase.a, "", $TXBASE_LIBPATH)
  if test -z "$LIBTXBASE_A"; then
    AC_MSG_WARN(libtxbase.a not found in $TXBASE_LIBPATH.  Set location with --with-txbase-libdir=)
    TXBASE_LIB=""
  else
    TXBASE_LIBDIR=`dirname $LIBTXBASE_A`
    AC_SUBST(TXBASE_LIBDIR)
    TXBASE_LIB="-ltxbase"
  fi
  AC_SUBST(TXBASE_LIB)
fi

dnl ######################################################################
dnl
dnl Find txbase and verify that version is sufficiently new
dnl
dnl ######################################################################

dnl Check OptSolve++ version number
AC_PATH_PROG(TXBASE_VERSION_CHECK, txmath_version.h, "", $TXBASE_INCDIR)
if test -z "$TXBASE_VERSION_CHECK"; then
  AC_MSG_ERROR(Cannot find txmath_version.h in $TXBASE_INCDIR!
  Please install OptSolve++ or use --with-txbase-dir=TXBASE_INSTALL_DIR)
fi

AC_MSG_CHECKING(OptSolve++ version)
TXBASE_INC_FILE="`dirname $TXBASE_INCDIR`/include/txmath_version.h"
TXBASE_VERSION=`grep VERSION $TXBASE_INC_FILE | sed 's/^.* \"//' | sed 's/\"//g'`
AC_MSG_RESULT($TXBASE_VERSION)
TXBASE_MAJOR_VERSION=`echo $TXBASE_VERSION | sed 's/\..*$//'`
# echo TXBASE_MAJOR_VERSION = $TXBASE_MAJOR_VERSION

if test -z "$TXBASE_OK_MAJOR_VERSION"; then
  TXBASE_OK_MAJOR_VERSION=1
fi
if test -z "$TXBASE_OK_MINOR_VERSION"; then
  TXBASE_OK_MINOR_VERSION=0
fi
if test -z "$TXBASE_OK_RELEASE"; then
  TXBASE_OK_RELEASE=0
fi
if test -z "$TXBASE_OK_VERSION"; then
  TXBASE_OK_VERSION=$TXBASE_OK_MAJOR_VERSION.$TXBASE_OK_MINOR_VERSION.$TXBASE_OK_RELEASE
fi

if test $TXBASE_MAJOR_VERSION -lt $TXBASE_OK_MAJOR_VERSION; then
  echo Major version must be at least $TXBASE_OK_MAJOR_VERSION
  exit
fi
if test $TXBASE_MAJOR_VERSION -eq $TXBASE_OK_MAJOR_VERSION; then
  TXBASE_MINOR_VERSION=`echo $TXBASE_VERSION | sed "s/^$TXBASE_MAJOR_VERSION\.//" | sed 's/\..*$//'`
  # echo TXBASE_MINOR_VERSION = $TXBASE_MINOR_VERSION
  if test $TXBASE_MINOR_VERSION -lt $TXBASE_OK_MINOR_VERSION; then
    echo Minor version must be at least $TXBASE_OK_MINOR_VERSION
    exit
  fi
  if test $TXBASE_MINOR_VERSION -eq $TXBASE_OK_MINOR_VERSION; then
    TXBASE_RELEASE=`echo $TXBASE_VERSION | sed 's/^.*\.//'`
    # echo TXBASE_RELEASE = $TXBASE_RELEASE
    if test $TXBASE_RELEASE -lt $TXBASE_OK_RELEASE; then
      echo Minor version must be at least $TXBASE_OK_RELEASE
      exit
    fi
  fi
fi
echo OptSolve of sufficiently high version

AC_DEFINE_UNQUOTED([TXBASE_INCDIR], "$TXBASE_INCDIR", "include directory for txbase")