ex3.3.inp

来自「ansys有限元分析程序」· INP 代码 · 共 79 行

! 3.3  七层框架结构计算
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/Clear
/FILNAME, EX3.3
/TITLE, EX3.3, 7 FLOOR PLANE FRAME.
! （1）在前处理模块中定义节点和单元
/PREP7
N, 1, 0, 0
N, 2, 7.5, 0
N, 3, 15, 0
N, 4, 0, 4
N, 5, 7.5, 4
N, 6, 15, 4    $    N, 7, 0, 4+3.3    $    N, 8, 7.5, 4+3.3
N, 9, 15, 4+3.3    $    N, 10, 0, 4+3.3*2    $    N, 11, 7.5, 4+3.3*2
N, 12, 15, 4+3.3*2    $    N, 13, 0, 4+3.3*3    $    N, 14, 7.5, 4+3.3*3
N, 15, 15, 4+3.3*3    $    N, 16, 0, 4+3.3*4    $    N, 17, 7.5, 4+3.3*4
N, 18, 15, 4+3.3*4    $    N, 19, 0, 4+3.3*5    $    N, 20, 7.5, 4+3.3*5
N, 21, 15, 4+3.3*5    $    N, 22, 0, 4+3.3*6    $    N, 23, 7.5, 4+3.3*6
N, 24, 15, 4+3.3*6
ET, 1, beam3
R, 1, 0.25, 1/192, 0.5
R, 2, 0.3, 1/40, 1
MP, EX, 1, 5e7
MP, NUXY, 1, 0.3
MP, DENS, 1, 2.5
Acel, 0, 9.8, 0
E, 1, 4
E, 2, 5
E, 3, 6
E, 4, 7
E, 5, 8    $    E, 6, 9    $    E, 7, 10    $    E, 8, 11
E, 9, 12    $    E, 10, 13    $    E, 11, 14    $    E, 12, 15
E, 13, 16    $    E, 14, 17    $    E, 15, 18    $    E, 16, 19
E, 17, 20    $    E, 18, 21    $    E, 19, 22    $    E, 20, 23
E, 21, 24
Real, 2
E, 4, 5    $    E, 5, 6    $    E, 7, 8    $    E, 8, 9
E, 10, 11    $    E, 11, 12    $    E, 13, 14    $    E, 14, 15
E, 16, 17    $    E, 17, 18    $    E, 19, 20    $    E, 20, 21
E, 22, 23    $    E, 23, 24
! （2）定义位移约束条件和荷载
D, 1, ALL
D, 2, ALL
D, 3, ALL
! （3）定义节点荷载和分布荷载
F, 4, FX, 25
F, 7, FX, 50
F, 10, FX, 75
F, 13, FX, 100
F, 16, FX, 125
F, 19, FX, 150
F, 22, FX, 200
SFBEAM, 34, 1, PRESS, 40
SFBEAM, 35, 1, PRESS, 40
! （4）在求解模块求解
/SOLU
SOLVE
FINISH
! （5）在后处理模块显示计算结果
/POST1
PLDISP, 2
! （6）定义单元表显示内力计算结果
ETABLE, MFORX, SMISC, 1
PLETAB, MFORX
ETABLE, IMOMENT, SMISC, 6
ETABLE, JMOMENT, SMISC, 12
ETABLE, ISHEAR, SMISC, 2
ETABLE, JSHEAR, SMISC, 8
PRETAB
! （7）绘制结构内力图
/TITLE, SHEAR FORCE DIAGRAM
PLLS, ISHEAR, JSHEAR
/TITLE, BENDING MOMENT DIAGRAM
PLLS, IMOMENT, JMOMENT
FINISH