ex3.1(2).inp

ansys有限元分析程序

! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!．增加节点后的ANSYS程序
! （1）设置工程选项
FINISH
/CLEAR
/FILNAME, EX3.1(2)
/UNITS, CGS
/TITLE, EX3.1(2), SIMULATION OF OVER-DETERMINED BEAM WITH MORE NODES.
! （2）在前处理模块中，定义节点
/PREP7
N, 1, 0, 0
N, 2, 0.06, 0     $   N, 3, 0.12, 0    $   N, 4, 0.18, 0
N, 5, 0.24, 0   $   N, 6, 0.30, 0        $   N, 7, 0.36, 0
N, 8, 0.42, 0        $   N, 9, 0.48, 0   $   N, 10, 0.54, 0
N, 11, 0.60, 0
NPLOT
NPLOT, 1
NLIST
DSYS, 1
NLIST
! （3）设置单元选项，定义单元
ET, 1, BEAM3
MP, EX, 1, 207e9
MP, NUXY, 1, 0.3
R, 1, 0.001, 0.020833, 0.05
E, 1, 2
E, 2, 3   $   E, 3, 4   $   E, 4, 5   $   E, 5, 6
E, 6, 7   $   E, 7, 8   $   E, 8, 9   $   E, 9, 10
E, 10, 11
EPLOT
ELIST
FINISH
! （4）进入求解模块，定义求解选项、位移边界条件和荷载，并求解
/SOLU
ANTYPE, STATIC
OUTPR, BASIC, ALL
D, 1, UX, 0, , , , , UY, ROTZ
D, 11, UY, 0
SFBEAM, 1, 1, PRES, 0, 60
SFBEAM, 2, 1, PRES, 60, 120   $   SFBEAM, 3, 1, PRES, 120, 180
SFBEAM, 4, 1, PRES, 180, 240   $   SFBEAM, 5, 1, PRES, 240, 300
SFBEAM, 6, 1, PRES, 300, 360   $   SFBEAM, 7, 1, PRES, 360, 420
SFBEAM, 8, 1, PRES, 420, 480   $   SFBEAM, 9, 1, PRES, 480, 540
SFBEAM, 10, 1, PRES, 540, 600
F, 6, FY, -200
SOLVE
FINISH
! （5）在后处理模块中，图形显示变形情况
/POST1
PRDISP
! （6）定义以两端弯矩和剪力为内容的单元表，并列出单元的单元表数据
ETABLE, IMOMENT, SMISC, 6
ETABLE, JMOMENT, SMISC, 12
ETABLE, ISHEAR, SMISC, 2
ETABLE, JSHEAR, SMISC, 8
PRETAB
! （7）用单元表数据绘制剪力图
/TITLE, SHEAR FORCE DIAGRAM
PLLS, ISHEAR, JSHEAR
! （8）用单元表数据绘制弯矩图
/TITLE, BENDING MOMENT DIAGRAM
PLLS, IMOMENT, JMOMENT
FINISH