ex3.6.inp

ansys有限元分析程序

! 3.6  空间刚架静力分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
/FILNAME, EX3.6
/TITLE, EX3.6, SPACE FRAME STATIC ANALYSIS.
! （1）在前处理模块中定义节点位置
/PREP7
/VUP, 1, Z
/view, 1, 2, -5, 1
/ESHAPE, 1
/PNum, node, 1
/PNum, elem, 1
N, 1, -6, -6, 6
N, 2, 0, 0, 0    $    N, 3, 12, -6, 0    $    N, 4, -6, 0, 6
N, 5, 0, 0, 6    $    N, 6, 6, 0, 6
! （2）在前处理模块中定义单元信息
ET, 1, BEAM4
MP, EX, 1, 200e6
MP, GXY, 1, 50E6
R, 1, 0.0015, 0.01, 0.01, 0.1, 0.1, , , 0.02, 0, 0
E, 1, 4
E, 4, 5    $    E, 2, 5    $    E, 5, 6    $    E, 3, 6
! （3）在前处理模块中定义位移约束和荷载信息
D, 1, ALL
D, 2, ALL
D, 3, ALL
F, 4, MX, 2
F, 5, FY, -4
SFBeam, 2, 1, PRESS, 1
FINISH
! （4）在求解模块求解
/SOLU
SOLVE
FINISH
! （5）在后处理模块中显示节点位移计算结果
/POST1
PLDISP, 2
PRDISP
! （6）定义单元表，通过单元表列表显示单元内力
ETABLE, IMFORX, SMISC, 1
ETABLE, IMFORY, SMISC, 2
ETABLE, IMFORZ, SMISC, 3
ETABLE, IMMOMX, SMISC, 4
ETABLE, IMMOMY, SMISC, 5
ETABLE, IMMOMZ, SMISC, 6
ETABLE, JMFORX, SMISC, 7
ETABLE, JMFORY, SMISC, 8
ETABLE, JMFORZ, SMISC, 9
ETABLE, JMMOMX, SMISC, 10
ETABLE, JMMOMY, SMISC, 11
ETABLE, JMMOMZ, SMISC, 12
PRETAB, IMFORX, IMFORY, IMFORZ, IMMOMX, IMMOMY, IMMOMZ
PRETAB, JMFORX, JMFORY, JMFORZ, JMMOMX, JMMOMY, JMMOMZ
! （7）通过单元表用“PLLS”命令绘制结构内力图
/TITLE, AXIAL FORCE DIAGRAM
PLLS, IMFORX, JMFORX
/TITLE, SHEAR FORCE DIAGRAM IN XZ PLANE
PLLS, IMFORY, JMFORY
/TITLE, SHEAR FORCE DIAGRAM IN XY PLANE
PLLS, IMFORZ, JMFORZ
/TITLE, TORSION MOMENT DIAGRAM
PLLS, IMMOMX, JMMOMX
/TITLE, BENDING MOMENT DIAGRAM AROUND Y
PLLS, IMMOMY, JMMOMY
/TITLE, BENDING MOMENT DIAGRAM AROUND Z
PLLS, IMMOMZ, JMMOMZ
FINISH