admin_db_space.asp

WAP网上购物系统源程序,,有兴趣的朋友,一起研究一下..交流经眼

<!--#include file=INC/skin.asp-->

<%
Dim const_txl_HomeUrl
const_txl_HomeUrl = ""
%>
<!--#include file=admin_login_check.asp-->
<%
Call OpenDataBase
txl_SiteHead const_txlname&"- 管理员"
showspace
Call CloseDataBase
web_end
Response.End()
sub showspace
%>
<br>
<table width="90%" border="0" cellspacing="0" cellpadding="0" align="center">
  <tr> 
    <td height="20"> <p> <a href=help.htm><%=const_txlname%>管理系统</a> &gt;&gt; <a href="help.htm">管理首页</a>&gt;&gt;查看空间占用情况<br>
      <%
	  if not fsolimit then
	  	call showspaceinfo
	  end if
	  %>
      <p></p></td>
  </tr>
</table>
<%end sub%>
<%sub showspaceinfo
	dim txl_Space,Upload_Space,Database_Space
	dim f,fso
	Set fso = CreateObject("Scripting.FileSystemObject") 
	Set f = fso.GetFolder(Server.Mappath("")) 
	txl_Space = f.Size
	Set f = Nothing
	Set f = fso.GetFolder(Server.Mappath(""&const_faceuploadurl2)) 
	Upload_Space = f.Size
	set f=nothing
	Set f = fso.GetFile(Server.Mappath(Replace(const_txl_HomeUrl & const_AccessDatabase,"/","\")))
	Database_Space = f.Size
	Set f = Nothing
%>
<table width=96% align="center">
        <tr> 
          <td><br>
      Wap影音目录总占用空间：<font color="#FF0000"><%=PrintSpaceValue(txl_Space)%></font> 
      [<font color="#FF0000"><%=txl_Space%></font> Bytes]<br>
      上传相片文件总占用空间：<font color="#FF0000"><%=PrintSpaceValue(Upload_Space)%></font> 
      [<font color="#FF0000"><%=Upload_Space%></font> Bytes]<br>
      Wap影音数据库文件大小：<font color="#FF0000"><%=PrintSpaceValue(database_Space)%></font>  [<%=database_Space%> Bytes]<br> </td>
        </tr>
      </table>
<%
end sub
function fsolimit()
	on error resume next
	fsolimit=false
	dim fsolimitstr,testfso
	Set testfso = CreateObject("Scripting.FileSystemObject") 
	if not isobject(testfso) then	'不支持FSO
		fsolimit=true
		fsolimitstr="注意：此功能需要FSO的支持，您现在使用的服务器<font color=""red"">不支持</font>该组件,所以该功能无法实现！"
	else
		fsolimit=false
		fsolimitstr="注意：此功能需要FSO的支持，您现在使用的服务器<font color=""green"">支持</font>该组件。"
	end if
	Response.Write(fsolimitstr)
end function
Function PrintSpaceValue(vv)

	Dim v
	v = vv
	If v > 1024*1024 Then
		v = v/1024/1024
		If inStr(v,".") Then
			v = Left(v,inStr(v,".")+2)
		End If
		v = v & " M"
	Else
		v = Fix(v/1024) & " K"
	End If
	PrintSpaceValue = v

End Function
%>