ex4.10(1).inp

ansys有限元分析程序

! 4.10  在端部集中力下的变截面悬臂梁
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! (1)设置工程选项，定义分析类型、单元类型和材料参数
/FILNAME, EX4.10(1)
/PREP7
/TITLE, EX4.10(1), LATERALLY LOADED TAPERED SUPPORT STRUCTURE (QUAD. ELEMENTS)
! 使用 PLANE42 单元
ANTYPE, STATIC
ET, 1, PLANE42, , , 3, , , 2 以提取中间节点的结果
R, 1, 50.8
MP, EX, 1, 207E3
MP, NUXY, 1, 0.0
! (2)定义节点位置和单元连接
N, 1, 635
N, 7, 1905
FILL
N, 8, 635, -76.2
N, 14, 1905, -228.6
FILL
E, 2, 1, 8, 9
EGEN, 6, 1, 1
! (3)选择节点，施加位移边界条件和荷载
NSEL, S, LOC, X, 1905
D, ALL, ALL
NSEL, ALL
F, 1, FY, -17793
FINISH
! (4)在求解模块，开始求解
/SOLU
OUTPR, , 1
SOLVE
FINISH
! (5)提取指定位置节点的应力，绘制变形图
/POST1
END_NODE = NODE (1905, 0, 0)
*GET, STS_E_42, NODE, END_NODE, S, X
PLDISP, 2
MID_NODE = NODE (1270, 0, 0)
*GET, STS_M_42, NODE, MID_NODE, S, EQV
PLNSOL, S, X
PLNSOL, S, 1
PLNSOL, S, 3
FINISH
! (6)改用更高阶的平面应力单元PLANE82重新计算
/PREP7
/TITLE, EX4.10(2), LATERALLY LOADED TAPERED SUPPORT STRUCTURE (PLANE82).
ET, 1, PLANE82, , , 3, , , 2 间节点的结果
EMID
NSEL, R, LOC, X, 1905
NSEL, R, LOC, Y, -114.3
D, ALL, ALL
NSEL, ALL
FINISH
! (7)在求解模块求解
/SOLU
SOLVE
FINISH
! (8)提取指定位置的节点的应力计算结果
/POST1
END_NODE = NODE (1905, 0, 0)
*GET, STS_E_82, NODE, END_NODE, S, X
MID_NODE = NODE (1270, 0, 0)
*GET, STS_M_82, NODE, MID_NODE, S, EQV
PLNSOL, S, X
PLNSOL, S, 1
PLNSOL, S, 3
FINISH