ex4.13(1).inp

ansys有限元分析程序

! 4.13  均匀拉力作用下含圆孔板的孔边应力集中
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）设置工程选项、分析类型、单元类型和材料参数
/FILNAME, EX4.13(1)
/PREP7
SMRT, OFF
/TITLE, EX4.13(1), STRESS CONCENTRATION AT A HOLE IN A PLATE with PLANE2.
/NOPR
ANTYPE, STATIC
ET, 1, PLANE2
MP, EX, 1, 207E3
MP, NUXY, 1, 0.3
! （2）定义关键点
K, 1, 152.4
K, 2, 152.4, 152.4
K, 3, , 152.4
K, 4, , 12.7
K, 5, 12.7
K, 6
! （3）定义线和线单元剖分的尺寸
L, 1, 2
L, 2, 3
L, 3, 4
LESIZE, 3, , , 4, .25
LARC, 4, 5, 6, 12.7
LESIZE, 4, , , 6
L, 5, 1
LESIZE, 5, , , 4, 4
! （4）定义面并将其剖分为面单元, 图形显示单元布置
AL, 1, 2, 3, 4, 5
ESIZE, , 4
AMESH, ALL
/AUTO, 1
/PLOPTS, INFO, 0
/PLOPTS, WINS, 0
/WINDOW, , LTOP
EPLOT
! （5）选择相应的线, 施加位移和荷载边界条件
LSEL, S, LINE, , 3, 5, 2
DL, ALL, , SYMM
LSEL, S, LINE, , 1
NSLL, , 1
SF, ALL, PRES, -6.895
LSEL, ALL
NSEL, ALL
CSYS, 1
FINISH
! （6）进入求解模块求解
/SOLU
SOLVE
FINISH
SAVE
! （7）进入后处理, 显示计算结果
/POST1
SET, 1, 1
NSORT, S, X, , , 3
PRNSOL, S, COMP
/WINDOW, 1, OFF
/NOERASE
/DSCALE, 2, 1
/WINDOW, 2, RTOP
PLNSOL, S, X
PLNSOL, S, Y
*GET, CRSESTR, NODE, 18, S, X
*STATUS, PARM
! （8）将计算结果保存到文件TABLE_1
SAVE, TABLE_1
! （9）改变单元类型为PLANE42, 用子模型技术重新计算
FINISH
/CLEAR, NOSTART
/FILNAME, 4.13(2)
/PREP7
SMRT, OFF
/NOPR
/TITLE, EX4.13(2), STRESS CONCENTRATION AT A HOLE IN A PLATE With PLANE42 SUB-MODEL.
ANTYPE, STATIC
ET, 1, PLANE42
MP, EX, 1, 207E3
MP, NUXY, 1, 0.3
! (10) 在柱坐标系下定义孔边子模型上的关键点
CSYS, 1
K, 10, 12.7, 45
K, 11, 12.7, 90
K, 12, 38.1, 45
K, 13, 38.1, 90
A, 10, 12, 13, 11
ESIZE, , 8
MSHK, 1
MSHA, 0, 2D
AMESH, 1
! (11) 设置窗口选项后, 绘制单元布置
/WINDOW, 2, OFF
/ERASE
/PLOPTS, INFO, 0
/PLOPTS, WINS, 0
/WINDOW, , LTOP
/USER
/DIST, 1, 18
/FOCUS, 1, 14, 25
EPLOT
LSEL, S, LINE, , 1, 2
NSLL, , 1
NWRITE
LSEL, ALL
NSEL, ALL
FINISH
SAVE
! (12) 在后处理模块恢复模型数据, 读入计算结果
/POST1
RESUME, EX4.13(1).db
FILE, EX4.13(1), rst
CBDOF, , , , , , , 0, , 0
! (13) 重新读模型, 施加不同的边界条件
FINISH
/PREP7
SMRT, OFF
RESUME, 4.13(2).DB
/NOPR
/INPUT, , cbdo, , :cb1
/GOPR
LSEL, S, LINE, , 3
DL, ALL, , SYMM
FINISH
! (14) 进入求解模块求解
/SOLU
SOLVE
FINISH
! (15) 在后处理模块显示应力计算结果, 
/POST1
SET, 1, 1
NSORT, S, X, , , 3
PRNSOL, S, COMP
/WINDOW, 1, OFF
/AUTO, 3
/WINDOW, 3, BOT
/NOERASE
/PLOPTS, MINM, 1
/USER, 3
/DIST, 3, 5.08
/FOCUS, 3, 5.08, 12.7
/CONTOUR, 3, , AUTO
PLNSOL, SX
*GET, SUBSTR, NODE, 18, S, X
! (16) 将计算结果保存到文件TABLE_2
SAVE, TABLE_2
! (17) 改变单元类型为PLANE146, 重新计算
FINISH
/CLEAR, NOSTART
/FILNAME, 4.13(3)
/PREP7
SMRT, OFF
/TITLE, EX4.13(3), STRESS CONCENTRATION AT A HOLE IN A PLATE With PLANE146 Element.
/NOPR
ANTYPE, STATIC
ET, 1, PLANE146
MP, EX, 1, 207E3
MP, NUXY, 1, 0.3
! (18)定义关键点
K, 1, 152.4
K, 2, 152.4, 152.4
K, 3, , 152.4
K, 4, , 12.7
K, 5, 12.7
K, 6
! (19)定义线和单元剖分的段数
L, 1, 2
L, 2, 3
L, 3, 4
LESIZE, 3, , , 4, .25
LARC, 4, 5, 6, 12.7
LESIZE, 4, , , 6
L, 5, 1
LESIZE, 5, , , 4, 4
! (20) 定义面并将其剖分为面单元, 图形显示单元布置
AL, 1, 2, 3, 4, 5
ESIZE, , 4
AMESH, ALL
/AUTO, 1
/PLOPTS, INFO, 0
/PLOPTS, WINS, 0
/WINDOW, , LTOP
EPLOT
! (21) 选择相应的线, 施加位移和荷载边界条件
LSEL, S, LINE, , 3, 5, 2
DL, ALL, , SYMM
LSEL, S, LINE, , 1
NSLL, , 1
SF, ALL, PRES, -6.895
LSEL, ALL
NSEL, ALL
CSYS, 1
FINISH
! (22) 进入求解模块求解
/SOLU
SOLVE
FINISH
! (23) 进入后处理, 显示计算结果
/POST1
SET, 1, 1
/WINDOW, 1, OFF
/NOERASE
/DSCALE, 2, 1
/WINDOW, 2, RTOP
PLNSOL, S, X
*GET, SUBSTR, NODE, 18, S, X
! (24) 将结果数据保存到数据库TABLE_3
SAVE, TABLE_3
FINISH
! (25) 从各个数据库中恢复数据, 依次输出显示
RESUME, TABLE_1
*STATUS, PARM
RESUME, TABLE_2
*STATUS, PARM
RESUME, TABLE_3
*STATUS, PARM
FINISH
! (26) 删除中间数据文件
/DEL, TABLE_1
/DEL, TABLE_2
/DEL, TABLE_3