ex5.10(1).inp

ansys有限元分析程序

! 5.10  圆筒在一对横向集中力作用下的变形
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）设置工程选项、分析类型、实常数、材料参数
/FILNAME, EX5.10(1)
/PREP7
SMRT, OFF
/TITLE, EX5.10(1), PINCHED CYLINDER UNDER CONCENTRATED FORCE.
ANTYPE, STATIC
ET, 1, SHELL93
R, , 2.3876
MP, EX, , 72.4E3
MP, NUXY, , 0.3125
! （2）在柱坐标系下定义关键点、柱面并对其进行单元剖分
CSYS, 1
K, 1, 125.8
K, 2, 125.8, , 131.5
KGEN, 2, 1, 2, 1, , 90
A, 1, 2, 4, 3
ESIZE, , 8
/View, 1, 1, 1, 1
AMESH, 1
! (3)在直角坐标系下定义约束
CSYS, 0
NSEL, S, LOC, X, 0
DSYM, SYMM, X, 0
NSEL, S, LOC, Y, 0
DSYM, SYMM, Y, 0
NSEL, S, LOC, Z, 0
DSYM, SYMM, Z, 0
NSEL, ALL
FK, 3, FY, -111.2
FINISH
! (4)在求解模块求解
/SOLU
SOLVE
FINISH
! (5)在后处理模块显示节点位移计算结果
/POST1
NSEL, S, LOC, Y, 125.8
NSEL, R, LOC, Z, 0
NSEL, R, LOC, X, 0
PRNSOL, U, COMP
TOP_NODE = NODE(125.8, 90, 0)
*GET, DISP, NODE, TOP_NODE, U, Y
! （6）将计算结果保存到文件
SAVE, TABLE_1
FINISH
! (7)改变单元重新计算
/CLEAR, NOSTART
/FILNAME, EX5.10(2)
/PREP7
/TITLE, EX5.10(2), PINCHED CYLINDER UNDER CONCENTRATED FORCE(SHELL150).
SMRT, OFF
ANTYPE, STATIC
ET, 1, SHELL150
R, , 2.3876
MP, EX, , 72.4E3
MP, NUXY, , 0.3125
! （8）在柱坐标系下定义关键点, 柱面并对其进行单元剖分
CSYS, 1
K, 1, 125.8
K, 2, 125.8, , 131.5
KGEN, 2, 1, 2, 1, , 90
A, 1, 2, 4, 3
ESIZE, , 8
/View, 1, 1, 1, 1
AMESH, 1
! （9）在直角坐标系下定义约束
CSYS, 0
NSEL, S, LOC, X, 0
DSYM, SYMM, X, 0
NSEL, S, LOC, Y, 0
DSYM, SYMM, Y, 0
NSEL, S, LOC, Z, 0
DSYM, SYMM, Z, 0
NSEL, ALL
FK, 3, FY, -111.2
FINISH
! (10) 在求解模块求解
/SOLU
SOLVE
FINISH
! (11) 在后处理模块显示节点位移计算结果
/POST1
SET, 1
NSEL, S, LOC, Y, 125.8
NSEL, R, LOC, Z, 0
NSEL, R, LOC, X, 0
PRNSOL, U, COMP
TOP_NODE = NODE(125.8, 90, 0)
*GET, DISP, NODE, TOP_NODE, U, Y
*STATUS, PARM
Resume, Table_1
*STATUS, PARM
FINISH