ex3.12.inp

ansys有限元分析程序

! 3.12  带有弹簧的支架的大变形分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/Clear
/FILNAME, EX3.12
/TITLE, EX3.12, LARGE DEFLECTION ANALYSIS OF A JOINT FRAME WITH SPRINGS.
/PREP7
! （1）定义节点
N, 1, 0, 0, 0    $    N, 2, 0, 0, 1000    $    N, 3, 1000, 0, 1000
N, 4, 1000, 0, 0    $    N, 5, 0, 1000, 1000    $    N, 6, 0, 1000, 0
N, 7, 700, 700, 500    $    N, 8, 400, 400, 500    $    N, 9, 0, 0, 0
N, 10, 0, 0, 1000    $    N, 11, 0, 0, 500    $    N, 12, 0, 0, 1500
N, 13, 0, 0, -500
! （2）定义单元
ET, 1, PIPE16
ET, 2, COMBIN7
ET, 3, COMBIN14
R, 1, 40, 10
R, 2, 1e8, 1e8, 1e8
R, 3, 5
MP, EX, 1, 200000
MP, PRXY, 1, 0.3
! 定义管单元
Mat, 1
Real, 1
Type, 1
E, 1, 6    $    E, 2, 5    $    E, 1, 4    $    E, 2, 3
E, 3, 4    $    E, 10, 8    $    E, 9, 8    $    E, 7, 8    $
E, 12, 5    $    E, 13, 6    $    E, 5, 3    $    E, 6, 4
E, 12, 2    $    E, 2, 1    $    E, 1, 13
! 定义铰接点单元
Real, 2
Type, 2
E, 1, 9, 11
E, 2, 10, 11
! 定义弹簧单元
Real, 3
Type, 3
E, 5, 7
E, 7, 6
Elist
/PNum, Elem, 1
Eplot
! （3）定义约束和荷载
D, 3, ALL
D, 4, ALL
D, 12, ALL
D, 13, ALL
F, 7, FY, -3000
FINISH
! （4）在求解模块求解
/SOLU
AnType, 0
NLGeom, ON
Nsubst, 10
Solve
FINISH
! （5）在后处理模块显示变形图，提取并显示结果
/POST1
PLDISP, 2
*GET, VERT7, NODE, 7, U, Y
*STATUS, PARM, 
FINISH