ex3.14.inp

ansys有限元分析程序

! 3.14  自行车车架变形和内力分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/Clear
/FILNAME, EX3.14
/TITLE, EX3.14, 3D Bicycle Space Frame.
! （1）进入前处理模块, 定义基本参数
/PREP7
x1 = 500  $  x2 = 825
y1 = 325  $  y2 = 400  $  z1 = 50
/Pnum, KP, 1
/Pnum, Line, 1
/VIEW, 1, 1, 2, 3
! （2）定义关键点
K, 1, 0, y1, 0
K, 2, 0, y2, 0  $  K, 3, x1, y2, 0  $  K, 4, x1, 0, 0
K, 5, x2, 0, z1    $  K, 6, x2, 0, -z1
! （3）过关键点定义线
L, 1, 2
L, 2, 3
L, 3, 4
L, 4, 1
L, 4, 6  $  L, 4, 5
L, 3, 5  $  L, 3, 6
! （4）定义单元类型和实常数
ET, 1, PIPE16
KEYOPT, 1, 6, 1
! 定义实常数
R, 1, 25, 2
R, 2, 12, 1
! （5） 定义材料参数
MP, EX, 1, 70000
MP, PRXY, 1, 0.33
! （6）定义单元尺寸后剖分单元
LESIZE, ALL, 50
! 开始剖分线单元
REAL, 1
LMESH, 1, 6, 1
REAL, 2
LMESH, 7, 8
/EShape, 1
Eplot
FINISH
! （7）进入求解模块后指定位移约束和荷载，并开始求解
/SOLU
ANTYPE, 0
! 在关键点上施加位移约束(用dk命令)
DK, 1, UX, 0, , , UY, UZ
DK, 5, UY, 0, , , UZ
DK, 6, UY, 0, , , UZ
! 在关键点上定义荷载 (用fk命令)
FK, 3, FY, -600
FK, 4, FY, -200
SOLVE
FINISH
! （8）定义单元表提取计算结果
/post1
! 命令格式：ETable, 单元表名称，数据项名称，数据编号
ETable, vonmi0, nmisc, 5
ETable, vonmj0, nmisc, 45
! 0度位置的轴向力
ETable, axii0, ls, 1
ETable, axij0, ls, 33
! 轴力引起的轴向应力(不含弯曲引起的应力)
ETable, diri, smisc, 13
ETable, dirj, smisc, 15
! （9）在多个窗口中同时显示多种结果
/WIND, ALL, OFF
/WIND, 1, LTOP
/WIND, 2, RTOP
/WIND, 3, LBOT
/WIND, 4, RBOT
GPLOT
/GCMD, 1, PLDISP, 2
/GCMD, 2, PLNSOL, U, SUM, 0, 1
! 用图形显示单元内力分布：PLLS, i端内力名称, j端内力名称
/GCMD, 3, PLLS, vonmi0, vonmj0
/GCMD, 4, PLLS, axii0, axij0
GPLOT
/CONT, 2, 9, 0, , 0.27
/CONT, 3, 9, 0, , 18
/CONT, 4, 9, -18, , 18
/FOCUS, ALL, -0.34, , , 1
/Replot
PRNSOL, DOF
FINISH