web.tcl

这个代码是tcl程序

###############################################
# WEB Traffic Generator - web.tcl             #
# L. Xu, K. Harfoush, and I. Rhee             #
# based on scripts from S. Floyd and E. Souza #
###############################################

proc add_web_nodes {bdel randomize dir} {
  global ns n1 n2
  global sf_ rf_
  global sb_ rb_
  global count

  if {$randomize == 0} {
    set x [expr $bdel/2]ms
    set y [expr $bdel/2]ms
  } else {
    set x [ns-random]
    set y [ns-random]
    set x [expr $bdel*($x/2147483647.0)]ms
    set y [expr $bdel*($y/2147483647.0)]ms
  }

  set i $count

  if {$dir == 0} {
    set sf_($i) [$ns node]
    set rf_($i) [$ns node]
    $ns duplex-link $sf_($i) $n1 10000Mb $x DropTail
    $ns duplex-link $rf_($i) $n2 10000Mb $y DropTail
  } else {
    set sb_($i) [$ns node]
    set rb_($i) [$ns node]
    $ns duplex-link $sb_($i) $n2 10000Mb $x DropTail
    $ns duplex-link $rb_($i) $n1 10000Mb $y DropTail
  }
  incr count
}


proc add_web_traffic {bdel nums ip ps os flowid dir} {
  global ns n1 n2
  global sf_ rf_
  global sb_ rb_
  global count
  global pool

  set numWeb 10
  PagePool/WebTraf set FID_ASSIGNING_MODE_ 2
  set pool [new PagePool/WebTraf]  

  # for ns2.2.6
  $pool set resp_trace_ 0   
  $pool set req_trace_ 0

  $pool set-num-client $numWeb     
  $pool set-num-server $numWeb     
  $pool set sameFid_ $flowid

  for {set i 0} {$i < $numWeb} {incr i} {
    add_web_nodes $bdel 1 $dir
    if {$dir == 0} {
      $pool set-server $i $sf_([expr $count - 1])
      $pool set-client $i $rf_([expr $count - 1])
    } else {
      $pool set-server $i $sb_([expr $count - 1])
      $pool set-client $i $rb_([expr $count - 1])
    }

  }

  $pool set-num-session $nums
  set numPage 1000
  for {set i 0} {$i < $nums} {incr i} {
    set interPage [new RandomVariable/Exponential]
    $interPage set avg_ $ip
    set pageSize [new RandomVariable/Constant]
    $pageSize set val_ $ps
    set interObj [new RandomVariable/Exponential]
    $interObj set avg_ [expr 0.01]
    set objSize [new RandomVariable/ParetoII]
    $objSize set avg_ $os
    $objSize set shape_ 1.2
    $pool create-session $i $numPage 0 $interPage $pageSize $interObj $objSize 
  }
}