ex7.10.inp

ansys有限元分析程序

! 7.10  矩形截面薄壁悬臂梁的自由振动
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! （1）定义工程选项、单元类型、材料参数和实常数
/FILNAME, EX7.10
/PREP7
/TITLE, EX7.10, TRANSVERSE VIBRATIONS OF A SHEAR BEAM.
ANTYPE, MODAL
ET, 1, SHELL28
R, 1, 0.1
MP, EX, 1, 200E9
MP, NUXY, 1, 0.27
MP, DENS, 1, 7860.0
! （2）定义节点位置和单元连接
/VIEW, 1, 1, 1, 1
N, 1
N, 2, 10
N, 3, 10, 10
N, 4, , 10
NGEN, 9, 4, 1, 4, 1, , , 3.75
E, 1, 2, 6, 5
EGEN, 3, 1, -1
E, 4, 1, 5, 8
EGEN, 8, 4, -4
! （3）设置位移约束和耦合自由度
D, ALL, UZ
D, 1, UX, , , 4, 1, UY
NSEL, S, LOC, Z, 3.75
CP, 1, UX, ALL
CP, 2, UY, ALL
NSEL, S, LOC, Z, 7.5
CP, 3, UX, ALL
CP, 4, UY, ALL
NSEL, S, LOC, Z, 11.25
CP, 5, UX, ALL
CP, 6, UY, ALL
NSEL, S, LOC, Z, 15
CP, 7, UX, ALL
CP, 8, UY, ALL
NSEL, S, LOC, Z, 18.75
CP, 9, UX, ALL
CP, 10, UY, ALL
NSEL, S, LOC, Z, 22.5
CP, 11, UX, ALL
CP, 12, UY, ALL
NSEL, S, LOC, Z, 26.25
CP, 13, UX, ALL
CP, 14, UY, ALL
NSEL, S, LOC, Z, 30
CP, 15, UX, ALL
CP, 16, UY, ALL
NSEL, ALL
FINISH
! （4）指定求解选项, 并求解
/SOLU
MXPAND, 4
MODOPT, REDUC
TOTAL, 8
SOLVE
! （5）提取频率计算结果
*GET, F1, MODE, 1, FREQ
*GET, F2, MODE, 3, FREQ
*STATUS, PARM
FINISH
! （6）在一般后处理模块中, 显示模态形状, 列表显示内存变量的值
/POST1
SET, 1, 1
/VUP, , Z
/VIEW, , , 1
PLDISP, 1
SET, 1, 3
PLDISP, 1
FINISH