configure.in

一个很好用的MPEG1/4的开源编码器的应用程序

dnl Process this file with autoconf to produce a configure script.
AC_INIT(recmpeg.c)

dnl Set various version strings - taken gratefully from the GTk sources
#
# Making releases:
#   MICRO_VERSION += 1;
#   INTERFACE_AGE += 1;
#   BINARY_AGE += 1;
# if any functions have been added, set INTERFACE_AGE to 0.
# if backwards compatibility has been broken,
# set BINARY_AGE and INTERFACE_AGE to 0.
#
MAJOR_VERSION=1
MINOR_VERSION=0
MICRO_VERSION=5
INTERFACE_AGE=0
BINARY_AGE=3
VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION

AC_SUBST(MAJOR_VERSION)
AC_SUBST(MINOR_VERSION)
AC_SUBST(MICRO_VERSION)
AC_SUBST(INTERFACE_AGE)
AC_SUBST(BINARY_AGE)
AC_SUBST(VERSION)

dnl Setup for automake
AM_INIT_AUTOMAKE(recmpeg, $VERSION)

dnl Detect the canonical host and target build environment
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

dnl Check for tools

AC_PROG_MAKE_SET
AC_PROG_CC
AC_PROG_INSTALL

dnl The alpha architecture needs special flags for binary portability
case "$target" in
    alpha*-*-linux*)
	if test x$ac_cv_prog_gcc = xyes; then
            CFLAGS="$CFLAGS -mcpu=ev4 -Wa,-mall"
        fi
        ;;
    *-*-solaris*)
	LIBS="$LIBS -lsocket -lnsl"
	;;
    *-*-cygwin* | *-*-mingw32*)
        if test "$build" != "$target"; then # cross-compiling
            ac_default_prefix=/usr/local/cross-tools/i386-mingw32msvc
	    LIBS="$LIBS -liberty"
        fi
        ;;
esac

dnl Check for UDP support
AC_ARG_ENABLE(udp,
[  --enable-udp            Support UDP output [default=yes]],
              , enable_udp=yes)
if test x$enable_udp = xyes; then
    CFLAGS="$CFLAGS -DUSE_UDP"
fi

dnl See if we have the getopt_long function
AC_CHECK_LIB(c, getopt_long, CFLAGS="$CFLAGS -D_GNU_SOURCE")
AC_CHECK_HEADER(getopt.h, CFLAGS="$CFLAGS -DHAS_GETOPT_H")

AM_PATH_LIBFAME
CFLAGS="$CFLAGS $LIBFAME_CFLAGS -D_FILE_OFFSET_BITS=64 -D_LARGEFILE_SOURCE"
LIBS="$LIBS $LIBFAME_LIBS"

dnl Finally create all the generated files

AC_OUTPUT([
Makefile
recmpeg.spec
])