ex5.5.inp

ansys有限元分析程序

! 5.5  简支和固支圆板的在不同荷载作用下的弯曲
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）设置工程参数、分析类型、单元类型、实常数和材料参数
/FILNAME, EX5.5
/PREP7
/TITLE, EX5.5, BENDING OF A CIRCULAR PLATE USING AXISYMMETRIC SHELL ELEMENTS.
ANTYPE, STATIC
ET, 1, SHELL51
R, 1, 25.4
MP, EX, 1, 207E3
MP, NUXY, 1, 0.3
! （2）定义关键点、线和面, 并剖分为面单元
K, 1
K, 2, 1016
K, 3, 508
L, 1, 3
L, 3, 2
LESIZE, 1, , , 5, 20
LESIZE, 2, , , 5, .05
LMESH, ALL
/PNUM, ELEM, 1
EPLOT
FINISH
! (3)按第1种情况计算:均布荷载、固支端
/SOLU
OUTPR, , 1
DK, 1, UX, , , , ROTZ
DK, 2, ALL
SFE, ALL, 1, PRES, , 0.041370
SOLVE
! (4)按第2种情况计算:中心集中荷载、固支边
FK, 1, FY, 33539
SFE, ALL, 1, PRES, , 0
SOLVE
! （5）按第3种情况计算:均布荷载、简支边
DKDELE, 2, ROTZ
FK, 1, FY
SFE, ALL, 1, PRES, , 0.010343
SOLVE
FINISH
! (6)在后处理模块中显示变形情况
/POST1
/DSCALE, 1, 35
/WINDOW, 1, -1, 1, -1, -.333
SET, 1, 1
PLDISP, 1
MID_NODE = NODE (0, 0, 0)
*GET, DEF_C1, NODE, MID_NODE, U, Y
ETABLE, STRS, LS, 9
*GET, STRSS_C1, ELEM, 10, ETAB, STRS
! (7)读入第2荷载步的计算结果, 显示变形图
/WINDOW, 1, OFF
/WINDOW, 2, -1, 1, -.333, .333, 1
/NOERASE
SET, 2, 1
PLDISP
*GET, DEF_C2, NODE, MID_NODE, U, Y
ETABLE, STRS, LS, 9
*GET, STRSS_C2, ELEM, 10, ETAB, STRS
! （8）读入第3荷载步的计算结果, 显示变形图
/WINDOW, 2, OFF
/WINDOW, 3, -1, 1, 0.333, 1, 1
SET, 3, 1
PLDISP
*GET, DEF_C3, NODE, MID_NODE, U, Y
ETABLE, STRS, LS, 9
*GET, STRSS_C3, ELEM, 1, ETAB, STRS
*STATUS, PARM
FINISH