boot.asm

DSP GEPE 压缩算法

       .title  "Flash bootup utility for 6211"
        .option D,T
        .length 102
        .width  140
     

PAGE_SIZE     .equ    0x2000	  ;flash page size in byte
FLASH_START   .equ    0x90000000  ;flash start address
BOOT_START    .equ    0x00000000  ;L2 sram start address

CODE_SIZE     .equ    0xFC00      ;application code size in byte

EMIF_GCR      .equ    0x01800000  ;EMIF global control     
EMIF_CE1      .equ    0x01800004  ;address of EMIF CE1 control reg. 
EMIF_CE2	  .equ    0x01800010  ;EMIF CE2 control FIFO
EMIF_CE3      .equ    0x01800014  ;EMIF CE3 control          
EMIF_SDCTRL   .equ    0x01800018  ;EMIF SDRAM control     
EMIF_SDRP     .equ    0x0180001C  ;EMIF SDRM refresh period 
EMIF_CE1_16   .equ    0xffffff13  ;
EMIF_CE1_32   .equ    0x22A28D22  ;
EMIF_CE2_V	  .equ	  0xFFF1C121
EMIF_CE3_V    .equ    0xFFFFFF33  ;EMIF CE3 control   ;0x30
EMIF_SDCTRL_V .equ    0x57116000  ;EMIF SDRAM control ; 把CE0全部改CE3  

 .sect ".boot_load" 
 .global _boot

 .ref _c_int00
 
_boot:
            mvkl  EMIF_GCR,A4    ;EMIF_GCR address ->A4
      ||    mvkl  0x3300,B4      

            mvkh  EMIF_GCR,A4
      ||    mvkh  0x3300,B4  
                            
            stw   B4,*A4     
                    
            mvkl  EMIF_CE2,A4		;EMIF_CE2 address ->A4
      ||	mvkl  EMIF_CE2_V,B4
      
      		mvkh  EMIF_CE2,A4
      ||    mvkh  EMIF_CE2_V,B4
      
            stw   B4,*A4          

            mvkl  EMIF_CE3,A4       ;EMIF_CE3 address ->A4
      ||    mvkl  EMIF_CE3_V,B4     ;

            mvkh  EMIF_CE3,A4
      ||    mvkh  EMIF_CE3_V,B4
      
            stw   B4,*A4 
                           
      ||    mvkl  EMIF_SDCTRL,A4    ;EMIF_SDCTRL address ->A4
      ||    mvkl  EMIF_SDCTRL_V,B4     ;

            mvkh  EMIF_SDCTRL,A4
      ||    mvkh  EMIF_SDCTRL_V,B4     
      
            stw   B4,*A4 
                           
      ||    mvkl  EMIF_SDRP,A4      ;EMIF_SDRP address ->A4
      ||    mvkl  0x61a,B4    ;

            mvkh  EMIF_SDRP,A4
      ||    mvkh  0x61a,B4
            
            stw   B4,*A4


            mvkl  BOOT_START+1024,A4 ;ram start address ->A4
      ||    mvkl  FLASH_START+1024,B4 ;flash start address ->B4

            mvkh  BOOT_START+1024,A4
      ||    mvkh  FLASH_START+1024,B4
            
            zero  A1 
            
_boot_loop:
            ldb   *B4++,B5
            mvkl  CODE_SIZE,B6

            add   1,A1,A1	;A1+=1,inc outer counter
      ||    mvkh  CODE_SIZE,B6
       
            cmplt  A1,B6,B0
            nop    
            stb   B5,*A4++
      [B0]  b     _boot_loop
            nop   5
        
            mvkl .S2 _c_int00, B0
            mvkh .S2 _c_int00, B0
            B    .S2 B0
            nop   5
; 
; end of the bootup routine