ex4.14.inp

ansys有限元分析程序

! 4.14  两端固定的厚壁管道在自重作用下的变形和应力
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）设置工程参数, 分析类型、单元类型、实常数和材料参数
/FILNAME, EX4.14
/PREP7
SMRT, OFF
/TITLE, EX4.14, BENDING OF AXISYMMETRIC THICK PIPE UNDER GRAVITY LOADING.
ANTYPE, STATIC
ET, 1, PLANE25, , , , , , 2
MP, EX, 1, 206.85E9
MP, DENS, 1, 7802
MP, NUXY, 1, 0
! (2)定义轴对称截面上的关键点和线
K, 1, 0.0127
K, 2, 0.0127, 2.54
KGEN, 2, 1, 2, 1, 0.0127
L, 1, 2
LESIZE, 1, , , 24
L, 2, 4
LESIZE, 2, , , 1
L, 3, 4
LESIZE, 3, , , 24
L, 1, 3
LESIZE, 4, , , 1
A, 3, 1, 2, 4
AMESH, 1
/VIEW, 1, 0, 0, 1
/VUP, 1, X
/ANGLE, 1, 0
EPLOT
! （3）定义重力加速度和位移约束条件
ACEL, 9.804, , -9.804
MODE, 1, 1
NSEL, S, LOC, Y, 0
D, ALL, ALL
NSEL, S, LOC, Y, 2.54
D, ALL, UY
NSEL, ALL
FINISH
! (4)在求解模块, 设置求解选项后求解
/SOLU
OUTPR, BASIC, LAST
SOLVE
FINISH
! (5)在后处理模块中显示第1个荷载步的0度位置的位移计算结果
/POST1
SET, 1, 1, , , , 0.0
/VUP, 1, X
/WINDOW, 1, -1.1, 2, 0, 2.5
! PLDISP, 1
PRNSOL, U, COMP
*GET, DEF_X, NODE, 3, U, X
NODE1=NODE(0.0254, 0.212, 0)
*GET, STRS_Y0, NODE, NODE1, S, Y
PLNSOL, S, Y
! (6)处理第1个荷载步的90度位置的计算结果
SET, 1, 1, , , , 90.0
/WINDOW, 1, OFF
/NOERASE
/WINDOW, 2, -1, 2, -2.5, 0
/VUP, 2, X
PLNSOL, S, Y
PRNSOL, U, COMP
*GET, DEF_Z, NODE, 3, U, Z
NODE1=NODE(0.0254, 0.212, 0)
*GET, STRS_Y90, NODE, NODE1, S, Y
*STATUS, PARM
FINISH