sys_init.asm

TI公司24X系列DSP控制无刷直流电机

;===========================================================================
; File Name:	Sys_init.asm
;
; Module Name: S Y S _ I N I T				      
;
; Originator:	Digital Control Systems Group
;			Texas Instruments
;
; Description:  Initializes F24x/xx devices
;
;
;=====================================================================================
; History:
;-------------------------------------------------------------------------------------
; 9-15-2000	Release	Rev 1.0	
;===========================================================================
		.include	"x24x_app.h"
		.def	SYS_INIT   
		.ref	GPR0

SYS_INIT:
;---target dependancy---------------
	.if (x240)

		POINT_PG0
		SETC	INTM			;Disable interrupts
		SPLK	#0h, IMR		;Mask all Ints
		SPLK	#0FFh, IFR		;Clear all Int Flags
		CLRC	SXM			;Clear Sign Extension Mode
		CLRC	OVM			;Reset Overflow Mode
		CLRC	CNF			;Config Block B0 to Data mem.
		LAR	AR1, #03C0h		;Init s/w stack pointer
		MAR	*,AR1

		POINT_B0
		SPLK	#04h, GPR0		;Set 0 wait states for XMIF
		OUT	GPR0, WSGR

		POINT_PF1
		SPLK	#0041h,PLL_CNTL1	;Disable PLL first.=CPUCLK/2,
		SPLK	#00B1h,PLL_CNTL2	;CLKIN(XTAL)=10MHz, PLL*2.0=20MHz
		SPLK	#0081h,PLL_CNTL1	;CLKMD=PLL Enable,SYSCLK/4=CPUCLK/2,
		SPLK	#40C0h,SYSCR	;CLKOUT=CPUCLK

	;Comment out if WD is to be active
		SPLK	#006Fh, WD_CNTL 	;Disable WD if VCCP=5V
		KICK_DOG
		RET
	.endif
;-----------------------------------


;---target dependancy---------------
	.if (x243)
		POINT_PG0
		SETC	INTM			;Disable interrupts
		SPLK	#0h, IMR		;Mask all Ints
		SPLK	#0FFh, IFR		;Clear all Int Flags
		CLRC	SXM			;Clear Sign Extension Mode
		CLRC	OVM			;Reset Overflow Mode
		CLRC	CNF			;Config Block B0 to Data mem.
		SPM	0
		LAR	AR1, #03C0h		;Init s/w stack pointer
		MAR	*,AR1

		POINT_B0
		SPLK	#0040h, GPR0	;Set 0 wait states for XMIF
		OUT	GPR0, WSGR

		POINT_PF1
		SPLK	#40C0h,SYSCR	;CLKOUT=CPUCLK

	;Comment out if WD is to be active
		SPLK	#006Fh, WD_CNTL 	;Disable WD if VCCP=5V
		KICK_DOG
		RET
	.endif
;-----------------------------------

;---target dependancy---------------
	.if (x2407)
		POINT_PG0
		SETC	INTM			;Disable interrupts
		SPLK	#0h, IMR		;Mask all Ints
		SPLK	#0FFh, IFR		;Clear all Int Flags
		CLRC	SXM			;Clear Sign Extension Mode
		CLRC	OVM			;Reset Overflow Mode
		CLRC	CNF			;Config Block B0 to Data mem.
		SPM	0
		LAR	AR1, #03C0h		;Init s/w stack pointer
		MAR	*,AR1

		POINT_B0
		SPLK	#00C0h, GPR0	;Set 1 wait states for I/O space
		OUT	GPR0, WSGR

		POINT_PF1
		SPLK	#0085h, SCSR1	; x4 PLL, ADC en, EV1 en, clr Ill Addr flg

	;Comment out if WD is to be active
		SPLK	#006Fh, WD_CNTL 	;Disable WD if VCCP=5V
		KICK_DOG
		RET
	.endif
;-----------------------------------