ex8.2(1).inp

ansys有限元分析程序

! 8.2  薄膜二维和三维非轴对称自由振动
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!．ANSYS二维分析程序
FINISH
/CLEAR, NOSTART
! （1）定义工程选项、分析类型、单元类型、材料参数和实常数
/FILNAME, EX8.2(1)
/PREP7
/TITLE, EX8.2(1), NONAXISYMMTRIC VIBRATION OF A STRETCHED CIRCULAR MEMBRANE.
ET, 1, SHELL61
R, 1, 1.27e-6
MP, EX, 1, 207E9
MP, NUXY, 1, 0
MP, ALPX, 1, 5.5556E-6
MP, DENS, 1, 7801.6
! （2）通过关键点的定义, 建立模型
K, 1
K, 2, 76.2e-3
L, 1, 2
LESIZE, 1, , , 9
LMESH, 1
! （3）选择边界节点, 施加位移约束
NSEL, S, LOC, X, 0
D, ALL, UX
NSEL, S, LOC, X, 76.2e-3
D, ALL, UX, , , , , UY
NSEL, ALL
M, ALL, UY
D, ALL, UZ
TREF, 0
BFUNIF, TEMP, -12
FINISH
! （4）进入求解模块, 开始求解
/SOLU
ANTYPE, STATIC
PSTRES, ON
OUTPR, BASIC, ALL
SOLVE
FINISH
! （5）重新进入求解模块, 进行模态分析
/SOLU
ANTYPE, MODAL
PSTRES, ON
MXPAND, 3
MODOPT, REDUC
MODE, 0
SOLVE
FINISH
! （6）在一般后处理模块, 图线显示模态
/POST1
/WINDOW, 1, LTOP
SET, 1, 1
PLDISP, 1
/NOERASE
*GET, F11, MODE, 0, FREQ
/WINDOW, 1, OFF
/WINDOW, 4, RBOT
SET, 1, 2
PLDISP, 1
*GET, F12, MODE, 2, FREQ
/WINDOW, 4, OFF
FINISH
! （7）重新进入求解模态, 求解第1阶谐波模态
/SOLU
MODE, 1
SOLVE
FINISH
/POST1
/WINDOW, 2, RTOP
SET, 1, 1
PLDISP, 1
*GET, F21, MODE, 0, FREQ
/WINDOW, 2, OFF
FINISH
! （8）重新进入求解模态, 求解第1阶谐波模态
/SOLU
MODE, 2
SOLVE
FINISH
! （9）在一般后处理模块, 图线显示谐波模态
/POST1
/WINDOW, 3, LBOT
SET, 1, 1
PLDISP, 1
*GET, F31, MODE, 0, FREQ
*STATUS, PARM
FINISH