main.pas

ODAC+SDAC源代码

unit Main;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, OdacVcl,
{$ENDIF}
  Db, OraScript, MemDS, DBAccess, Ora, OraSmart;

type
  TfmMain = class(TForm)
    OraSession: TOraSession;
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    ToolBar: TPanel;
    btOpen: TButton;
    DBNavigator: TDBNavigator;
    btClose: TButton;
    ConnectDialog: TConnectDialog;
    meComments: TDBMemo;
    Query: TSmartQuery;
    btCreate: TButton;
    btDrop: TButton;
    sqCreate: TOraScript;
    sqDrop: TOraScript;
    Splitter1: TSplitter;
    ToolBar1: TToolBar;
    btLoad: TButton;
    btSave: TButton;
    OpenDialog: TOpenDialog;
    SaveDialog: TSaveDialog;
    ToolButton1: TToolButton;
    cbLongStrings: TCheckBox;
    btClear: TButton;
    ToolButton2: TToolButton;
    cbUseNet: TCheckBox;
    cbDebug: TCheckBox;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btLoadClick(Sender: TObject);
    procedure btSaveClick(Sender: TObject);
    procedure btCreateClick(Sender: TObject);
    procedure btDropClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure cbLongStringsClick(Sender: TObject);
    procedure btClearClick(Sender: TObject);
    procedure cbUseNetClick(Sender: TObject);
    procedure cbDebugClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  fmMain: TfmMain;

implementation

{$R *.nfm}

procedure TfmMain.btOpenClick(Sender: TObject);
begin
  Query.Open;
end;

procedure TfmMain.btCloseClick(Sender: TObject);
begin
  Query.Close;
end;

procedure TfmMain.btLoadClick(Sender: TObject);
var
  List: TStringList;
begin
  if Query.Active and OpenDialog.Execute then begin
    if Query.State = dsBrowse then
      Query.Edit;

    if Query.FieldByName('Value') is TBlobField then
      TBlobField(Query.FieldByName('Value')).LoadFromFile(OpenDialog.FileName)
    else begin
      List := TStringList.Create;
      try
        List.LoadFromFile(OpenDialog.FileName);
        Query.FieldByName('Value').AsString := List.Text;
      finally
        List.Free;
      end;
    end;
  end;
end;

procedure TfmMain.btSaveClick(Sender: TObject);
var
  List: TStringList;
begin
  if not Query.EOF and SaveDialog.Execute then
    if Query.FieldByName('Value') is TBlobField then
      TBlobField(Query.FieldByName('Value')).SaveToFile(SaveDialog.FileName)
    else begin
      List := TStringList.Create;
      try
        List.Text := Query.FieldByName('Value').AsString;
        List.SaveToFile(SaveDialog.FileName);
      finally
        List.Free;
      end;
    end;
end;

procedure TfmMain.btCreateClick(Sender: TObject);
begin
  OraSession.Connect;
  if OraSession.OracleVersion >= '8.0.0.0' then
    sqCreate.MacroByName('Len').AsInteger := 4000
  else
    sqCreate.MacroByName('Len').AsInteger := 2000;
  sqCreate.Execute;
end;

procedure TfmMain.btDropClick(Sender: TObject);
begin
  sqDrop.Execute;
end;

procedure TfmMain.FormCreate(Sender: TObject);
begin
  cbLongStrings.Checked := Query.OptionsDS.LongStrings;
  cbUseNet.Checked := OraSession.Options.Net;
  cbDebug.Checked := Query.Debug;
end;

procedure TfmMain.cbLongStringsClick(Sender: TObject);
var
  OldActive: boolean;
begin
  OldActive := Query.Active;
  Query.Active := False;
  Query.OptionsDS.LongStrings := cbLongStrings.Checked;
  Query.Active := OldActive;
end;

procedure TfmMain.btClearClick(Sender: TObject);
begin
  if Query.Active then begin
    if Query.State = dsBrowse then
      Query.Edit;
    Query.FieldByName('Value').AsString := '';
  end;
end;

procedure TfmMain.cbUseNetClick(Sender: TObject);
begin
  OraSession.Options.Net := cbUseNet.Checked;
end;

procedure TfmMain.cbDebugClick(Sender: TObject);
begin
  Query.Debug := cbDebug.Checked;
  sqCreate.Debug := cbDebug.Checked;
  sqDrop.Debug := cbDebug.Checked;
end;

end.