ex6.3.inp

ansys有限元分析程序

! 6.3  悬臂压杆的过曲屈分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! (1)设置工程选项、单元类型、实常数和材料参数
/FILNAME, EX6.3
/PREP7
/TITLE, EX6.3, LARGE DEFLECTIONS OF A BUCKLED BAR (THE ELASTICA).
ANTYPE, STATIC
NLGEOM, ON
ET, 1, BEAM3, , , , , , , 1
R, 1, 161.29, 2167.86, 12.7
MP, EX, 1, 207000
MP, PRXY, , 0.3
! （2）定义节点和单元
N, 1
N, 11, , 2540
FILL
E, 1, 2
EGEN, 10, 1, 1
FINISH
! （3）设置求解选项, 位移约束和荷载, 开始求解
/SOLU
SOLCONTROL, 0
NEQIT, 250
OUTPR, BASIC, LAST
D, 1, ALL
FCR=-171.5
PI=3.14159265359
F, 11, FY, FCR*1.015
F, 11, FX, 1
SOLVE
! (4)增加荷载, 继续求解
FDEL, 11, FX
F, 11, FY, FCR*1.063
SOLVE
F, 11, FY, FCR*1.152
SOLVE
F, 11, FY, FCR*1.293
SOLVE
F, 11, FY, FCR*1.518
SOLVE
F, 11, FY, FCR*1.884
SOLVE
FINISH
! (5)在一般后处理模块中, 绘制后屈曲构型图
/POST1
/USER
/FOCUS, , 1270, 1270
/DIST, , 1397
/DSCALE, , 1
SET, 1, 0
PLDISP, 1
/NOERASE
SET, 2, 0
PLDISP
SET, 3, 0
PLDISP
*GET, UX3, NODE, 11, U, X
*GET, UY3, NODE, 11, U, Y
*GET, ROT3A, NODE, 11, ROT, Z
SET, 4, 0
PLDISP
*GET, UX4, NODE, 11, U, X
*GET, UY4, NODE, 11, U, Y
*GET, ROT4A, NODE, 11, ROT, Z
SET, 5, 0
PLDISP
*GET, UX5, NODE, 11, U, X
*GET, UY5, NODE, 11, U, Y
*GET, ROT5A, NODE, 11, ROT, Z
SET, 6, 0
PLDISP
*GET, UX6, NODE, 11, U, X
*GET, UY6, NODE, 11, U, Y
*GET, ROT6A, NODE, 11, ROT, Z
*STATUS, PARM
FINISH