ex8.2(2).inp

ansys有限元分析程序

! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!．ANSYS三维分析程序
FINISH
/CLEAR, NOSTART
! （1）定义工程选项、分析类型、单元类型、材料参数和实常数
/FILNAME, EX8.2(2)
/PREP7
/TITLE, EX8.2(2), NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE.
ANTYPE, STATIC
ET, 1, SHELL41, , 1
MP, EX, 1, 207E9
MP, NUXY, 1, 0
MP, ALPX, 1, 5.5556E-6
MP, DENS, 1, 7801.6
R, 1, 1.27e-6
! （2）定义节点和单元
CSYS, 1
N, 1, .0001
N, 10, 76.2e-3
FILL
NGEN, 4, 10, 1, 10, 1, , 10
NROTAT, ALL
E, 1, 2, 12, 11
EGEN, 3, 10, -1
EGEN, 9, 1, -3
! （3）选择节点, 施加位移边界条件
NSEL, S, LOC, Y, 0
! 定义用于循环对称分析的边界部件
CM, RIGHT, NODE
NSEL, S, LOC, Y, 30
CM, LEFT, NODE
NSEL, ALL
/NOPR
CYCLIC
/GOPR
D, ALL, ALL, 0
TREF, 0
BFUNIF, TEMP, -12
FINISH
! （4）进入求解模块, 打开预应力选项并开始求解静力分析
/SOLU
PSTRES, ON
SOLVE
FINISH
! （5）再次进入前处理模块, 进行模态分析
/PREP7
/TITLE, EX8-2(2), NONAXISYM. VIBR. OF A STRETCHED CIRCULAR MEMBRANE (MODAL)
ANTYPE, MODAL
MODOPT, LANB, 4, 1, 1000
MXPAND, 4
PSTRES, ON
! （6）修改位移边界条件
DDEL, ALL, ALL
NSEL, S, LOC, Y, 0
NSEL, A, LOC, Y, 30
D, ALL, UX, , , , , UY
NSEL, S, LOC, X, 76.2e-3
D, ALL, ALL, 0
NSEL, ALL
/REPLOT
FINISH
! （7）在求解模块, 进行轴对称问题的求解
/SOLU
/OUTPUT, SCRATCH
CYCSOL, 0, 1, 12, 'RIGHT'
/OUTPUT
FINISH
! （8）在一般后处理模块, 处理频率计算结果
/POST1
SET, 1, 1
*GET, F01_1, ACTIVE, , SET, FREQ
SET, 1, 2
*GET, F02_1, ACTIVE, , SET, FREQ
SET, 2, 1
*GET, F11_1, ACTIVE, , SET, FREQ
SET, 2, 2
*GET, F11_2, ACTIVE, , SET, FREQ
SET, 2, 3
*GET, F12_1, ACTIVE, , SET, FREQ
SET, 2, 4
*GET, F12_2, ACTIVE, , SET, FREQ
*STATUS, PARM
FINISH
! （9）处理和显示模态
/NOPR
/POST1
EXPAND, 12
/VIEW, , 1, 1, 1
/VUP, 1, Z
/GLINE, , -1
/TRIAD, OFF
SET, 1, 2
/TITLE, EX8_2(2), STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 0, MODE 2
PLNSOL, U, Z
SET, 2, 2
/TITLE, EX8_2(2), STRETCHED CIRCULAR MEMBRANE - NODAL DIAM 1, MODE 2
PLNSOL, U, Z
FINISH