tcenter.bat

利用VC++和OpenGVS结合编的一个关于火车运行的三维模拟程序。是OpenGVS三维初学者的应该参考的好范例。

@echo off
rem Startup Train demo (master)
if "%OS%" == "Windows_NT" setlocal

rem Startup file gvsinit.gvc relies on databases being there...
set G_TEST_NUL=\nul
if "%OS%" == "Windows_NT" set G_TEST_NUL=

if "" == "%GV_ROOT%" goto CHKW9X
goto CHKTGT

:CHKW9X
if "moreroom" == "%1" goto NEWROOM
if "%OS%" == "Windows_NT" goto CHKTGT

rem Since running Win9x, ensure presence of sufficient environment space
call command.com /e:12288 /c %0 moreroom %1 %2 %3 %4 %5 %6 %7 %8 %9
goto QUIT

:NEWROOM
shift

:CHKTGT
rem If specified, run prebuilt executable from %GV_ROOT%\bindemo\w32\%G_PROC%
if "%1" == "ogl" goto HAVETGT
if "%1" == "g3" goto HAVETGT
if "%1" == "sgld3" goto HAVETGT
if "%1" == "sglg3" goto HAVETGT
if not EXIST train%gfx%.exe set gfx=ogl
goto CHKENV

:HAVETGT
set gfx=%1
shift

:CHKENV
if NOT "%1" == "GV_ROOT" goto SETUPENV
rem Caller gave us GV_ROOT directory-spec; use it
if EXIST ..\env.bat call ..\env.bat %2
shift
shift
goto HAVEENV

:SETUPENV
if EXIST ..\env.bat call ..\env.bat

:HAVEENV
if EXIST "%GV_ROOT%\models\gvm\Intersim\train%G_TEST_NUL%" goto RUNIT

:WHOOPS
echo Whoops - Could not find the %GV_ROOT%\models\gvm\Intersim\train database directory!
echo Do you have OpenGVS installed on this system and have you setup
echo your OpenGVS environment (e.g., login_gv.bat)?
pause
goto QUIT

:RUNIT
echo train%GFX% -master -noborder -nosge_ground -cgeometry=../center.txt %1 %2 %3
train%GFX% -master -noborder -nosge_ground -cgeometry=../center.txt %1 %2 %3

:QUIT
if "%OS%" == "Windows_NT" endlocal
set gfx=
set G_TEST_NUL=