ex5.1.inp

ansys有限元分析程序

! 5.1  含椭圆孔的椭圆薄膜在外部张力作用下的静力分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）设置工程选项, 分析类型、单元类型和材料参数
/FILNAME, EX5.1(1)
/PREP7
SMRT, OFF
/TITLE, EX5.1(1), ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE42).
/COM, USING 2-D STRUCTURAL SOLID, PLANE42
ANTYPE, STATIC
ET, 1, PLANE42, , , 3
MP, EX, 1, 210E9
MP, NUXY, 1, 0.3
R, 1, 0.1
! （2）在椭圆坐标系下, 定义关键点、线和面
! LOCAL, KCN, KCS, XC, YC, ZC, THXY, THYZ, THZX, PAR1, PAR2
LOCAL, 11, 1, , , , , , , 0.5
K, 1, 2, 90
K, 2, 2, 0
L, 1, 2
LOCAL, 12, 1, , , , , , , 0.8461585
K, 3, 3.25, 90
K, 4, 3.25, 0
L, 3, 4
CSYS, 0
L, 2, 4
L, 1, 3
AL, 2, 4, 1, 3
! (3)在相应的线上施加位移约束
DL, 4, 1, SYMM
DL, 3, 1, SYMM
SFL, 2, PRES, -10E6
MSHK, 2
MSHA, 0, 2D
SAVE
FINISH
! (4)执行自适应网格剖分和求解宏程序, 执行自定义的后处理宏程序
ADAPT, 3, 7, , , 1
/Post1
EPLOT
PLDISP, 1
PLNSOL, S, X
PLNSOL, S, Y
PLNSOL, S, 1
FINISH
! (5)定义完成后处理功能的宏程序MAC
*CREATE, MAC
/Graphics, Full
/POST1
PRERR
NSEL, S, LOC, Y, 0.0
NSEL, R, LOC, X, 2.0
*GET, MNODE, NODE, , NUM, MAX
*GET, SY_D, NODE, MNODE, S, Y
NSEL, ALL
ESEL, ALL
*STATUS, PARM
/Graphics, Power
*END
! (6)用前定义的宏程序完成后处理, 将计算结果保存到变量
*USE, MAC
SAVE, TABLE1
FINISH
! (7)改变单元为PLANE82, 重新计算
/CLEAR, NOSTART
/FILNAME, EX5.1(2)
/PREP7
SMRT, OFF
RESUME, EX5.1(1).db
/TITLE, EX5.1(2), ELLIPTIC MEMBRANE UNDER A UNIFORMLY-DISTRIBUTED LOAD(PLANE82).
ET, 1, PLANE82, , , 3
FINISH
! （8）执行自适应网格宏程序, 执行自定义的后处理宏程序
ADAPT, 2, 5, , , 1
/Post1
/WINDOW, 5, OFF
/WINDOW, 1, FULL
PLNSOL, S, EQV
PLDISP, 1
PLNSOL, S, X
PLNSOL, S, Y
PLNSOL, S, 1
FINISH
! （9）用前定义的宏程序完成后处理, 将计算结果保存到变量
*USE, MAC
FINISH