ex3.2(2).inp

ansys有限元分析程序

! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/Clear
/FILNAME, EX3.2(2)
/TITLE, EX3.2(2), 4 SPANS CONTINUE BEAM BY GEOMETRIC MODELING.
/prep7
! （1）定义关键点和线
K, 1, 0, 0
K, 2, 4, 0    $    K, 3, 6, 0
K, 4, 8, 0    $    K, 5, 10, 0    $    K, 6, 16, 0
K, 7, 20, 0    $    K, 8, 22, 0
L, 1, 2
L, 2, 3    $    L, 3, 4    $    L, 4, 5
L, 5, 6    $    L, 6, 7    $    L, 7, 8
! （2）定义梁单元
ET, 1, Beam3
R, 1, 0.3, 0.003, 0.1
MP, EX, 1, 1000
MP, PRXY, 1, 0.3
ESize, , 10
LMESH, ALL
! （3）定义约束和荷载
AnType, 0
DK, 1, UX, 0, , , UY
DK, 2, UY, 0, 
DK, 5, UY, 0, 
DK, 6, UY, 0, 
DK, 7, UY, 0, 
FK, 3, FY, -30
FK, 4, FY, -30
FK, 8, FY, -20
SFBEAM, 41, 1, PRESS, 20
SFBEAM, 42, 1, PRESS, 20
SFBEAM, 43, 1, PRESS, 20
SFBEAM, 44, 1, PRESS, 20
SFBEAM, 45, 1, PRESS, 20
SFBEAM, 46, 1, PRESS, 20
SFBEAM, 47, 1, PRESS, 20
SFBEAM, 48, 1, PRESS, 20
SFBEAM, 49, 1, PRESS, 20
SFBEAM, 50, 1, PRESS, 20
FINISH
! （4）在求解模块求解
/SOLU
Solve
FINISH
! （5）在后处理模块显示变形图，提取并显示结果
/POST1
PLDISP, 2
PrDisp
! （6）定义以两端弯矩和剪力为内容的单元表，并列出单元的单元表数据
ETABLE, IMOMENT, SMISC, 6
ETABLE, JMOMENT, SMISC, 12
ETABLE, ISHEAR, SMISC, 2
ETABLE, JSHEAR, SMISC, 8
PRETAB
! （7）用单元表数据绘制剪力图和弯矩图
/TITLE, SHEAR FORCE DIAGRAM
PLLS, ISHEAR, JSHEAR
/TITLE, BENDING MOMENT DIAGRAM
PLLS, IMOMENT, JMOMENT
FINISH