ex9.2.inp

ansys有限元分析程序

!9.2  用轴对称壳单元SHELL51计算压力容器
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
Finish
/Clear
/FileName, EX9.2
/Title, EX9.2, Long Cyclinder Pressure Vessel for CNG
! （1）定义基本参数
h1=298.5
b1=44.5
b2=b1+23
b12=b1/2+b2/2
r1=185
r2=203
r12=r1/2+r2/2
! （2）定义壳体中面上的关键点
/Prep7
k, 1, b12, h1
k, 2, b12, sqrt(r12*r12-b12*b12)
k, 3, r12, 0
k, 4, r12, -1000+h1
k, 5, 0, 0
! （3）定义壳体中面的线
L, 1, 2
L, 3, 4
Larc, 3, 2, 5, r12
LFILLT, 1, 3, 63/2+40/2, , 
SFL, 1, PRES, -23
SFL, 4, PRES, -23
SFL, 3, PRES, 23
SFL, 2, PRES, -23
! （4）定义单元类型、材料参数和实常数
ANTYPE, STATIC
ET, 1, SHELL51
MP, EX, 1, 206E3
MP, NUXY, 1, 0.3
! （5）定义实常数，将罐体中面线剖分为线单元
R, 1, 18
Lesize, all, 10
Lmesh, 2
Lmesh, 3
R, 2, 23
Real, 2
Lmesh, 1
Lmesh, 4
! （6）提取指定位置的节点，施加端部封头拉力和罐体内压
BottNode=Node(r12, -1000+h1, 0)
TopNode=Node(b12, h1, 0)
D, BottNode, UY, , , , , UZ, ROTZ
F, TopNode, FY, 143086
FINISH
! （7）在求解模块中，设置输出选项后求解
/SOLU
OUTPR, ALL, 1
SOLVE
FINISH
! （8）在后处理模块定义单元表，提取单元应力
/POST1
PLDISP, 2
ETABLE, SY_TOP, LS, 1
ETABLE, SY_MID, LS, 5
ETABLE, SY_BOT, LS, 9
ETABLE, SZ_TOP, LS, 3
ETABLE, SZ_MID, LS, 7
ETABLE, SZ_BOT, LS, 11
ETABLE, TX_TOP, SMISC, 13
ETABLE, TZ_TOP, SMISC, 14
ETABLE, MX_TOP, SMISC, 16
ETABLE, MZ_TOP, SMISC, 17
SADD, BendSY, SY_TOP, SY_BOT, 0.5, -0.5, , 
SADD, bendSZ, SZ_TOP, SZ_BOT, 0.5, -0.5, , 
pretab, SY_TOP, SY_MID, SY_BOT, SZ_TOP, SZ_MID, SZ_BOT
pretab, TX_TOP, TZ_TOP, MX_TOP, MZ_TOP, BENDSY, BENDSZ 
Finish