ex3.9.inp

ansys有限元分析程序

! 3.9  悬臂等强度梁的弯曲
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
/FILNAME, EX3.9
! （1）定义工程选项，分析类型为静力（STATIC）分析，单元类型和实常数，材料参数等
/PREP7
/TITLE, EX3.9(1), BENDING OF A TAPERED PLATE (BEAM) WITH SHELL63 ELEMENT.
ANTYPE, STATIC
ET, 1, SHELL63, 2
R, 1, 12.7
MP, EX, 1, 207E3
MP, NUXY, 1, 0
! （2）通过节点和单元建模
N, 1
N, 8, 508, -38.1
FILL
N, 11
N, 18, 508, 38.1
FILL
E, 1, 2, 12
E, 2, 3, 12
E, 13, 12, 3
E, 3, 4, 14
E, 14, 13, 3
EGEN, 3, 2, 2, 5
! （3）定义耦合自由度，以保证变形对称
CP, 1, UZ, 2, 12
CP, 2, ROTY, 2, 12
CPSGEN, 6, 1, 1, 2
OUTPR, ALL, ALL
D, 8, ALL, , , 18, 10
D, ALL, ROTX, 0
F, 1, FZ, -44.483
FINISH
! （4）进入求解模块，开始求解
/SOLU
SOLVE
FINISH
! （5）进入一般后处理模块，绘制变形图定义单元表，提取应力结果和节点位移
/POST1
/VIEW, 1, 1, 1, 1
PLDISP, 2
ETABLE, STRS, S, 1
ESORT, STRS
*GET, SMAX1, SORT, , MAX
PRNSOL, DOF
LFT_NODE = NODE(0, 0, 0)
*GET, DEFL1, NODE, LFT_NODE, U, Z
*STATUS, PARM
! （6）将计算结果保存到数据库
SAVE, TABLE_1
FINISH
! （7）改为三维梁单元BEAM44，重新计算
/CLEAR, NOSTART
/PREP7
/TITLE, EX3.9(2), BENDING OF A TAPERED PLATE WITH TAPERED BEAM ELEMENT BEAM44.
! （8）定义分析类型，单元类型和实常数
ANTYPE, STATIC
ET, 1, BEAM44
*DO, I, 1, 10
  R, I, 1, 1, (I-1)*76.2*12.7*12.7*12.7/120, 6.35, 1
  RMORE, 1, 1, I*76.2*12.7*12.7*12.7/120, 6.35, 1
*ENDDO
RMOD, 1, 3, 76.2*12.7*12.7*12.7/120/2
RLIST
MP, EX, 1, 207E3
MP, GXY, 1, 207E3/2.6
! （9）定义节点位置
N, 1
N, 11, 508
FILL
N, 12, , , 10
NGEN, 10, 1, 12
! (10) 定义梁单元
E, 1, 2, 12
EGEN, 10, 1, 1, , , , , 1
! (11) 施加位移约束条件
D, 11, ALL
D, 1, UY, , , 10, , ROTX, ROTZ
F, 1, FZ, -44.483
OUTPR, ALL, ALL
FINISH
! (12) 在求解模块中求解
/SOLU
SOLVE
FINISH
! (13) 在后处理模块中，绘制变形图，定义单元表，提取应力计算结果
/POST1
/VIEW, 1, 1, 1, 1
PLDISP, 2
ETABLE, STRS, NMISC, 1
ESORT, STRS
*GET, SMAX2, SORT, , MAX
PRNSOL, DOF
LFT_NODE = NODE (0, 0, 0)
*GET, DEFL2, NODE, LFT_NODE, U, Z
SAVE, TABLE_2
! (14) 从数据库中恢复数据，并显示前后两次的计算结果
RESUME, TABLE_1
*STATUS, PARM
RESUME, TABLE_2
*STATUS, PARM
FINISH