txcrange.m4

xgrafix 是PTSG模拟程序中的图形截面库 改版本是最新版本

dnl ######################################################################
dnl
dnl File:	txcrange.m4
dnl
dnl Purpose:	Determine the locations of txcrange includes and libraries. 
dnl 		Allows also for the installation of the ML library. 
dnl 
dnl Version: $Id: txcrange.m4,v 1.4 2005/07/20 13:05:49 cary Exp $
dnl
dnl Tech-X configure system
dnl
dnl ######################################################################


dnl ######################################################################
dnl
dnl Allow the user to specify an overall txcrange directory.  If specified,
dnl we look for include and lib under this.
dnl
dnl ######################################################################

AC_ARG_WITH(txcrange-dir,[  --with-txcrange-dir=<location of txcrange installation> ],TXCRANGE_DIR="$withval",TXCRANGE_DIR="")

dnl ######################################################################
dnl
dnl Find txcrange includes - looking in include location if present,
dnl otherwise in dir/include if present, otherwise in default locations,
dnl first parallel, then serial.
dnl
dnl ######################################################################

AC_ARG_WITH(txcrange-incdir,[  --with-txcrange-incdir=<location of txcrange includes> ],
TXCRANGE_INCDIR="$withval",TXCRANGE_INCDIR="")
if test -n "$TXCRANGE_INCDIR"; then
  TXCRANGE_INCPATH=$TXCRANGE_INCDIR
elif test -n "$TXCRANGE_DIR"; then
  TXCRANGE_INCPATH=$TXCRANGE_DIR/include
else
  TXCRANGE_INCPATH="/usr/local/txphysics/include"
fi

if test -n "$TXCRANGE_INCPATH"; then 
  AC_PATH_PROGS(TXCRANGE_H, txcrange.h, "", $TXCRANGE_INCPATH)
  if test -z "$TXCRANGE_H"; then
    AC_MSG_WARN(txcrange.h not found in $TXCRANGE_INCPATH.  Set with --with-txcrange-incdir=)
    TXCRANGE_INC=" "
  else
    TXCRANGE_INCDIR=`dirname $TXCRANGE_H`
    AC_SUBST(TXCRANGE_INCDIR)
    TXCRANGE_INC="-I$TXCRANGE_INCDIR"
    AC_SUBST(TXCRANGE_INC)
    TXCRANGE_DIR=`dirname $TXCRANGE_INCDIR`
  fi
fi

dnl ######################################################################
dnl
dnl Find txcrange libraries
dnl
dnl ######################################################################

AC_ARG_WITH(txcrange-libdir,[  --with-txcrange-libdir=<location of txcrange library> ],
TXCRANGE_LIBDIR="$withval",TXCRANGE_LIBDIR="")

if test -n "$TXCRANGE_LIBDIR"; then
  TXCRANGE_LIBPATH=$TXCRANGE_LIBDIR
elif test -n "$TXCRANGE_DIR"; then
  TXCRANGE_LIBPATH=$TXCRANGE_DIR/lib
else
  TXCRANGE_LIBPATH=""
fi

if test -n "$TXCRANGE_LIBPATH"; then
  AC_PATH_PROGS(LIBTXCRANGE_A, libtxcrange.a, "", $TXCRANGE_LIBPATH)
  if test -z "$LIBTXCRANGE_A"; then
    AC_MSG_WARN(libtxcrange.a not found.  Set with --with-txcrange-libdir=)
    TXCRANGE_LIBS=""
  else
    TXCRANGE_LIBDIR=`dirname $LIBTXCRANGE_A`
    AC_SUBST(TXCRANGE_LIBDIR)
    TXCRANGE_LIBS="-L$TXCRANGE_LIBDIR -ltxcrange $FLIBS"' $(RPATH_FLAG)'"$TXCRANGE_LIBDIR"
  fi
  dnl echo TXCRANGE_LIBS = $TXCRANGE_LIBS
  AC_SUBST(TXCRANGE_LIBS)
fi

dnl ######################################################################
dnl
dnl Define for whether txcrange found
dnl
dnl ######################################################################

if test -n "$TXCRANGE_LIBS"; then
  AC_DEFINE(HAVE_TXCRANGE)
fi