ex4.12(1).inp

ansys有限元分析程序

! 4.12  端部集中力下悬臂圆环曲梁弯曲的三维分析
! 本程序来源于邢静忠编著的《ANSYS应用实例与分析》，科学出版社，2006年
!
FINISH
/CLEAR, NOSTART
! (1)定义工程选项、分析类型、单元类型和材料参数
/FILNAME, EX4.12(1)
/PREP7
SMRT, OFF
/TITLE, EX4.12(1), BENDING OF A CURVED BEAM WITH SOLID5.
ANTYPE, STATIC
ET, 1, SOLID5, 2
MP, EX, 1, 70E3
MP, NUXY, 1, 0.25
! (2)在柱坐标系定义关键点、线和体
CSYS, 1
K, 1, 104.6
K, 2, 109.7
KGEN, 2, 1, 2, 1, , , 2.54
KGEN, 2, 1, 4, 1, , 90
L, 1, 5
LESIZE, 1, , , 20
V, 1, 2, 4, 3, 5, 6, 8, 7
ESIZE, , 1
/VIEW, 1, 1, 1, 1
/Device, VECTOR, 1
VMESH, 1
! (3)选择节点, 施加位移约束和荷载
/Device, VECTOR, 0
NSEL, S, LOC, Y, 0
D, ALL, ALL, 0
NSEL, ALL
FK, 5, FY, 1.1121
*REPEAT, 4, 1
NOORDER
FINISH
! (4)进入求解模块, 开始求解
/SOLU
SOLVE
FINISH
! (5)定义完成后处理的宏程序
*CREATE, MAC
/POST1
CSYS, 0
NSEL, S, LOC, X, 0, 0.01, , 1
PRNSOL, U, COMP
LCDEF, 1, 1
LCFACT, 1, (1/2.187)
LCASE, 1
PRNSOL, U, COMP
FINISH
*END
! (6)提取自由端位移计算结果
/POST1
*GET, U1, NODE, 5, U, Y
PLNSOL, S, Y
! （7）将计算结果保存到文件
SAVE, TABLE_1
*USE, MAC
! (8)重新开始用SOLID92单元分析
FINISH
/CLEAR, NOSTART
/FILNAME, EX4.12(2)
/PREP7
SMRT, OFF
/TITLE, EX4.12(2), BENDING OF A CURVED BEAM WITH SOLID92.
ET, 1, SOLID92
MP, EX, 1, 70E3
MP, NUXY, 1, 0.25
! (9)通过关键点定义模型
CSYS, 1
/VIEW, 1, 1, 1, 1
K, 1, 104.6
K, 2, 109.7
KGEN, 2, 1, 2, 1, , , 2.54
KGEN, 2, 1, 4, 1, , 4.5
V, 1, 2, 4, 3, 5, 6, 8, 7
VGEN, 20, 1, 1, 1, , 4.5, , 4
ESIZE, , 1
VMESH, ALL
! (10)选择节点, 施加位移约束和荷载
NSEL, S, LOC, Y, 0
D, ALL, ALL, 0
NSEL, S, LOC, Y, 90
CP, 1, UY, ALL
NSEL, R, LOC, X, 109.7
NSEL, R, LOC, Z, 0
F, ALL, FY, 4.4483
NSEL, ALL
SAVE
FINISH
! (11)进入求解模块开始求解, 并使用前面的宏程序进行相应的后处理
/SOLU
SOLVE
FINISH
! (12)选择自由端节点, 提取位移计算结果
/POST1
PLNSOL, S, Y
*USE, MAC
NDE=NODE(0, 109.7, 0)
*GET, UY2, NODE, NDE, U, Y
*SET, U2, (UY2/(1/2.187))
! (13)将计算结果保存到文件
SAVE, TABLE_2
! (14)重新开始用SOLID98单元分析
/PREP7
SMRT, OFF
RESUME
/TITLE, EX4.12(3), BENDING OF A CURVED BEAM WITH SOLID98.
ET, 1, SOLID98, 2
FINISH
! (15)进入求解模块开始求解, 并使用前面的宏程序进行相应的后处理
/SOLU
SOLVE
FINISH
! (16)选择自由端节点, 提取位移计算结果
/POST1
PLNSOL, S, Y
*USE, MAC
NDE=NODE(0, 109.7, 0)
*GET, UY3, NODE, NDE, U, Y
*SET, U3, (UY3/(1/2.187))
! (17)将计算结果保存到文件
SAVE, TABLE_3
! (18)重新开始用SOLID148单元分析
/PREP7
SMRT, OFF
RESUME
/TITLE, EX4.12(4), BENDING OF A CURVED BEAM WITH SOLID148.
ET, 1, SOLID148, 2
FINISH
! (19)进入求解模块开始求解
/SOLU
SOLVE
FINISH
! (20)图形显示环向应力分布, 使用宏程序进行后处理, 选择自由端节点, 提取位移结果
/POST1
SET, LAST
PLNSOL, S, Y
*USE, MAC
NDE=NODE(0, 109.7, 0)
*GET, UY3, NODE, NDE, U, Y
*SET, U3, (UY3/(1/2.187))
*STATUS, PARM
Resume, Table_1
*STATUS, PARM
Resume, Table_2
*STATUS, PARM
Resume, Table_3
*STATUS, PARM
FINISH