📄 split.asp
字号:
<!--#include file="conn.asp"-->
<%'包含conn.asp文件，该文件用来打开Connection对象，
'使用Include文件可以免去在每个ASP程序中写连接语句的麻烦%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>分页显示</title>
</head>
<body>
<%
'定义Recordset对象
Set rs=Server.CreateObject("ADODB.Recordset")
'设置ActiveConnection属性
Set rs.ActiveConnection=conn
strSQL="Select * From eword"
'打开记录集
rs.Open strSQL,conn,3,1
'设置每页显示3行记录
rs.PageSize=3
'读取参数
page=CLng(Request.QueryString("page"))
'处理无效页码
If page<1 then
page=1
End if
If page>rs.PageCount Then
page=rs.PageCount
End if
'设置当前页
rs.AbsolutePage=page
%>
<h2 align="center">分页显示表eword</h2>
<br> 当前页码：<%=page%>/<%=rs.PageCount%>
<br>
<table border="1" width="100%">
<tr><td bgcolor="#c0c0c0">序号</td><td bgcolor="#c0c0c0">英文单词</td>
<td bgcolor="#c0c0c0">中文解释</td></tr>
<%
For i=1 To rs.PageSize
strNo=(page-1)*rs.PageSize + i
'在表中显示字段值
Response.Write("<tr><td>" &CStr(strNo)& "</td><td>"& rs.Fields(0).Value &_
"</td><td>" & CStr(rs.Fields(1).Value)& "</td></tr>")
rs.MoveNext
'如果到达记录集结尾，结束循环
If rs.Eof Then Exit For
Next
Response.Write("</table><br>")
'设置第一页
If Page=1 Then
Response.Write "第一页 "
Else
Response.Write("<a href=split.asp?page=1>第一页</a>")
End If
'设置上一页
If Page=1 Then
Response.Write " 上一页 "
Else
Response.Write("<a href=split.asp?page=" & page-1 & ">上一页</a>")
End If
'设置下一页
If Page=rs.PageCount Then
Response.Write " 下一页 "
Else
Response.Write("<a href=split.asp?page=" & page+1 & ">下一页</a>")
End If
'设置最后一页
If Page=rs.PageCount Then
Response.Write " 最后一页"
Else
Response.Write("<a href=split.asp?page=" & rs.PageCount & ">最后一页</a>")
End If
'断开数据库连接
conn.Close
If Conn.state=0 Then
End if
'释放连接关闭数据库
Set Conn=nothing
Set rs=nothing
%>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -