www51.sc2

web51的开发库

MEMORY
{
  text   (rx)   : ORIGIN = 0, LENGTH = 0x10000
  bit    (rw!x) : ORIGIN = 0, LENGTH = 0x80
  data   (rw!x) : ORIGIN = 0, LENGTH = 0x100
  xdata  (rw!x) : ORIGIN = 0, LENGTH = 0x400
  edata  (rw!x) : ORIGIN = 0, LENGTH = 0
  eeprom (rw!x) : ORIGIN = 0, LENGTH = 0x800
}

SECTIONS
{
  /* Read-only sections, merged into text segment: */
  .hash         : { *(.hash)		}
  .dynsym       : { *(.dynsym)		}
  .dynstr       : { *(.dynstr)		}
  .gnu.version  : { *(.gnu.version)	}
  .gnu.version_d  : { *(.gnu.version_d)	}
  .gnu.version_r  : { *(.gnu.version_r)	}

  .rel.init     : { *(.rel.init)	}
  .rela.init    : { *(.rela.init)	}
  .rel.text     :
    {
      *(.rel.text)
      *(.rel.text.*)
      *(.rel.gnu.linkonce.t*)
    }
  .rela.text    :
    {
      *(.rela.text)
      *(.rela.text.*)
      *(.rela.gnu.linkonce.t*)
    }
  .rel.fini     : { *(.rel.fini)	}
  .rela.fini    : { *(.rela.fini)	}
  .rel.rodata   :
    {
      *(.rel.rodata)
      *(.rel.rodata.*)
      *(.rel.gnu.linkonce.r*)
    }
  .rela.rodata  :
    {
      *(.rela.rodata)
      *(.rela.rodata.*)
      *(.rela.gnu.linkonce.r*)
    }
  .rel.data     :
    {
      *(.rel.data)
      *(.rel.data.*)
      *(.rel.gnu.linkonce.d*)
    }
  .rela.data    :
    {
      *(.rela.data)
      *(.rela.data.*)
      *(.rela.gnu.linkonce.d*)
    }
  .rel.ctors    : { *(.rel.ctors)	}
  .rela.ctors   : { *(.rela.ctors)	}
  .rel.dtors    : { *(.rel.dtors)	}
  .rela.dtors   : { *(.rela.dtors)	}
  .rel.got      : { *(.rel.got)		}
  .rela.got     : { *(.rela.got)		}
  .rel.bss      : { *(.rel.bss)		}
  .rela.bss     : { *(.rela.bss)		}
  .rel.plt      : { *(.rel.plt)		}
  .rela.plt     : { *(.rela.plt)		}

  /* Internal text space or external memory */

  .text :
  {
    *(vectors)
    *(.init)
    *(.progmem.gcc*)
    *(.progmem*)
    *(reset_begin)
    *(reset_device)
    *(reset_network)
    *(reset_end)
    *(one_times)
    *(fast_begin)
    *(fast)
    *(fast_end)
    *(slow_begin)
    *(slow)
    *(slow_end)
    *(cpu_rom)
    *(.text)
    *(.text.*)
    *(cpu_dir_begin)
    *(cpu_dir)
    *(cpu_dir_end)
    *(cpu_files)
    *(cpu_top)
    *(.fini)
    PROVIDE (intIE0 = _reti_) ;
    PROVIDE (intTF0 = _reti_) ;
    PROVIDE (intIE1 = _reti_) ;
    PROVIDE (intTF1 = _reti_) ;
    PROVIDE (intRITI = _reti_) ;
    _etext = . ;
  } > text

  .reg : AT (ADDR (.text) + SIZEOF (.text))
  {
    *(.regbank)
    __reg_start = . ;
    *(.rdata*)
    __reg_end = . ;
  } > data

  .rbss	:
  {
    __rbss_start = . ;
    *(.rbss*)
    __rbss_end = . ;
  } > data

  .bdata ((MAX (0x20, ( SIZEOF(.rbss) + ADDR(.rbss))))) :
  {
    PROVIDE (__bdata_start = .) ;
    *(.bdata*)
    __bdata_end = . ;
  } > data

  .bbss	(SIZEOF(.bdata) + ADDR(.bdata)) :
  {
    PROVIDE (__bbss_start = .) ;
    *(.bbss*)
    __bbss_end = . ;
  } > data

  .bit	((((SIZEOF(.bbss) + ADDR(.bbss)) - 0x20) * 8 )) :
  {
    PROVIDE (__bit_start = .) ;
    *(.bitdata*)
    __bit_end = . ;
  } > bit

  .bitbss SIZEOF(.bit) + ADDR(.bit) :
  {
    PROVIDE (__bbss_start = .) ;
    *(.bitbss*)
    __bbss_end = . ;
  } > bit

  .data	(((SIZEOF(.bit) + SIZEOF(.bitbss) + 7) / 8) + SIZEOF(.bbss) + ADDR(.bbss)) :
  {
    PROVIDE (__data_start = .) ;
    *(.data)
    *(.gnu.linkonce.d*)
    __data_end = . ;
  } > data

  .bss SIZEOF(.data) + ADDR(.data) :
  {
    PROVIDE (__bss_start = .) ;
    *(.bss*)
    *(COMMON)
    __bss_end = . ;
  } > data

  .idata SIZEOF(.bss) + ADDR(.bss) :
  {
    PROVIDE (__idata_start = .) ;
    *(.idata)
    __idata_end = . ;
    PROVIDE (stack = .) ;
  } > data

  .ibss  0x90 : /* SIZEOF(.idata) + ADDR(.idata) :*/
  {
    PROVIDE (__ibss_start = .) ;
    *(buf_data)
    *(.ibss)
    __ibss_end = . ;
/*    PROVIDE (stack = .) ; */
  } > data

  .xdata :
  {
    PROVIDE (__xdata_start = .) ;
    *(.xdata*)
    __xdata_end = . ;
  } > xdata

  .ixdata SIZEOF(.xdata) :
  {
    PROVIDE (__ixdata_start = .) ;
    *(.xbss*)
    __ixdata_end = . ;
  } > xdata

  .edata :
  {
    PROVIDE (__edata_start = .) ;
    *(.edata*)
    __edata_end = . ;
  } > edata

  .iedata SIZEOF(.edata) :
  {
    PROVIDE (__iedata_start = .) ;
    *(.ebss*)
    __iedata_end = . ;
  } > edata

  .eeprom :
  {
    PROVIDE (__eeprom_start = .) ;
    *(ee_config)
    *(ee_dir_begin)
    *(ee_dir)
    *(ee_dir_end)
    *(ee_files)
    *(.eeprom*)
    __eeprom_end = . ;
  } > eeprom

  /* Stabs debugging sections.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  .stab.excl 0 : { *(.stab.excl) }
  .stab.exclstr 0 : { *(.stab.exclstr) }
  .stab.index 0 : { *(.stab.index) }
  .stab.indexstr 0 : { *(.stab.indexstr) }
  .comment 0 : { *(.comment) }
 
  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to the beginning
     of the section so we begin them at 0.  */

  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }

  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }

  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }

  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }
}