ex3.7.inp

ansys有限元分析程序

! 3.7  悬臂梁的双向弯曲
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
Finish
/CLEAR, START
/FILNAME, EX3.7
/PREP7
/TITLE, EX3.7(1), STRAIGHT CANTILEVER BEAM BY SOLID5 ELEMENT.
! （1）利用六面体单元SOLID5计算悬臂梁的组合变形
ANTYPE, STATIC
ET, 1, SOLID5, 2
MP, EX, 1, 69E3
MP, NUXY, 1, 0.3
! （2）定义悬臂梁上的8个的关键点
K, 1
K, 2, 152.4
KGEN, 2, 1, 2, 1, , 5.08
KGEN, 2, 1, 4, 1, , , 2.54
! 上面两行命令完成了节点3到4的定义和节点5到8的位置定义
! （3）定义一条边线，指定这条线剖分单元的个数和一般单元的尺寸
L, 1, 2
SMRT, OFF
LESIZE, ALL, , , 10
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! （4）选择左侧截面处的所有节点，并固定这些节点。在右侧的所有节点上施加集中力
NSEL, S, LOC, X, 0
D, ALL, ALL
NSEL, ALL
FK, 2, FX, 4.4483/4
*REPEAT, 4, 2
NOORDER
FINISH
! （5）求解在自由端拉力作用下悬臂梁的变形
/SOLU
SOLVE
! （6）改变荷载，计算在Y方向的集中力作用下的情形
FKDELE, ALL, FX
FK, 2, FY, 4.4483/4
*REPEAT, 4, 2
SOLVE
! （7）改变荷载，计算在Z方向的集中力作用下的情形
FKDELE, ALL, FY
FK, 2, FZ, 4.4483/4
*REPEAT, 4, 2
SOLVE
FINISH
! （8）进入一般后处理模块
/POST1
CSYS, 0
! （9）定义宏程序，完成自由端位移结果的处理
*CREATE, MAC
SET, ARG1, 1
LCDEF, ARG1, ARG1
NSEL, S, LOC, X, 152.4
PRNSOL, U, COMP
LCFACT, ARG1, ARG2
LCASE, ARG1
PRNSOL, U, COMP
*END
! (10) 使用上面定义的宏程序处理第一个荷载工况
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX1, NODE, N1, U, X
! (11) 处理第2个荷载步的计算结果
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY1, NODE, N1, U, Y
! (12) 处理第3个荷载步的计算结果
*USE, MAC, 3, (1/10.9646)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ1, NODE, N1, U, Z
! (13) 将第一种情况的计算结果保存到数据库
SAVE, TABLE_1
FINISH
! (14) 改变单元类型，重新分析矩形截面悬臂梁在端部集中力作用下的变形
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(2), STRAIGHT CANTILEVER BEAM by SOLID92 ELEMENT.
SMRT, OFF
MOPT, VMESH, MAIN
MOPT, AMESH, ALTE
! (15) 使用10节点四面体单元SOLID92
ANTYPE, STATIC
ET, 1, SOLID92
MP, EX, 1, 69E3
MP, PRXY, 1, 0.3
K, 1
K, 2, , 5.08
KGEN, 2, 1, 2, 1, , , 2.54
KGEN, 2, 1, 4, 1, 152.4/9
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! (16) 利用第1块体的单元模式，生成其余的8部分单元，定义固定端部的约束
VGEN, 9, 1, 1, 1, 152.4/9, , , 4
NSEL, S, LOC, X, 0
D, ALL, ALL
SAVE
! (17) 获取相应节点的编号，并在这些节点上施加荷载
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 1.27
*GET, MIDD, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 5.08
NSEL, R, LOC, Z, 1.27
*GET, TOPP, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 0.0
NSEL, R, LOC, Z, 1.27
*GET, BOTT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 2.54
*GET, LFT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, .00
*GET, RGHT, NDMX
NSEL, ALL
! (18) 给上面选择出的这些节点施加沿着X方向的轴向荷载
F, RGHT, FX, 4.4483/6
F, LFT, FX, 4.4483/6
F, TOPP, FX, 4.4483/6
F, BOTT, FX, 4.4483/6
F, MIDD, FX, 4.4483/3
FINISH
! (19) 进入求解模块开始计算
/SOLU
SOLVE
! (20) 改变荷载，给上面选择出的这些节点施加沿着Y方向的轴向荷载，重新计算
FDELE, ALL
F, RGHT, FY, 4.4483/6
F, LFT, FY, 4.4483/6
F, TOPP, FY, 4.4483/6
F, BOTT, FY, 4.4483/6
F, MIDD, FY, 4.4483/3
SOLVE
! (21) 改变荷载，给上面选择出的这些节点施加沿着Z方向的轴向荷载，重新计算
FDELE, ALL
F, RGHT, FZ, 4.4483/6
F, LFT, FZ, 4.4483/6
F, TOPP, FZ, 4.4483/6
F, BOTT, FZ, 4.4483/6
F, MIDD, FZ, 4.4483/3
SOLVE
FINISH
! (22) 利用前面定义的宏，处理前面计算的3种荷载工况的位移
/POST1
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX2, NODE, N1, U, X
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY2, NODE, N1, U, Y
*USE, MAC, 3, (1/.432)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ2, NODE, N1, U, Z
! (23) 将第二种情况的计算结果保存到数据库
SAVE, TABLE_2
FINISH
! (24) 改变为10节点四面体耦合场单元SOLID98，重新计算悬臂梁在端部集中力作用下的双向弯曲
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(3), STRAIGHT CANTILEVER BEAM by SOLID98 ELEMENT.
SMRT, OFF
MOPT, VMESH, MAIN
MOPT, AMESH, ALTE
RESUME
ET, 1, SOLID98, 2
! (25) 选择自由端有荷载的节点
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 1.27
*GET, MIDD, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 5.08
NSEL, R, LOC, Z, 1.27
*GET, TOPP, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 0.0
NSEL, R, LOC, Z, 1.27
*GET, BOTT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, 2.54
*GET, LFT, NDMX
!
NSEL, S, LOC, X, 152.4
NSEL, R, LOC, Y, 2.54
NSEL, R, LOC, Z, .00
*GET, RGHT, NDMX
NSEL, ALL
! (26) 给上面选择出的这些节点施加沿着X方向的轴向荷载，开始计算
F, RGHT, FX, 4.4483/6
F, LFT, FX, 4.4483/6
F, TOPP, FX, 4.4483/6
F, BOTT, FX, 4.4483/6
F, MIDD, FX, 4.4483/3
FINISH
/SOLU
SOLVE
! (27) 改变荷载，给上面选择出的这些节点施加沿着Y方向的轴向荷载，重新计算
FDELE, ALL
F, RGHT, FY, 4.4483/6
F, LFT, FY, 4.4483/6
F, TOPP, FY, 4.4483/6
F, BOTT, FY, 4.4483/6
F, MIDD, FY, 4.4483/3
SOLVE
! (28) 改变荷载，给上面选择出的这些节点施加沿着Z方向的轴向荷载，重新计算
FDELE, ALL
F, RGHT, FZ, 4.4483/6
F, LFT, FZ, 4.4483/6
F, TOPP, FZ, 4.4483/6
F, BOTT, FZ, 4.4483/6
F, MIDD, FZ, 4.4483/3
SOLVE
FINISH
! (29) 在后处理模块中，利用前面定义的宏，处理前面计算的3种荷载工况的位移
/POST1
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX3, NODE, N1, U, X
!
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY3, NODE, N1, U, Y
!
*USE, MAC, 3, (1/.432)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ3, NODE, N1, U, Z
! (30) 将第三种情况的计算结果保存到数据库
SAVE, TABLE_3
FINISH
!
! (31) 改变为20节点四面体3D单元SOLID147，重新计算悬臂梁在端部集中力作用下的双向弯曲
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.7(4), STRAIGHT CANTILEVER BEAM by SOLID147 ELEMENT.
SMRT, OFF
MOPT, VMESH, ALTE
MOPT, AMESH, ALTE
ANTYPE, STATIC
ET, 1, SOLID147
MP, EX, 1, 69E3
MP, NUXY, 1, 0.3
! (32) 定义梁上的8个关键点
K, 1
K, 2, 152.4
KGEN, 2, 1, 2, 1, , 5.08
KGEN, 2, 1, 4, 1, , , 2.54
! (33) 定义一条边线，指定这条线剖分单元的个数和一般单元的尺寸
L, 1, 2
LESIZE, ALL, , , 10
ESIZE, 25.4
V, 1, 2, 4, 3, 5, 6, 8, 7
VMESH, 1
! (34) 选择并固定左侧截面处的所有节点，在右侧的所有节点上施加集中力
NSEL, S, LOC, X, 0
D, ALL, ALL
NSEL, ALL
FK, 2, FX, 4.4483/4
*REPEAT, 4, 2
NOORDER
FINISH
! (35) 分别求解在自由端拉力和横向力作用下悬臂梁的轴向变形和横向挠度。
/SOLU
SOLVE
!
FKDELE, ALL, FX
FK, 2, FY, 1.1121
*REPEAT, 4, 2
SOLVE
!
FKDELE, ALL, FY
FK, 2, FZ, 1.1121
*REPEAT, 4, 2
SOLVE
FINISH
! (36) 进入后处理模块，准备提取有限元结果
/POST1
CSYS, 0
! (37) 定义宏程序，完成自由端位移计算结果的处理
*CREATE, MAC
SET, ARG1, 1
LCDEF, ARG1, ARG1
NSEL, S, LOC, X, 152.4
PRNSOL, U, COMP
LCFACT, ARG1, ARG2
LCASE, ARG1
PRNSOL, U, COMP
*END
! (38) 使用上面定义的宏程序处理第1个工况
*USE, MAC, 1, (1/7.6E-4)
SET, 1, 1
LCSEL, S, 0, 0
N1=NODE(152.4, 0, 0)
*GET, UX4, NODE, N1, U, X
! (39) 提取第二步结果
*USE, MAC, 2, (1/2.4712)
SET, 2, 1
LCSEL, S, 0, 0
*GET, UY4, NODE, N1, U, Y
! (40) 提取第3步结果
*USE, MAC, 3, (1/10.9646)
SET, 3, 1
LCSEL, S, 0, 0
*GET, UZ4, NODE, N1, U, Z
! (41) 将第四种情况的计算结果保存到数据库
SAVE, TABLE_4
! (42) 从第1个表中恢复数据，绘制单元应力云图
RESUME, TABLE_1
NSEL, ALL
/VIEW, 1, 2, 1, 1
EPLOT
/TYPE, 1, CAP
/DIST, 1, 5.08
/FOCUS, 1, .3, .15, .09
/Auto
PLNSOL, S, X
*STATUS, PARM
! (43) 从结果文件中读入计算结果，并显示
RESUME, TABLE_2
*STATUS, PARM
RESUME, TABLE_3
*STATUS, PARM
RESUME, TABLE_4
*STATUS, PARM
! (44) 删除宏文件，临时文件TABLE_*
/DELETE, MAC
/DELETE, TABLE_1
/DELETE, TABLE_2
/DELETE, TABLE_3
/DELETE, TABLE_4
FINISH