ex3.5(1).inp

ansys有限元分析程序

! 3.5  矩形截面梁的纵横弯曲分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
/FILNAME, EX3.5(1)
/PREP7
/TITLE, EX3.5(1), TIE ROD WITH LATERAL LOADING, NO STRESS STIFFENING.
! （1）定义求解类型，实常数和材料参数
ANTYPE, STATIC
ET, 1, BEAM4, , , , , , 1
R, 1, 0.403225e-2, 0.135492e-5, 0.135492e-5, 0.0635, 0.0635
MP, EX, 1, 210E9
MP, PRXY, , 0.3
! （2）定义节点位置
N, 1
N, 5, 2.54
FILL
! （3）定义单元连接关系
E, 1, 2
EGEN, 4, 1, 1
! （4）定义位移约束和荷载条件
D, ALL, UY, , , , , ROTX, ROTZ
D, 1, UZ
NSEL, S, , , 5
DSYM, SYMM, X
NSEL, ALL
! （5）施加荷载
F, 1, FX, -97740
SFBEAM, ALL, 1, PRES, 314
FINISH
! （6）进入求解模块，开始求解
/SOLU
SOLVE
FINISH
! （7）进入后处理模块，显示位移计算结果，提取左边支座节点的转角和跨中挠度
/POST1
NSEL, S, , , 1, 5, 4
PRNSOL, U, Z
PRNSOL, ROT, Y
NSEL, ALL
PRRSOL
RGHT_END = NODE (2.54, 0, 0)
LFT_END  = NODE (0, 0, 0)
*GET, UZ_MX_C2, NODE, RGHT_END, U, Z
*GET, SLOPE_C2, NODE, LFT_END, ROT, Y
FINISH
! （8）在时间历程后处理器中，叠加处理5号节点位置的弯矩
/POST26
RFORCE, 2, RGHT_END, M, Y
STORE
*GET, M_MX_C2, VARI, 2, EXTREM, VMAX
FINISH
! （9）重新进入前处理模块，重新计算考虑应力强化效应的压杆
/PREP7
/TITLE, EX3.5(2), TIE ROD WITH LATERAL LOADING, STRESS STIFFENING PRESENT.
SSTIF, ON
NSUBST, 5
AUTOTS, ON
FINISH
! (10) 进入求解模块，指定最小收敛误差后，开始非线性求解
/SOLU
CNVTOL, F, , .0001, , 1
SOLVE
FINISH
! (11) 进入后处理模块，显示位移计算结果，提取左边支座节点的转角和跨中挠度
/POST1
NSEL, S, , , 1, 5, 4
PRNSOL, U, Z
PRNSOL, ROT, Y
PRRSOL
*GET, UZ_MX_C1, NODE, RGHT_END, U, Z
*GET, SLOPE_C1, NODE, LFT_END, ROT, Y
FINISH
! (12) 在时间历程后处理器中，叠加处理跨中（5号节点）位置的弯矩
/POST26
RFORCE, 2, RGHT_END, M, Y
STORE
*GET, M_MX_C1, VARI, 2, EXTREM, VMAX
*STATUS, PARM
FINISH