main.pas

ODAC+SDAC源代码

unit Main;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls,
  MemDS, DBAccess,  DB, MSAccess, SdacVcl;

type
  TfmMain = class(TForm)
    MSConnection: TMSConnection;
    MSQuery: TMSQuery;
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    MSConnectDialog: TMSConnectDialog;
    ToolBar: TPanel;
    btOpen: TButton;
    btClose: TButton;
    btPrepare: TButton;
    btUnPrepare: TButton;
    btExecute: TButton;
    meSQL: TMemo;
    StatusBar: TStatusBar;
    Panel1: TPanel;
    DBNavigator1: TDBNavigator;
    btRefreshRecord: TButton;
    cbDebug: TCheckBox;
    Label1: TLabel;
    edUpdatingTable: TEdit;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btPrepareClick(Sender: TObject);
    procedure btUnPrepareClick(Sender: TObject);
    procedure btExecuteClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure meSQLExit(Sender: TObject);
    procedure MSQueryAfterExecute(Sender: TObject; Result: Boolean);
    procedure btRefreshRecordClick(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
    procedure edUpdatingTableExit(Sender: TObject);
  private
    { Private declarations }
    procedure ShowState;
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation

{$R *.nfm}

procedure TfmMain.ShowState;
var
  St:string;

  procedure AddSt(S:string);
  begin
    if St <> '' then
      St := St + ', ';
    St := St + S;
  end;

begin
  St := '';

  if MSQuery.Prepared then begin
    AddSt('Prepared');

    if MSQuery.IsQuery then
      AddSt('IsQuery');
  end;

  if MSQuery.Active then
    AddSt('Active')
  else
    AddSt('Inactive');

  if MSQuery.Executing then
    AddSt('Executing');

  if MSQuery.Fetching then
    AddSt('Fetching');

  edUpdatingTable.Text := MSQuery.UpdatingTable;

  StatusBar.Panels[0].Text := St;
end;

procedure TfmMain.meSQLExit(Sender: TObject);
begin
  if Trim(MSQuery.SQL.Text) <> Trim(meSQL.Lines.Text) then
    MSQuery.SQL.Text := meSQL.Lines.Text;
  ShowState;
end;

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  try
    MSQuery.Open;
  finally
    ShowState;
  end;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  MSQuery.Close;
  ShowState;
end;

procedure TfmMain.btPrepareClick(Sender: TObject);
begin
  try
    MSQuery.Prepare;
  finally
    ShowState;
  end;
end;

procedure TfmMain.btUnPrepareClick(Sender: TObject);
begin
  MSQuery.UnPrepare;
  ShowState;
end;

procedure TfmMain.btExecuteClick(Sender: TObject);
begin
  try
    MSQuery.Execute;
  finally
    ShowState;
  end;
end;

procedure TfmMain.FormShow(Sender: TObject);
begin
  meSQL.Lines.Assign(MSQuery.SQL);
  ShowState;

  cbDebug.Checked := MSQuery.Debug;
end;

procedure TfmMain.MSQueryAfterExecute(Sender: TObject; Result: Boolean);
begin
  if csDestroying in ComponentState then
    Exit;

  ShowState;

  if Result then
    StatusBar.Panels[0].Text := StatusBar.Panels[0].Text + '   >>>> Success'
  else
    StatusBar.Panels[0].Text := StatusBar.Panels[0].Text + '   >>>> Fail';

{$IFDEF WIN32}
  MessageBeep(1);
{$ENDIF}
end;

procedure TfmMain.btRefreshRecordClick(Sender: TObject);
begin
  MSQuery.RefreshRecord;
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  MSQuery.Debug := cbDebug.Checked;
end;

procedure TfmMain.edUpdatingTableExit(Sender: TObject);
begin
  try
    MSQuery.UpdatingTable := edUpdatingTable.Text;
  except
    edUpdatingTable.SetFocus;
    raise;
  end;
end;

end.